sysdeps/unix/sysv/linux/s390/s390-64/syscall.S

   1 /* Copyright (C) 2001, 2006 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22 /* Please consult the file sysdeps/unix/sysv/linux/s390/sysdep.h for
  23    more information about the value -4095 used below.*/
  24
  25 ENTRY (syscall)
  26         /* Save registers and setup stack.  */
  27         stmg    %r6,%r15,48(%r15)  /* Save registers.  */
  28         cfi_offset (%r15,-40)
  29         cfi_offset (%r14,-48)
  30         cfi_offset (%r13,-56)
  31         cfi_offset (%r12,-64)
  32         cfi_offset (%r11,-72)
  33         cfi_offset (%r10,-80)
  34         cfi_offset (%r9,-88)
  35         cfi_offset (%r8,-96)
  36         cfi_offset (%r7,-104)
  37         cfi_offset (%r6,-112)
  38         lgr     %r1,%r15
  39         lg      %r0,8(%r15)        /* Load eos.  */
  40         aghi    %r15,-160          /* Buy stack space.  */
  41         cfi_adjust_cfa_offset (160)
  42         stg     %r1,0(%r15)        /* Store back chain.  */
  43         stg     %r0,8(%r15)        /* Store eos.  */
  44
  45         lgr    %r1,%r2             /* Move syscall number.  */
  46         lgr    %r2,%r3             /* First parameter.  */
  47         lgr    %r3,%r4             /* Second parameter.  */
  48         lgr    %r4,%r5             /* Third parameter.  */
  49         lgr    %r5,%r6             /* Fourth parameter.  */
  50         lg     %r6,320(%r15)       /* Fifth parameter.  */
  51         lg     %r7,328(%r15)       /* Sixth parameter.  */
  52
  53         basr   %r8,0
  54 0:      clg    %r1,4f-0b(%r8)      /* svc number < 256? */
  55         jl     2f
  56 1:      svc    0
  57         j      3f
  58 2:      ex     %r1,1b-0b(%r8)      /* lsb of R1 is subsituted as SVC number */
  59 3:      lg     %r15,0(%r15)        /* load back chain */
  60         cfi_adjust_cfa_offset (-160)
  61         lmg     %r6,15,48(%r15)    /* Load registers.  */
  62
  63         lghi   %r0,-4095
  64         clgr   %r2,%r0             /* Check R2 for error.  */
  65         jgnl   SYSCALL_ERROR_LABEL
  66         br     %r14                /* Return to caller.  */
  67 4:      .quad  256
  68 PSEUDO_END (syscall)
  69