src/Widgets/gmpc-song-list.vala

   1 /* Gnome Music Player Client (GMPC)
   2  * Copyright (C) 2004-2012 Qball Cow <qball@gmpclient.org>
   3  * Project homepage: http://gmpclient.org/
   4
   5  * This program is free software; you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation; either version 2 of the License, or
   8  * (at your option) any later version.
   9
  10  * This program is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14
  15  * You should have received a copy of the GNU General Public License along
  16  * with this program; if not, write to the Free Software Foundation, Inc.,
  17  * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 */
  19
  20 using Config;
  21 using Gtk;
  22 using Gmpc;
  23 using MPD;
  24
  25 private const bool use_transition_gsl = Gmpc.use_transition;
  26 private const string some_unique_name_gsl = Config.VERSION;
  27
  28 public class Gmpc.Widgets.Songlist : Gmpc.Widgets.Qtable
  29 {
  30     private const int MAX_RESULTS           = 125;
  31     /* Constructor function  */
  32     public Songlist()
  33     {
  34         this.spacing = 6;
  35         this.max_columns = 3;
  36
  37     }
  38     /**
  39      * Add a artist entry
  40      */
  41     private void add_artist_entry(MPD.Song song, int level=0)
  42     {
  43         /* Event box */
  44         var event = new Gtk.EventBox();
  45         event.set_visible_window(false);
  46
  47         var box = new Gtk.HBox(false, 6);
  48         /* Disc image */
  49         /* add padding */
  50         var ali = new Gtk.Alignment(0.0f, 0.5f,0f,0f);
  51         ali.set_padding(0,0,level*32,0);
  52         box.pack_start(ali, false, false, 0);
  53
  54         var image = new Gmpc.MetaData.Image(Gmpc.MetaData.Type.ARTIST_ART, 32);
  55         image.set_no_cover_icon("no-artist");
  56         image.set_loading_cover_icon("fetching-artist");
  57         image.set_squared(false);
  58         image.update_from_song(song);
  59         /* add the image */
  60         ali.add(image);
  61
  62         /* Create lLabel */
  63         string label = null;
  64         if(song.albumartist != null && song.albumartist.length > 0 )
  65         {
  66             label = "%s: %s".printf(_("Artist"), song.albumartist);
  67         }
  68         else
  69         {
  70             label = "%s: %s".printf(_("Artist"), song.artist);
  71         }
  72         var wlabel = new Clicklabel(label);
  73         wlabel.set_do_bold(true);
  74         wlabel.set_can_focus(true);
  75
  76         MPD.Song song_file = song.copy();
  77         wlabel.clicked.connect((source, event) =>
  78         {
  79             artist_song_clicked(song_file);
  80         });
  81
  82         /* add the label */
  83         box.pack_start(wlabel, false, false, 0);
  84
  85         /* Add the entry */
  86         event.add(box);
  87         //this.pack_start(event, false, false, 0);
  88         this.add_header(event);
  89     }
  90
  91     /**
  92      * Add a album entry
  93      */
  94     private void add_album_entry(MPD.Song song, int level=0)
  95     {
  96         /* Event box */
  97         var event = new Gtk.EventBox();
  98         event.set_visible_window(false);
  99
 100         var box = new Gtk.HBox(false, 6);
 101         /* Disc image */
 102         /* add padding */
 103         var ali = new Gtk.Alignment(0.0f, 0.5f,0f,0f);
 104         ali.set_padding(0,0,level*32,0);
 105         box.pack_start(ali, false, false, 0);
 106
 107
 108         //var image = new Gtk.Image.from_icon_name("media-album", Gtk.IconSize.BUTTON);
 109         var image = new Gmpc.MetaData.Image(Gmpc.MetaData.Type.ALBUM_ART, 32);
 110         image.set_squared(false);
 111         image.update_from_song(song);
 112         /* add the image */
 113         ali.add(image);
 114
 115         /* Create lLabel */
 116         string label = "%s: %s".printf(_("Album"), song.album);
 117         var wlabel = new Clicklabel(label);
 118         wlabel.set_do_bold(true);
 119         wlabel.set_can_focus(true);
 120
 121         MPD.Song song_file = song.copy();
 122         wlabel.clicked.connect((source) =>
 123         {
 124             album_song_clicked(song_file);
 125         });
 126         /* add the label */
 127         box.pack_start(wlabel, false, false, 0);
 128
 129         /* Add the entry */
 130         event.add(box);
 131 //        this.pack_start(event, false, false, 0);
 132         this.add_header(event);
 133     }
 134     /**
 135      * Add a disc entry
 136      */
 137     private void add_disc_entry(string entry, int level=0)
 138     {
 139         GLib.debug("Disc entry add: %s", entry);
 140
 141         /* */
 142         var box = new Gtk.HBox(false, 6);
 143
 144         /* add padding */
 145         var ali = new Gtk.Alignment(0.0f, 0.5f,0f,0f);
 146         ali.set_padding(0,0,level*32,0);
 147         box.pack_start(ali, false, false, 0);
 148
 149         /* Disc image */
 150         var image = new Gtk.Image.from_icon_name("media-album", Gtk.IconSize.BUTTON);
 151         /* add the image */
 152         ali.add(image);
 153
 154         /* Create lLabel */
 155         string label = "<b>%s: %s</b>".printf(_("Disc"), entry);
 156         var wlabel = new Gtk.Label("");
 157         wlabel.set_markup(label);
 158
 159         /* add the label */
 160         box.pack_start(wlabel, false, false, 0);
 161
 162         /* Add the entry */
 163         //this.pack_start(box, false, false, 0);
 164         this.add_header(box);
 165     }
 166
 167
 168     /**
 169      * Add a song entry
 170      */
 171
 172     private void add_song_entry(MPD.Song song, int level=0)
 173     {
 174         var event = new Gtk.EventBox();
 175         event.set_visible_window(false);
 176         GLib.debug("Song entry add: %s", song.file);
 177
 178         var box = new Gtk.HBox(false, 6);
 179
 180         /* add padding */
 181         var ali = new Gtk.Alignment(0.0f, 0.5f,0f,0f);
 182         ali.set_padding(0,0,level*32,0);
 183         box.pack_start(ali, false, false, 0);
 184
 185         /* Title image */
 186         var image = new Gtk.Image.from_icon_name("media-audiofile", Gtk.IconSize.MENU);
 187
 188         event.enter_notify_event.connect((source, event) =>
 189         {
 190             image.set_from_stock("gtk-media-play", Gtk.IconSize.MENU);
 191             return false;
 192
 193         });
 194
 195         event.leave_notify_event.connect((source, event) =>
 196         {
 197             image.set_from_icon_name("media-audiofile",Gtk.IconSize.MENU);
 198             return false;
 199         });
 200
 201         /* add the image */
 202         event.add(image);
 203         ali.add(event);
 204
 205
 206         MPD.Song song_file = song.copy();
 207         event.button_release_event.connect((source, event) =>
 208         {
 209             if(event.button == 1)
 210             {
 211                 play_song_clicked(song_file);
 212                 return true;
 213             }
 214             else if (event.button == 3)
 215             {
 216                 song_context_menu(song_file);
 217                 return true;
 218             }
 219             return false;
 220         });
 221
 222         /* add title label */
 223         string label = null;
 224         if(song.track != null && song.title != null)
 225         {
 226             label = "%02s. %s".printf(song.track, song.title);
 227         }
 228         else if (song.title != null)
 229         {
 230             label = song.title;
 231         }
 232         else
 233         {
 234             label = GLib.Path.get_basename(song.file);
 235         }
 236         var wlabel = new Gmpc.Clicklabel(label);
 237         wlabel.set_can_focus(true);
 238
 239         /* add the label */
 240         box.pack_start(wlabel, false, false, 0);
 241         wlabel.context_menu.connect((source) =>
 242         {
 243             stdout.printf("song list context menu\n");
 244             song_context_menu(song_file);
 245         });
 246
 247         wlabel.clicked.connect((source, alt) =>
 248         {
 249             if(alt)
 250                 play_song_clicked(song_file);
 251             else
 252                 song_clicked(song_file);
 253         });
 254
 255         /* Add the entry */
 256         //this.pack_start(box, false, false, 0);
 257         this.add(box);
 258     }
 259
 260     /* User click on the title */
 261     public signal void song_clicked      (MPD.Song song);
 262     public signal void song_context_menu (MPD.Song song);
 263     /* user clicked on the play */
 264     public signal void play_song_clicked (MPD.Song song);
 265     /* user clicked on the album */
 266     public signal void album_song_clicked (MPD.Song song);
 267     /* user clicked on the artist */
 268     public signal void artist_song_clicked(MPD.Song song);
 269
 270     /**
 271      * Fill the widget from a song list
 272      */
 273     public void set_from_data(owned MPD.Data.Item? list, bool show_album=false, bool show_artist=false)
 274     {
 275         int results = 0;
 276         /* Removing everything it contains */
 277         foreach(var child in this.get_children())
 278         {
 279             child.destroy();
 280         }
 281
 282         if(list == null) return;
 283
 284         /* Sort the list so we can display it correctly */
 285         list.sort_album_disc_track();
 286         weak MPD.Data.Item iter = list;
 287         /* itterating items */
 288         string disc = null;
 289         string album = null;
 290         string artist = null;
 291         /* Itterate over the songs */
 292         int level = -1;
 293         for(; iter != null; iter.next(false))
 294         {
 295             /* if it is no MPD.Song, skip */
 296             if(iter.song == null) continue;
 297             if(results > this.MAX_RESULTS)
 298             {
 299                 var bar = new Gtk.InfoBar();
 300                 var label = new Gtk.Label(_("Only the first %i results are shown. Please refine your search.".printf(MAX_RESULTS)));
 301                 label.set_alignment(0.0f,0.5f);
 302                 bar.set_message_type(Gtk.MessageType.WARNING);
 303                 (bar.get_content_area() as Gtk.Container).add(label);
 304
 305 //                this.pack_start(bar, false, false);
 306                 this.add_header(bar);
 307                 break;
 308             }
 309             results++;
 310
 311             if(show_artist)
 312             {
 313                 if(iter.song.albumartist != null &&
 314                         iter.song.albumartist.length > 0)
 315                 {
 316                     if(artist == null || artist != iter.song.albumartist)
 317                     {
 318                         this.add_artist_entry(iter.song,0);
 319                         artist = iter.song.albumartist;
 320                         disc = null;
 321                         album = null;
 322                     }
 323                 }
 324                 else if(iter.song.artist != null && (artist == null || artist != iter.song.artist))
 325                 {
 326                     this.add_artist_entry(iter.song,0);
 327                     artist = iter.song.artist;
 328                     disc = null;
 329                     album = null;
 330                 }
 331             }
 332             if(show_album)
 333             {
 334                 if(iter.song.album != null && (album == null || album != iter.song.album))
 335                 {
 336                     this.add_album_entry(iter.song,(artist != null)?1:0);
 337                     album = iter.song.album;
 338                     disc = null;
 339                 }
 340             }
 341             /* Check for a new disc */
 342             if(iter.song.disc != null && (disc == null  || disc != iter.song.disc))
 343             {
 344                 this.add_disc_entry(iter.song.disc,((artist != null)?1:0)+((album!=null)?1:0));
 345                 /* Add a  new disc button */
 346                 disc = iter.song.disc;
 347             }
 348             /* add song row */
 349             level = 0;
 350             if(disc != null) level++;
 351             if(artist != null) level++;
 352             if(album != null) level++;
 353             this.add_song_entry(iter.song,level);
 354         }
 355
 356         /* show everything */
 357         this.show_all();
 358     }
 359 }