sysdeps/unix/sysv/linux/s390/s390-32/socket.S

   1 /* Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep-cancel.h>
  21 #include <socketcall.h>
  22
  23 /* &%/$&!! preprocessor */
  24 #define P(a, b) P2(a, b)
  25 #define P2(a, b) a##b
  26
  27         .text
  28 /* The socket-oriented system calls are handled unusally in Linux.
  29    They are all gated through the single `socketcall' system call number.
  30    `socketcall' takes two arguments: the first is the subcode, specifying
  31    which socket function is being called; and the second is a pointer to
  32    the arguments to the specific function.
  33
  34    The .S files for the other calls just #define socket and #include this.  */
  35
  36 #ifndef __socket
  37 #ifndef NO_WEAK_ALIAS
  38 #define __socket P(__,socket)
  39 #else
  40 #define __socket socket
  41 #endif
  42 #endif
  43
  44 #ifndef NARGS      /* the socket.o object is compiled directly ... */
  45 #define NARGS 3
  46 #endif
  47
  48 .globl __socket
  49 ENTRY(__socket)
  50         /* Save registers and setup stack.  */
  51         stm     %r6,%r15,24(%r15)       /* save registers */
  52         cfi_offset (%r15, -36)
  53         cfi_offset (%r14, -40)
  54         cfi_offset (%r13, -44)
  55         cfi_offset (%r12, -48)
  56         cfi_offset (%r11, -52)
  57         cfi_offset (%r10, -56)
  58         cfi_offset (%r9, -60)
  59         cfi_offset (%r8, -64)
  60         cfi_offset (%r7, -68)
  61         cfi_offset (%r6, -72)
  62         lr      %r1,%r15
  63         l       %r0,4(0,%r15)           /* load eos */
  64         ahi     %r15,-120               /* buy stack space */
  65         cfi_adjust_cfa_offset (120)
  66         st      %r1,0(0,%r15)           /* store back chain */
  67         st      %r0,4(0,%r15)           /* store eos */
  68
  69         /* Reorder arguments */
  70 #if (NARGS >= 6)
  71         mvc     0x74(4,%r15),216(%r15)  /* move between parameter lists */
  72 #endif
  73 #if (NARGS >= 5)
  74         st      %r6,0x70(0,%r15)        /* store into parameter list */
  75 #endif
  76 #if (NARGS >= 4)
  77         st      %r5,0x6C(0,%r15)        /* store into parameter list */
  78 #endif
  79 #if (NARGS >= 3)
  80         st      %r4,0x68(0,%r15)        /* store into parameter list */
  81 #endif
  82 #if (NARGS >= 2)
  83         st      %r3,0x64(0,%r15)        /* store into parameter list */
  84         st      %r2,0x60(0,%r15)
  85 #endif
  86
  87 #if defined NEED_CANCELLATION && defined CENABLE
  88         SINGLE_THREAD_P (%r4)
  89         jne     L(socket_cancel)
  90 #endif
  91
  92         /* load subcode for socket syscall */
  93         lhi     %r2,P(SOCKOP_,socket)
  94         la      %r3,0x60(0,%r15)        /* load address of parameter list */
  95
  96         /* Do the system call trap.  */
  97         svc     SYS_ify(socketcall)
  98
  99 4:
 100         l       %r15,0(0,%r15)          /* load back chain */
 101         lm      %r6,15,24(%r15)         /* load registers */
 102
 103         /* gpr2 is < 0 if there was an error.  */
 104         lhi     %r0,-125
 105         clr     %r2,%r0
 106         jnl     SYSCALL_ERROR_LABEL
 107
 108         /* Successful; return the syscall's value.  */
 109         br      %r14
 110
 111 #if defined NEED_CANCELLATION && defined CENABLE
 112 L(socket_cancel):
 113         basr    %r13,0
 114 1:      l       %r1,2f-1b(%r13)
 115         /* call CENABLE.  */
 116         bas     %r14,0(%r13,%r1)
 117         lr      %r0,%r2
 118
 119         /* load subcode for socket syscall */
 120         lhi     %r2,P(SOCKOP_,socket)
 121         la      %r3,0x60(0,%r15)        /* load address of parameter list */
 122
 123         /* Do the system call trap.  */
 124         svc     SYS_ify(socketcall)
 125
 126         l       %r3,3f-1b(%r13)
 127         lr      %r12,%r2
 128         lr      %r2,%r0
 129         /* call CDISABLE.  */
 130         bas     %r14,0(%r13,%r3)
 131         lr      %r2,%r12
 132         j       4b
 133
 134 2:      .long   CENABLE-1b
 135 3:      .long   CDISABLE-1b
 136 #endif
 137
 138         SYSCALL_ERROR_HANDLER
 139 END (__socket)
 140
 141 #ifndef NO_WEAK_ALIAS
 142 weak_alias (__socket, socket)
 143 #endif