sysdeps/sparc/sparc64/lshift.S

   1 /* SPARC v9 __mpn_lshift --
   2
   3    Copyright (C) 1996, 1999 Free Software Foundation, Inc.
   4
   5    This file is part of the GNU MP Library.
   6
   7    The GNU MP Library is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU Lesser General Public License as published by
   9    the Free Software Foundation; either version 2.1 of the License, or (at your
  10    option) any later version.
  11
  12    The GNU MP Library is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15    License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public License
  18    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20    MA 02111-1307, USA.  */
  21
  22 #include <sysdep.h>
  23
  24 /* INPUT PARAMETERS
  25    res_ptr      %o0
  26    src_ptr      %o1
  27    size         %o2
  28    cnt          %o3  */
  29
  30         .register       %g2, #scratch
  31         .register       %g3, #scratch
  32
  33 ENTRY(__mpn_lshift)
  34         sllx    %o2,3,%g1
  35         add     %o1,%g1,%o1     ! make %o1 point at end of src
  36         ldx     [%o1-8],%g2     ! load first limb
  37         sub     %g0,%o3,%o5     ! negate shift count
  38         add     %o0,%g1,%o0     ! make %o0 point at end of res
  39         add     %o2,-1,%o2
  40         andcc   %o2,4-1,%g4     ! number of limbs in first loop
  41         srlx    %g2,%o5,%g1     ! compute function result
  42         be,pn   %xcc,.L0        ! if multiple of 4 limbs, skip first loop
  43          mov    %g1,%g5
  44
  45         sub     %o2,%g4,%o2     ! adjust count for main loop
  46
  47 .Loop0: ldx     [%o1-16],%g3
  48         add     %o0,-8,%o0
  49         add     %o1,-8,%o1
  50         sllx    %g2,%o3,%o4
  51         addcc   %g4,-1,%g4
  52         srlx    %g3,%o5,%g1
  53         mov     %g3,%g2
  54         or      %o4,%g1,%o4
  55         bne,pt  %xcc,.Loop0
  56          stx    %o4,[%o0+0]
  57
  58 .L0:    brz,pn  %o2,.Lend
  59          nop
  60
  61 .Loop:  ldx     [%o1-16],%g3
  62         add     %o0,-32,%o0
  63         sllx    %g2,%o3,%o4
  64         addcc   %o2,-4,%o2
  65         srlx    %g3,%o5,%g1
  66
  67         ldx     [%o1-24],%g2
  68         sllx    %g3,%o3,%g4
  69         or      %o4,%g1,%o4
  70         stx     %o4,[%o0+24]
  71         srlx    %g2,%o5,%g1
  72
  73         ldx     [%o1-32],%g3
  74         sllx    %g2,%o3,%o4
  75         or      %g4,%g1,%g4
  76         stx     %g4,[%o0+16]
  77         srlx    %g3,%o5,%g1
  78
  79         ldx     [%o1-40],%g2
  80         sllx    %g3,%o3,%g4
  81         or      %o4,%g1,%o4
  82         stx     %o4,[%o0+8]
  83         srlx    %g2,%o5,%g1
  84
  85         add     %o1,-32,%o1
  86         or      %g4,%g1,%g4
  87         bne,pt  %xcc,.Loop
  88          stx    %g4,[%o0+0]
  89
  90 .Lend:  sllx    %g2,%o3,%g2
  91         stx     %g2,[%o0-8]
  92
  93         jmpl    %o7+8, %g0
  94          mov    %g5,%o0
  95
  96 END(__mpn_lshift)