sysdeps/unix/sysv/linux/sparc/sparc64/clone.S

   1 /* Copyright (C) 1997, 2000, 2007 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson (rth@tamu.edu).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* clone() is even more special than fork() as it mucks with stacks
  21    and invokes a function in the right context after its all over.  */
  22
  23 #include <asm/errno.h>
  24 #include <asm/unistd.h>
  25 #include <tcb-offsets.h>
  26 #include <sysdep.h>
  27
  28 #define CLONE_VM        0x00000100
  29 #define CLONE_THREAD    0x00010000
  30
  31 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  32              pid_t *ptid, void *tls, pid_t *ctid); */
  33
  34         .register       %g2,#scratch
  35         .register       %g3,#scratch
  36
  37         .text
  38
  39 ENTRY (__clone)
  40         save    %sp, -192, %sp
  41         cfi_def_cfa_register(%fp)
  42         cfi_window_save
  43         cfi_register(%o7, %i7)
  44
  45         /* sanity check arguments */
  46         brz,pn  %i0, 99f                /* fn non-NULL? */
  47          mov    %i0, %g2
  48         brz,pn  %i1, 99f                /* child_stack non-NULL? */
  49          mov    %i2, %o0                /* clone flags */
  50
  51         /* The child_stack is the top of the stack, allocate one
  52            whole stack frame from that as this is what the kernel
  53            expects.  Also, subtract STACK_BIAS.  */
  54         sub     %i1, 192 + 0x7ff, %o1
  55         mov     %i3, %g3
  56         mov     %i2, %g4
  57
  58         mov     %i4,%o2                 /* PTID */
  59         mov     %i5,%o3                 /* TLS */
  60         ldx     [%fp+0x7ff+176],%o4     /* CTID */
  61
  62         /* Do the system call */
  63         set     __NR_clone, %g1
  64         ta      0x6d
  65         bcs,pn  %xcc, 98f
  66          nop
  67         brnz,pn %o1, __thread_start
  68          nop
  69         jmpl    %i7 + 8, %g0
  70          restore %o0, %g0, %o0
  71 99:     mov     EINVAL, %o0
  72 98:     call    HIDDEN_JUMPTARGET(__errno_location)
  73          mov    %o0, %i0
  74         st      %i0, [%o0]
  75         jmpl    %i7 + 8, %g0
  76          restore %g0,-1,%o0
  77 END(__clone)
  78
  79         .type __thread_start,@function
  80 __thread_start:
  81 #ifdef RESET_PID
  82         sethi   %hi(CLONE_THREAD), %l0
  83         andcc   %g4, %l0, %g0
  84         bne,pt  %icc, 1f
  85          andcc  %g4, CLONE_VM, %g0
  86         bne,a,pn %icc, 2f
  87          mov    -1,%o0
  88         set     __NR_getpid,%g1
  89         ta      0x6d
  90 2:      st      %o0,[%g7 + PID]
  91         st      %o0,[%g7 + TID]
  92 1:
  93 #endif
  94         mov     %g0, %fp        /* terminate backtrace */
  95         call    %g2
  96          mov    %g3,%o0
  97         call    HIDDEN_JUMPTARGET(_exit),0
  98          nop
  99
 100         .size   __thread_start, .-__thread_start
 101
 102 weak_alias (__clone, clone)