sysdeps/unix/sysv/linux/s390/s390-64/clone.S

   1 /* Wrapper around clone system call.  64 bit S/390 version.
   2    Copyright (C) 2001, 2003, 2004 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 /* clone is even more special than fork as it mucks with stacks
  22    and invokes a function in the right context after its all over.  */
  23
  24 #include <sysdep.h>
  25 #include <tls.h>
  26 #define _ERRNO_H        1
  27 #include <bits/errno.h>
  28
  29 /* int __clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  30                pid_t *parent_tid, void *tls, pid_t *child_tid);  */
  31 /* sys_clone  (void *child_stack, unsigned long flags,
  32                pid_t *parent_tid, pid_t *child_tid, void *tls);  */
  33
  34         .text
  35 ENTRY(__clone)
  36         stg     %r6,48(%r15)            /* store %r6 to save area */
  37         cfi_offset (%r6,-112)
  38         lgr     %r0,%r5                 /* move *arg out of the way */
  39         ltgr    %r1,%r2                 /* check fn and move to %r1 */
  40         jz      error                   /* no NULL function pointers */
  41         ltgr    %r2,%r3                 /* check child_stack and move to %r2 */
  42         jz      error                   /* no NULL stack pointers */
  43         lgr     %r3,%r4                 /* move flags to %r3 */
  44         lgr     %r4,%r6                 /* move parent_tid to %r4 */
  45         lg      %r5,168(%r15)           /* load child_tid from stack */
  46         lg      %r6,160(%r15)           /* load tls from stack */
  47         svc     SYS_ify(clone)
  48         ltgr    %r2,%r2                 /* check return code */
  49         jz      thread_start
  50         lg      %r6,48(%r15)            /* restore %r6 */
  51         jgm     SYSCALL_ERROR_LABEL
  52         br      %r14
  53 error:
  54         lghi    %r2,-EINVAL
  55         jg      SYSCALL_ERROR_LABEL
  56 PSEUDO_END (__clone)
  57
  58 thread_start:
  59 #ifdef RESET_PID
  60         tmh     %r3,1           /* CLONE_THREAD == 0x00010000 */
  61         jne     1f
  62         lhi     %r2,-1
  63         tml     %r3,256         /* CLONE_VM == 0x00000100 */
  64         jne     2f
  65         svc     SYS_ify(getpid)
  66 2:      ear     %r3,%a0
  67         sllg    %r3,%r3,32
  68         ear     %r3,%a1
  69         st      %r2,PID(%r3)
  70         st      %r2,TID(%r3)
  71 1:
  72 #endif
  73         /* fn is in gpr 1, arg in gpr 0 */
  74         lgr     %r2,%r0         /* set first parameter to void *arg */
  75         aghi    %r15,-160       /* make room on the stack for the save area */
  76         xc      0(8,%r15),0(%r15)
  77         basr    %r14,%r1        /* jump to fn */
  78         DO_CALL (exit, 1)
  79 weak_alias (__clone, clone)