sysdeps/unix/sysv/linux/s390/s390-32/mmap64.S

   1 /* Copyright (C) 2000, 2001, 2007 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <kernel-features.h>
  22
  23 #define EINVAL  22
  24 #define ENOSYS  38
  25
  26         .text
  27 ENTRY(__mmap64)
  28         /* Save registers and setup stack frame.  */
  29         stm     %r6,%r15,24(%r15)
  30         cfi_offset (%r15, -36)
  31         cfi_offset (%r14, -40)
  32         cfi_offset (%r13, -44)
  33         cfi_offset (%r12, -48)
  34         cfi_offset (%r11, -52)
  35         cfi_offset (%r10, -56)
  36         cfi_offset (%r9, -60)
  37         cfi_offset (%r8, -64)
  38         cfi_offset (%r7, -68)
  39         cfi_offset (%r6, -72)
  40         lr      %r1,%r15
  41         ahi     %r15,-120               /* Buy stack space.   */
  42         cfi_adjust_cfa_offset (120)
  43         st      %r1,0(%r15)             /* Store back chain.  */
  44
  45         /* Store parameters on stack, because mmap2 and old_mmap
  46          * take only one parameter: a pointer to the parameter area.  */
  47         st      %r6,0x70(%r15)          /* Store 'fd'.      */
  48         st      %r5,0x6C(%r15)          /* Store 'flags'.   */
  49         st      %r4,0x68(%r15)          /* Store 'prot'.    */
  50         st      %r3,0x64(%r15)          /* Store 'length'.  */
  51         st      %r2,0x60(%r15)          /* Store 'start'.   */
  52
  53 #ifdef __NR_mmap2
  54         lm      %r0,%r1,216(%r15)       /* Load 64 bit offset.  */
  55         tml     %r1,0x0fff              /* Offset page aligned ?  */
  56         jnz     2f                      /* No -> EINVAL.  */
  57         srdl    %r0,12                  /* mmap2 takes the offset in pages.  */
  58         ltr     %r0,%r0                 /* Offset > 2^44 ?  */
  59         jnz     2f
  60         st      %r1,0x74(%r15)          /* Store page offset.  */
  61
  62         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  63         svc     SYS_ify(mmap2)          /* Do the system call trap.  */
  64
  65 #ifndef __ASSUME_MMAP2_SYSCALL
  66         chi     %r2,-ENOSYS
  67         je      1f
  68 #endif
  69
  70         l       %r15,0(%r15)            /* Load back chain.  */
  71         cfi_adjust_cfa_offset (-120)
  72         lm      %r6,%r15,24(%r15)       /* Load registers.  */
  73
  74         /* Check gpr 2 for error.  */
  75         lhi     %r0,-4096
  76         clr     %r2,%r0
  77         jnl     SYSCALL_ERROR_LABEL
  78
  79         /* Successful; return the syscall's value.  */
  80         br      %r14
  81
  82 #endif
  83
  84 #if !defined __ASSUME_MMAP2_SYSCALL || !defined __NR_mmap2
  85 1:      lm      %r0,%r1,216(%r15)       /* Load 64 bit offset.  */
  86         st      %r1,0x74(%r15)          /* Store lower word of offset.  */
  87         ltr     %r0,%r0                 /* Offset > 2^32 ?  */
  88         jnz     2f
  89         alr     %r1,%r3                 /* Add length to offset.  */
  90         brc     3,2f                    /* Carry -> EINVAL.  */
  91
  92         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  93         svc     SYS_ify(mmap)   /* Do the system call trap.  */
  94
  95         l       %r15,0(%r15)            /* Load back chain.  */
  96         lm      %r6,%r15,24(%r15)       /* Load registers.  */
  97
  98         /* Check gpr 2 for error.  */
  99         lhi     %r0,-4096
 100         clr     %r2,%r0
 101         jnl     SYSCALL_ERROR_LABEL
 102
 103         /* Successful; return the syscall's value.  */
 104         br      %r14
 105 #endif
 106
 107 2:      lhi     %r2,-EINVAL
 108         l       %r15,0(%r15)            /* Load back chain.  */
 109         lm      %r6,%r15,24(%r15)       /* Load registers.  */
 110         j       SYSCALL_ERROR_LABEL
 111
 112 PSEUDO_END (__mmap64)
 113
 114 weak_alias (__mmap64, mmap64)