sysdeps/unix/sysv/linux/s390/s390-32/mmap.S

   1 /* Copyright (C) 2000, 2001, 2007 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <kernel-features.h>
  22
  23 #define EINVAL  22
  24
  25         .text
  26 ENTRY(__mmap)
  27         /* Save registers and setup stack frame.  */
  28         stm     %r6,%r15,24(%r15)
  29         cfi_offset (%r15, -36)
  30         cfi_offset (%r14, -40)
  31         cfi_offset (%r13, -44)
  32         cfi_offset (%r12, -48)
  33         cfi_offset (%r11, -52)
  34         cfi_offset (%r10, -56)
  35         cfi_offset (%r9, -60)
  36         cfi_offset (%r8, -64)
  37         cfi_offset (%r7, -68)
  38         cfi_offset (%r6, -72)
  39         lr      %r1,%r15
  40         ahi     %r15,-120               /* buy stack space */
  41         cfi_adjust_cfa_offset (120)
  42         st      %r1,0(%r15)             /* store back chain */
  43
  44         /* Store parameters on stack, because old_mmap/mmap2
  45          * take only one parameter: a pointer to the parameter area
  46          */
  47         st      %r6,0x70(%r15)          /* Store 'fd'.      */
  48         st      %r5,0x6C(%r15)          /* Store 'flags'.   */
  49         st      %r4,0x68(%r15)          /* Store 'prot'.    */
  50         st      %r3,0x64(%r15)          /* Store 'length'.  */
  51         st      %r2,0x60(%r15)          /* Store 'start'.   */
  52         l       %r1,216(%r15)           /* Load offset.     */
  53
  54 #ifdef __ASSUME_MMAP2_SYSCALL
  55         /* I don't think it is worthwhile trying to use mmap2 whenever
  56          * it is available.  Only use it when we are sure the syscall
  57          * exists.  */
  58         tml     %r1,0x0fff              /* Offset page aligned ?  */
  59         lhi     %r2,-EINVAL
  60         jnz     1f                      /* No -> EINVAL.  */
  61         srl     %r1,12                  /* mmap2 takes the offset in pages.  */
  62         st      %r1,0x74(%r15)          /* Store page offset.  */
  63         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  64         svc     SYS_ify(mmap2)          /* Do the system call trap.  */
  65 #else
  66         st      %r1,0x74(%r15)          /* Store offset unmodified.  */
  67         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  68         svc     SYS_ify(mmap)           /* Do the system call trap.  */
  69 #endif
  70
  71 1:      l       %r15,0(%r15)            /* Load back chain.  */
  72         cfi_adjust_cfa_offset (-120)
  73         lm      %r6,%r15,24(%r15)       /* Load registers.  */
  74
  75         /* check gpr 2 for error */
  76         lhi     %r0,-4096
  77         clr     %r2,%r0
  78         jnl     SYSCALL_ERROR_LABEL
  79
  80         /* Successful; return the syscall's value.  */
  81         br      %r14
  82
  83 PSEUDO_END (__mmap)
  84
  85 weak_alias (__mmap, mmap)