sysdeps/unix/sysv/linux/sparc/sparc32/socket.S

   1 /* Copyright (C) 1997, 1998, 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Miguel de Icaza <miguel@gnu.ai.mit.edu>, 1997.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep-cancel.h>
  21 #include <socketcall.h>
  22
  23 #define P(a, b) P2(a, b)
  24 #define P2(a, b) a##b
  25
  26 #ifndef NARGS
  27 #ifdef socket
  28 #error NARGS not defined
  29 #endif
  30 #define NARGS 3
  31 #endif
  32
  33         .text
  34 /* The socket-oriented system calls are handled unusually in Linux.
  35    They are all gated through the single `socketcall' system call number.
  36    `socketcall' takes two arguments: the first is the subcode, specifying
  37    which socket function is being called; and the second is a pointer to
  38    the arguments to the specific function.
  39
  40    The .S files for the other calls just #define socket and #include this.  */
  41
  42 #ifndef __socket
  43 # ifndef NO_WEAK_ALIAS
  44 #  define __socket P(__,socket)
  45 # else
  46 #  define __socket socket
  47 # endif
  48 #endif
  49
  50         .globl          __syscall_error
  51 ENTRY (__socket)
  52
  53         /* Drop up to 6 arguments (recvfrom) into the memory allocated by
  54            the caller for varargs, since that's really what we have.  */
  55         st %o0, [%sp + 68 + 0]
  56         st %o1, [%sp + 68 + 4]
  57 #if NARGS > 2
  58         st %o2, [%sp + 68 + 8]
  59 #if NARGS > 3
  60         st %o3, [%sp + 68 + 12]
  61 #if NARGS > 4
  62         st %o4, [%sp + 68 + 16]
  63 #if NARGS > 5
  64         st %o5, [%sp + 68 + 20]
  65 #endif
  66 #endif
  67 #endif
  68 #endif
  69
  70 #if defined NEED_CANCELLATION && defined CENABLE
  71         SINGLE_THREAD_P
  72         cmp %g1, 0
  73         bne .Lsocket_cancel
  74 #endif
  75          mov P(SOCKOP_,socket), %o0     /* arg 1: socket subfunction */
  76         add %sp, 68, %o1                /* arg 2: parameter block */
  77         LOADSYSCALL(socketcall)
  78         t 0x10
  79         bcc 1f
  80          mov %o7, %g1
  81         call __syscall_error
  82          mov %g1, %o7
  83 1:      jmpl %o7 + 8, %g0
  84          nop
  85
  86 #if defined NEED_CANCELLATION && defined CENABLE
  87 .Lsocket_cancel:
  88         save %sp, -96, %sp
  89         cfi_def_cfa_register(%fp)
  90         cfi_window_save
  91         cfi_register(%o7, %i7)
  92         CENABLE
  93          nop
  94         mov %o0, %l0
  95         add %sp, 68 + 96, %o1
  96         mov P(SOCKOP_,socket), %o0
  97         LOADSYSCALL(socketcall)
  98         t 0x10
  99         bcc 1f
 100          mov %o0, %l1
 101         CDISABLE;
 102          mov %l0, %o0;
 103         call __syscall_error;
 104          mov %l1, %o0;
 105         b 1f
 106          mov -1, %l1;
 107 1:      CDISABLE
 108          mov %l0, %o0
 109 2:      jmpl %i7 + 8, %g0
 110          restore %g0, %l1, %o0
 111 #endif
 112
 113 END (__socket)
 114
 115 #ifndef NO_WEAK_ALIAS
 116 weak_alias (__socket, socket)
 117 #endif