sysdeps/sparc/sparc32/lshift.S

   1 ! Sparc __mpn_lshift --
   2 !
   3 ! Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
   4 !
   5 ! This file is part of the GNU MP Library.
   6 !
   7 ! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ! it under the terms of the GNU Lesser General Public License as published by
   9 ! the Free Software Foundation; either version 2.1 of the License, or (at your
  10 ! option) any later version.
  11 !
  12 ! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15 ! License for more details.
  16 !
  17 ! You should have received a copy of the GNU Lesser General Public License
  18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ! MA 02111-1307, USA.
  21
  22
  23 ! INPUT PARAMETERS
  24 ! RES_PTR       %o0
  25 ! SRC_PTR       %o1
  26 ! SIZE          %o2
  27 ! CNT           %o3
  28
  29 #include <sysdep.h>
  30
  31 ENTRY(__mpn_lshift)
  32         sll     %o2,2,%g1
  33         add     %o1,%g1,%o1     ! make %o1 point at end of src
  34         ld      [%o1-4],%g2     ! load first limb
  35         sub     %g0,%o3,%o5     ! negate shift count
  36         add     %o0,%g1,%o0     ! make %o0 point at end of res
  37         add     %o2,-1,%o2
  38         andcc   %o2,4-1,%g4     ! number of limbs in first loop
  39         srl     %g2,%o5,%g1     ! compute function result
  40         be      LOC(0)          ! if multiple of 4 limbs, skip first loop
  41         st      %g1,[%sp+80]
  42
  43         sub     %o2,%g4,%o2     ! adjust count for main loop
  44
  45 LOC(loop0):
  46         ld      [%o1-8],%g3
  47         add     %o0,-4,%o0
  48         add     %o1,-4,%o1
  49         addcc   %g4,-1,%g4
  50         sll     %g2,%o3,%o4
  51         srl     %g3,%o5,%g1
  52         mov     %g3,%g2
  53         or      %o4,%g1,%o4
  54         bne     LOC(loop0)
  55          st     %o4,[%o0+0]
  56
  57 LOC(0): tst     %o2
  58         be      LOC(end)
  59          nop
  60
  61 LOC(loop):
  62         ld      [%o1-8],%g3
  63         add     %o0,-16,%o0
  64         addcc   %o2,-4,%o2
  65         sll     %g2,%o3,%o4
  66         srl     %g3,%o5,%g1
  67
  68         ld      [%o1-12],%g2
  69         sll     %g3,%o3,%g4
  70         or      %o4,%g1,%o4
  71         st      %o4,[%o0+12]
  72         srl     %g2,%o5,%g1
  73
  74         ld      [%o1-16],%g3
  75         sll     %g2,%o3,%o4
  76         or      %g4,%g1,%g4
  77         st      %g4,[%o0+8]
  78         srl     %g3,%o5,%g1
  79
  80         ld      [%o1-20],%g2
  81         sll     %g3,%o3,%g4
  82         or      %o4,%g1,%o4
  83         st      %o4,[%o0+4]
  84         srl     %g2,%o5,%g1
  85
  86         add     %o1,-16,%o1
  87         or      %g4,%g1,%g4
  88         bne     LOC(loop)
  89          st     %g4,[%o0+0]
  90
  91 LOC(end):
  92         sll     %g2,%o3,%g2
  93         st      %g2,[%o0-4]
  94         retl
  95         ld      [%sp+80],%o0
  96
  97 END(__mpn_lshift)