sysdeps/unix/sysv/linux/alpha/settimeofday.S

   1 /* Copyright (C) 1998, 2003, 2006 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <kernel-features.h>
  23
  24 .text
  25
  26 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
  27 #define SETTIMEOFDAY    __settimeofday_tv64
  28 #else
  29 #define SETTIMEOFDAY    __settimeofday
  30 #endif
  31
  32 #if defined __ASSUME_TIMEVAL64
  33 PSEUDO(SETTIMEOFDAY, settimeofday, 2)
  34         ret
  35 PSEUDO_END(SETTIMEOFDAY)
  36 #else
  37 /* The problem here is that initially we made struct timeval compatible with
  38    OSF/1, using int32.  But we defined time_t with uint64, and later found
  39    that POSIX requires tv_sec to be time_t.
  40
  41    So now we have to do compatibility stuff.  */
  42
  43 /* The variable is shared between all wrappers around signal handling
  44    functions which have RT equivalents.  */
  45 .comm __libc_missing_axp_tv64, 4
  46
  47 LEAF(SETTIMEOFDAY, 16)
  48         ldgp    gp, 0(pv)
  49         subq    sp, 16, sp
  50 #ifdef PROF
  51         .set noat
  52         lda     AT, _mcount
  53         jsr     AT, (AT), _mcount
  54         .set at
  55 #endif
  56         .prologue 1
  57
  58         ldl     t0, __libc_missing_axp_tv64
  59         bne     t0, $do32
  60
  61         /* Save arguments in case we do need to fall back.  */
  62         stq     a0, 0(sp)
  63         stq     a1, 8(sp)
  64
  65         ldi     v0, SYS_ify(settimeofday)
  66         callsys
  67         bne     a3, $err64
  68
  69         /* Everything ok.  */
  70         addq    sp, 16, sp
  71         ret
  72
  73         /* If we didn't get ENOSYS, it is a real error.  */
  74         .align 3
  75 $err64: cmpeq   v0, ENOSYS, t0
  76         beq     t0, $error
  77         stl     t0, __libc_missing_axp_tv64
  78
  79         /* Recover the saved arguments.  */
  80         ldq     a1, 8(sp)
  81         ldq     a0, 0(sp)
  82
  83         .align 3
  84 $do32:
  85         /* Conditionally bounce the timeval down.  */
  86         beq     a0, 1f
  87         ldq     t0, 0(a0)
  88         ldq     t1, 8(a0)
  89         stl     t0, 0(sp)
  90         stl     t1, 4(sp)
  91         mov     sp, a0
  92
  93 1:      ldi     v0, SYS_ify(osf_settimeofday)
  94         callsys
  95         bne     a3, $error
  96
  97         addq    sp, 16, sp
  98         ret
  99
 100         .align 3
 101 $error:
 102         addq    sp, 16, sp
 103         SYSCALL_ERROR_HANDLER
 104
 105 END(SETTIMEOFDAY)
 106 #endif /* __ASSUME_TIMEVAL64 */
 107
 108 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
 109 default_symbol_version (__settimeofday_tv64, __settimeofday, GLIBC_2.1)
 110
 111 /* It seems to me to be a misfeature of the assembler that we can only
 112    have one version-alias per symbol.  So create an alias ourselves.
 113    The 'p' is for 'public'.  *Shrug*  */
 114 strong_alias (__settimeofday_tv64, __settimeofday_tv64p)
 115 default_symbol_version (__settimeofday_tv64p, settimeofday, GLIBC_2.1)
 116 #else
 117 weak_alias (__settimeofday, settimeofday)
 118 #endif