sysdeps/x86_64/elf/start.S

   1 /* Startup code compliant to the ELF x86-64 ABI.
   2    Copyright (C) 2001, 2002, 2003, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2001.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, write to the Free
  35    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  36    02111-1307 USA.  */
  37
  38 /* This is the canonical entry point, usually the first thing in the text
  39    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  40    point runs, most registers' values are unspecified, except for:
  41
  42    %rdx         Contains a function pointer to be registered with `atexit'.
  43                 This is how the dynamic linker arranges to have DT_FINI
  44                 functions called for shared libraries that have been loaded
  45                 before this code runs.
  46
  47    %rsp         The stack contains the arguments and environment:
  48                 0(%rsp)                 argc
  49                 8(%rsp)                 argv[0]
  50                 ...
  51                 (8*argc)(%rsp)          NULL
  52                 (8*(argc+1))(%rsp)      envp[0]
  53                 ...
  54                                         NULL
  55 */
  56
  57 #include "bp-sym.h"
  58
  59         .text
  60         .globl _start
  61         .type _start,@function
  62 _start:
  63         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  64            the outermost frame obviously.  */
  65         xorl %ebp, %ebp
  66
  67         /* Extract the arguments as encoded on the stack and set up
  68            the arguments for __libc_start_main (int (*main) (int, char **, char **),
  69                    int argc, char *argv,
  70                    void (*init) (void), void (*fini) (void),
  71                    void (*rtld_fini) (void), void *stack_end).
  72            The arguments are passed via registers and on the stack:
  73         main:           %rdi
  74         argc:           %rsi
  75         argv:           %rdx
  76         init:           %rcx
  77         fini:           %r8
  78         rtld_fini:      %r9
  79         stack_end:      stack.  */
  80
  81         movq %rdx, %r9          /* Address of the shared library termination
  82                                    function.  */
  83         popq %rsi               /* Pop the argument count.  */
  84         movq %rsp, %rdx         /* argv starts just at the current stack top.  */
  85         /* Align the stack to a 16 byte boundary to follow the ABI.  */
  86         andq  $~15, %rsp
  87
  88         pushq %rax              /* Push garbage because we push 8 more bytes.  */
  89
  90         /* Provide the highest stack address to the user code (for stacks
  91            which grow downwards).  */
  92         pushq %rsp
  93
  94 #ifdef SHARED
  95         /* Pass address of our own entry points to .fini and .init.  */
  96         movq __libc_csu_fini@GOTPCREL(%rip), %r8
  97         movq __libc_csu_init@GOTPCREL(%rip), %rcx
  98
  99         movq BP_SYM (main)@GOTPCREL(%rip), %rdi
 100
 101         /* Call the user's main function, and exit with its value.
 102            But let the libc call main.    */
 103         call BP_SYM (__libc_start_main)@PLT
 104 #else
 105         /* Pass address of our own entry points to .fini and .init.  */
 106         movq $__libc_csu_fini, %r8
 107         movq $__libc_csu_init, %rcx
 108
 109         movq $BP_SYM (main), %rdi
 110
 111         /* Call the user's main function, and exit with its value.
 112            But let the libc call main.    */
 113         call BP_SYM (__libc_start_main)
 114 #endif
 115
 116         hlt                     /* Crash if somehow `exit' does return.  */
 117
 118 /* Define a symbol for the first piece of initialized data.  */
 119         .data
 120         .globl __data_start
 121 __data_start:
 122         .long 0
 123         .weak data_start
 124         data_start = __data_start