src/Widgets/gmpc-metadata-text-label.vala

   1 /* Gnome Music Player Client
   2  * Copyright (C) 2011-2012 Qball Cow <qball@gmpclient.org>
   3  * Project homepage: http://gmpclient.org/
   4
   5  * This program is free software; you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation; either version 2 of the License, or
   8  * (at your option) any later version.
   9
  10  * This program is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14
  15  * You should have received a copy of the GNU General Public License along
  16  * with this program; if not, write to the Free Software Foundation, Inc.,
  17  * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 */
  19 using GLib;
  20 using Gmpc;
  21
  22 private const bool use_transition_mdtl = Gmpc.use_transition;
  23 private const string some_unique_name_mdtl = Config.VERSION;
  24
  25
  26 namespace Gmpc.MetaData.Widgets
  27 {
  28     public class TextLabel : Gtk.Label
  29     {
  30         private MPD.Song? cur_song = null;
  31         private string song_checksum = null;
  32         private Gmpc.MetaData.Type cur_type = Gmpc.MetaData.Type.ALBUM_TXT;
  33         private void set_from_item(Gmpc.MetaData.Item? item)
  34         {
  35             if(item != null )
  36             {
  37                 if(item.content_type == Gmpc.MetaData.ContentType.TEXT)
  38                 {
  39                     string res = item.get_text();
  40                     this.set_text(res);
  41                 }
  42                 else if(item.content_type == Gmpc.MetaData.ContentType.HTML)
  43                 {
  44
  45                     string res = item.get_text_from_html();
  46                     this.set_text(res);
  47                 }
  48                 else if(item.content_type == Gmpc.MetaData.ContentType.URI )
  49                 {
  50                     string path = item.get_uri();
  51                     string res = null;
  52                     try
  53                     {
  54                         GLib.FileUtils.get_contents( path, out res);
  55                         this.set_text(res);
  56                     }
  57                     catch (Error e)
  58                     {
  59                         this.set_text(_("Error reading file: %s").printf(e.message));
  60                     }
  61                 }
  62                 else
  63                 {
  64                     this.set_text(_("Not available"));
  65                 }
  66             }
  67             else
  68             {
  69                 this.set_text(_("Not available"));
  70             }
  71         }
  72
  73         /**
  74          * @param song The #MPD.Song to display the text for.
  75          * @param type The #Gmpc.MetaData.Type of metadata to display.
  76          * Create a text label for Song, that displays
  77          * Text metadata
  78          * @return a #TextLabel or type #Gtk.Label
  79          */
  80
  81         public TextLabel(MPD.Song song,Gmpc.MetaData.Type type)
  82         {
  83             this.set_line_wrap(true);
  84             this.set_text("Not available");
  85             this.set_alignment(0.0f, 0.0f);
  86             this.set_padding(4,4);
  87             this.set_selectable(true);
  88             cur_type = type;
  89             cur_song = song.copy();
  90             song_checksum = Gmpc.Misc.song_checksum(song);
  91
  92             metawatcher.data_changed.connect((csong, type, result, met) =>
  93             {
  94                 if(type == cur_type && song_checksum == Gmpc.Misc.song_checksum(csong))
  95                 {
  96                     if(result == Gmpc.MetaData.Result.AVAILABLE)
  97                     {
  98                         this.set_from_item(met);
  99                     }
 100                     else if (result == Gmpc.MetaData.Result.FETCHING)
 101                     {
 102                         this.set_text(_("Fetching..."));
 103                     }
 104                     else
 105                     {
 106                         this.set_from_item(null);
 107                     }
 108
 109                 }
 110             });
 111
 112             /** Query */
 113             Gmpc.MetaData.Item item = null;
 114             var a = MetaData.get_path(cur_song, type, out item);
 115             if(a == Gmpc.MetaData.Result.AVAILABLE)
 116             {
 117                 this.set_from_item(item);
 118             }
 119             else if (a == Gmpc.MetaData.Result.FETCHING)
 120             {
 121                 this.set_text(_("Fetching..."));
 122             }
 123             else
 124             {
 125                 this.set_from_item(null);
 126             }
 127             this.populate_popup.connect((source, menu)=>
 128             {
 129                 /*  Add refetch */
 130                 var mitem = new Gtk.ImageMenuItem.with_label(_("Refetch"));
 131                 mitem.set_image(
 132                     new Gtk.Image.from_stock("gtk-refresh", Gtk.IconSize.MENU));
 133                 mitem.activate.connect((source)=>{
 134                     MetaData.get_path(cur_song, type|Gmpc.MetaData.Type.QUERY_NO_CACHE, out item);
 135                 });
 136                 menu.append(mitem);
 137                 mitem.show();
 138
 139                 /*  Add selector */
 140                 mitem = new Gtk.ImageMenuItem.with_label(_("Metadata selector"));
 141                 mitem.set_image(
 142                     new Gtk.Image.from_stock("gtk-edit", Gtk.IconSize.MENU));
 143                 mitem.activate.connect((source)=>{
 144                     new Gmpc.MetaData.EditWindow(cur_song, cur_type);
 145                 });
 146                 menu.append(mitem);
 147                 mitem.show();
 148             });
 149
 150         }
 151
 152     }
 153
 154 }// end namespace Gmpc.MetaData