sysdeps/unix/sysv/linux/s390/s390-32/clone.S

   1 /* Copyright (C) 2000, 2001, 2004 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* clone is even more special than fork as it mucks with stacks
  21    and invokes a function in the right context after its all over.  */
  22
  23 #include <sysdep.h>
  24 #include <tls.h>
  25 #define _ERRNO_H        1
  26 #include <bits/errno.h>
  27
  28 /* int __clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  29                pid_t *parent_tid, void *tls, pid_t *child_tid);  */
  30 /* sys_clone  (void *child_stack, unsigned long flags,
  31                pid_t *parent_tid, pid_t *child_tid, void *tls);  */
  32
  33         .text
  34 ENTRY(__clone)
  35         st      %r6,24(%r15)            /* store %r6 to save area */
  36         cfi_offset (%r6, -72)
  37         lr      %r0,%r5                 /* move *arg out of the way */
  38         ltr     %r1,%r2                 /* check fn and move to %r1 */
  39         jz      error                   /* no NULL function pointers */
  40         ltr     %r2,%r3                 /* check child_stack and move to %r2 */
  41         jz      error                   /* no NULL stack pointers */
  42         lr      %r3,%r4                 /* move flags to %r3 */
  43         lr      %r4,%r6                 /* move parent_tid to %r4 */
  44         l       %r5,100(%r15)           /* load child_tid from stack */
  45         l       %r6,96(%r15)            /* load tls from stack */
  46         svc     SYS_ify(clone)
  47         ltr     %r2,%r2                 /* check return code */
  48         jz      thread_start
  49         l       %r6,24(%r15)            /* restore %r6 */
  50         jm      SYSCALL_ERROR_LABEL
  51         br      %r14
  52 error:
  53         lhi     %r2,-EINVAL
  54         j       SYSCALL_ERROR_LABEL
  55 PSEUDO_END (__clone)
  56
  57 thread_start:
  58 #ifdef RESET_PID
  59         tmh     %r3,1           /* CLONE_THREAD == 0x00010000 */
  60         jne     1f
  61         lhi     %r2,-1
  62         tml     %r3,256         /* CLONE_VM == 0x00000100 */
  63         jne     2f
  64         svc     SYS_ify(getpid)
  65 2:      ear     %r3,%a0
  66         st      %r2,PID(%r3)
  67         st      %r2,TID(%r3)
  68 1:
  69 #endif
  70         /* fn is in gpr 1, arg in gpr 0 */
  71         lr      %r2,%r0         /* set first parameter to void *arg */
  72         ahi     %r15,-96        /* make room on the stack for the save area */
  73         xc      0(4,%r15),0(%r15)
  74         basr    %r14,%r1        /* jump to fn */
  75         DO_CALL (exit, 1)
  76 weak_alias (__clone, clone)