sysdeps/unix/sysv/linux/sparc/sparc32/getcontext.S

   1 /* Save current context.
   2    Copyright (C) 2008 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2008.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22
  23 #include "ucontext_i.h"
  24
  25 /*  int __getcontext (ucontext_t *ucp)
  26
  27   Saves the machine context in UCP such that when it is activated,
  28   it appears as if __getcontext() returned again.
  29
  30   This implementation is intended to be used for *synchronous* context
  31   switches only.  Therefore, it does not have to save anything
  32   other than the PRESERVED state.  */
  33
  34
  35 ENTRY(__getcontext)
  36         save    %sp, -112, %sp
  37         st      %g0, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_PSR]
  38
  39         /* In reality, we only use the GREG_PC value when setting
  40            or swapping contexts.  But we fill in NPC for completeness.  */
  41         add     %i7, 8, %o0
  42         st      %o0, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_PC]
  43         add     %o0, 4, %o0
  44         st      %o0, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_NPC]
  45
  46         rd      %y, %o1
  47         st      %o1, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_Y]
  48
  49         st      %g1, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_G1]
  50         st      %g2, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_G2]
  51         st      %g3, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_G3]
  52         st      %g4, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_G4]
  53         st      %g5, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_G5]
  54         st      %g6, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_G6]
  55         st      %g7, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_G7]
  56
  57         mov     SIG_BLOCK, %o0
  58         clr     %o1
  59         add     %i0, UC_SIGMASK, %o2
  60         mov     8, %o3
  61         mov     __NR_rt_sigprocmask, %g1
  62         ta      0x10
  63
  64         /* Zero, success, return value.  */
  65         st      %g0, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O0]
  66         st      %i1, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O1]
  67         st      %i2, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O2]
  68         st      %i3, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O3]
  69         st      %i4, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O4]
  70         st      %i5, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O5]
  71         st      %i6, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O6]
  72         st      %i7, [%i0 + UC_MCONTEXT + MC_GREGS + GREG_O7]
  73
  74         st      %g0, [%i0 + UC_MCONTEXT + MC_GWINS]
  75
  76         /* Do not save FPU state, it is volatile across calls.  */
  77         stb     %g0, [%i0 + UC_MCONTEXT + MC_FPREGS + FPU_EN]
  78
  79         st      %g0, [%i0 + UC_MCONTEXT + MC_XRS + XRS_ID]
  80         st      %g0, [%i0 + UC_MCONTEXT + MC_XRS + XRS_PTR]
  81         jmpl    %i7 + 8, %g0
  82          restore %g0, %g0, %o0
  83 END(__getcontext)
  84
  85 weak_alias (__getcontext, getcontext)