sysdeps/s390/s390-32/elf/start.S

   1 /* Startup code compliant to the ELF s390 ABI.
   2    Copyright (C) 2000, 2001, 2002, 2003, 2004, 2006
   3    Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    In addition to the permissions in the GNU Lesser General Public
  13    License, the Free Software Foundation gives you unlimited
  14    permission to link the compiled version of this file with other
  15    programs, and to distribute those programs without any restriction
  16    coming from the use of this file. (The GNU Lesser General Public
  17    License restrictions do apply in other respects; for example, they
  18    cover modification of the file, and distribution when not linked
  19    into another program.)
  20
  21    Note that people who make modified versions of this file are not
  22    obligated to grant this special exception for their modified
  23    versions; it is their choice whether to do so. The GNU Lesser
  24    General Public License gives permission to release a modified
  25    version without this exception; this exception also makes it
  26    possible to release a modified version which carries forward this
  27    exception.
  28
  29    The GNU C Library is distributed in the hope that it will be useful,
  30    but WITHOUT ANY WARRANTY; without even the implied warranty of
  31    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  32    Lesser General Public License for more details.
  33
  34    You should have received a copy of the GNU Lesser General Public
  35    License along with the GNU C Library; if not, write to the Free
  36    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  37    02111-1307 USA.  */
  38
  39 /*
  40    This is the canonical entry point, usually the first thing in the text
  41    segment. Most registers' values are unspecified, except for:
  42
  43    %r14         Contains a function pointer to be registered with `atexit'.
  44                 This is how the dynamic linker arranges to have DT_FINI
  45                 functions called for shared libraries that have been loaded
  46                 before this code runs.
  47
  48    %r15         The stack contains the arguments and environment:
  49                 0(%r15)                 argc
  50                 4(%r15)                 argv[0]
  51                 ...
  52                 (4*argc)(%r15)          NULL
  53                 (4*(argc+1))(%r15)      envp[0]
  54                 ...
  55                                         NULL
  56 */
  57
  58         .text
  59         .globl _start
  60         .type _start,@function
  61 _start:
  62         /* Setup pointer to literal pool of _start */
  63         basr    %r13,0
  64 .L0:    ahi     %r13,.Llit-.L0
  65
  66         /* load argc and argv from stack */
  67         la      %r4,4(%r15)             # get argv
  68         l       %r3,0(%r15)             # get argc
  69
  70         /* align the stack to a double word boundary */
  71         lhi     %r0,-8
  72         nr      %r15,%r0
  73
  74         /* Setup a stack frame and a parameter area */
  75         ahi     %r15,-104               # make room on stack
  76         xc      0(4,%r15),0(%r15)       # clear back-chain
  77
  78         /* set up arguments for __libc_start_main:
  79            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
  80            Note that envp will be determined later in __libc_start_main
  81          */
  82         stm     %r14,%r15,96(%r15)      # store rtld_fini/stack_end to parameter area
  83         la      %r7,96(%r15)
  84         l       %r6,.L2-.Llit(%r13)     # load pointer to __libc_csu_fini
  85         l       %r5,.L1-.Llit(%r13)     # load pointer to __libc_csu_init
  86         l       %r2,.L3-.Llit(%r13)     # load pointer to main
  87         l       %r1,.L4-.Llit(%r13)     # load pointer to __libc_start_main
  88 #ifdef PIC
  89         l       %r12,.L5-.Llit(%r13)    # load .got pointer
  90         la      %r6,0(%r13,%r6)
  91         la      %r5,0(%r13,%r5)
  92         la      %r12,0(%r13,%r12)
  93         l       %r2,0(%r12,%r2)
  94         la      %r1,0(%r13,%r1)
  95 #endif
  96
  97         /* ok, now branch to the libc main routine */
  98         basr    %r14,%r1
  99
 100         /* crash if __libc_start_main returns */
 101         .word   0
 102
 103 .Llit:
 104 #ifndef PIC
 105 .L1:    .long  __libc_csu_init
 106 .L2:    .long  __libc_csu_fini
 107 .L3:    .long  main
 108 .L4:    .long  __libc_start_main
 109 #else
 110 .L1:    .long  __libc_csu_init-.Llit
 111 .L2:    .long  __libc_csu_fini-.Llit
 112 .L3:    .long  main@GOT
 113 .L4:    .long  __libc_start_main@plt-.Llit
 114 .L5:    .long  _GLOBAL_OFFSET_TABLE_-.Llit
 115 #endif
 116
 117 /* Define a symbol for the first piece of initialized data.  */
 118         .data
 119         .globl __data_start
 120 __data_start:
 121         .long 0
 122         .weak data_start
 123         data_start = __data_start