sysdeps/unix/sysv/linux/sh/sh3/getcontext.S

   1 /* Save current context.
   2    Copyright (C) 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  int __getcontext (ucontext_t *uc);  */
  25
  26         .text
  27         .align  5
  28 ENTRY(__getcontext)
  29
  30         /* Return value of getcontext.  R0 is the only register whose
  31            value is not preserved.  */
  32         mov     #0, r0
  33         mov.l   r0, @(oR0,r4)
  34         mov.l   r1, @(oR1,r4)
  35         mov.l   r2, @(oR2,r4)
  36         mov.l   r3, @(oR3,r4)
  37         mov.l   r4, @(oR4,r4)
  38         mov.l   r5, @(oR5,r4)
  39         mov.l   r6, @(oR6,r4)
  40         mov.l   r7, @(oR7,r4)
  41         mov     r4, r0
  42         add     #(oMACL+4), r0
  43         sts.l   macl, @-r0
  44         sts.l   mach, @-r0
  45         stc.l   gbr, @-r0
  46
  47         /* Save T flag to SR.  */
  48         movt    r1
  49         mov.l   r1, @-r0
  50         sts.l   pr, @-r0
  51
  52         /* The return address of getcontext is the restart pc.  */
  53         sts.l   pr, @-r0
  54
  55         mov.l   r15, @-r0
  56         mov.l   r14, @-r0
  57         mov.l   r13, @-r0
  58         mov.l   r12, @-r0
  59         mov.l   r11, @-r0
  60         mov.l   r10, @-r0
  61         mov.l   r9, @-r0
  62         mov.l   r8, @-r0
  63
  64         /* sigprocmask (SIG_BLOCK, NULL, &uc->uc_sigmask).  */
  65         mov     r4, r6
  66         add     #oSIGMASK, r6
  67         mov     #SIG_BLOCK, r4
  68         mov     #0, r5
  69         mov     #+SYS_ify(sigprocmask), r3
  70         trapa   #0x13
  71         mov     r0, r1
  72         mov     #-12, r2
  73         shad    r2, r1
  74         not     r1, r1                  // r1=0 means r0 = -1 to -4095
  75         tst     r1, r1                  // i.e. error in linux
  76         bf      .Lgetcontext_end
  77 .Lsyscall_error:
  78         SYSCALL_ERROR_HANDLER
  79 .Lgetcontext_end:
  80         /* All done, return 0 for success.  */
  81         mov     #0, r0
  82 .Lpseudo_end:
  83         rts
  84          nop
  85
  86 PSEUDO_END(__getcontext)
  87
  88 weak_alias (__getcontext, getcontext)