sysdeps/unix/sysv/linux/sparc/sparc64/brk.S

   1 /* Copyright (C) 1997, 2008 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson <richard@gnu.ai.mit.edu>, 1997.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* __brk is a special syscall under Linux since it never returns an
  21    error.  Instead, the error condition is indicated by returning the old
  22    break value (instead of the new, requested one).  */
  23
  24 #include <sysdep.h>
  25 #define _ERRNO_H
  26 #include <bits/errno.h>
  27
  28 #ifdef PIC
  29 .section .bss
  30         .align 8
  31         .globl __curbrk
  32 __curbrk: .skip 8
  33         .type __curbrk,@object
  34         .size __curbrk,8
  35 #else
  36 .common __curbrk, 8, 8
  37 #endif
  38
  39         .text
  40 ENTRY (__brk)
  41         save    %sp, -192, %sp
  42         cfi_def_cfa_register(%fp)
  43         cfi_window_save
  44         cfi_register(%o7, %i7)
  45 #ifdef PIC
  46 1:      call    2f
  47         sethi   %hi(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
  48 2:      or      %l7, %lo(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
  49         add     %l7, %o7, %l7
  50 #endif
  51
  52         LOADSYSCALL(brk)
  53         mov     %i0, %o0
  54
  55         ta      0x6d
  56
  57         /* All the ways we can fail... */
  58         bcs,pn  %xcc, .Lerr1
  59          nop
  60         brz,pt  %i0, .Lok
  61          subcc  %i0, %o0, %g0
  62         bne,pn  %xcc, .Lerr0
  63          nop
  64
  65         /* Update __curbrk and return cleanly.  */
  66 .Lok:   sethi   %hi(__curbrk), %g1
  67         or      %g1, %lo(__curbrk), %g1
  68 #ifdef PIC
  69         ldx     [%l7+%g1], %g1
  70 #endif
  71         stx     %o0, [%g1]
  72         mov     %g0, %i0
  73
  74         /* Don't use "ret" cause the preprocessor will eat it.  */
  75         jmpl    %i7+8, %g0
  76          restore
  77
  78         /* What a horrible way to die.  */
  79 .Lerr0: set     ENOMEM, %o0
  80 .Lerr1:
  81 #ifndef _LIBC_REENTRANT
  82         sethi   %hi(errno), %g1
  83         or      %g1, %lo(errno), %g1
  84 #ifdef PIC
  85         ldx     [%l7+%g1], %g1
  86 #endif
  87         st      %o0, [%g1]
  88 #else
  89 #ifndef NOT_IN_libc
  90         call    HIDDEN_JUMPTARGET(__errno_location)
  91 #else
  92         call    __errno_location
  93 #endif
  94          mov    %o0,%l1
  95         st      %l1, [%o0]
  96 #endif
  97         sub     %g0, 1, %i0
  98         jmpl    %i7+8, %g0
  99          restore
 100 END (__brk)
 101
 102 weak_alias (__brk, brk)