sysdeps/s390/s390-32/elf/setjmp.S

   1 /* setjmp for s390, ELF version.
   2    Copyright (C) 2000, 2002, 2005 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #define _ASM
  23 #define _SETJMP_H
  24 #include <bits/setjmp.h>
  25
  26         /* We include the BSD entry points here as well but we make
  27            them weak.  */
  28 ENTRY (setjmp)
  29         .weak C_SYMBOL_NAME (setjmp)
  30         lhi    %r3,1                /* second argument of one */
  31         j      .Linternal_sigsetjmp /* branch relativ to __sigsetjmp */
  32 END (setjmp)
  33
  34         /* Binary compatibility entry point.  */
  35 ENTRY(_setjmp)
  36         .weak  C_SYMBOL_NAME (_setjmp)
  37         lhi    %r3,0                /* second argument of zero */
  38         j      .Linternal_sigsetjmp /* branch relativ to __sigsetjmp */
  39 END (_setjmp)
  40 libc_hidden_def (_setjmp)
  41
  42 ENTRY(__setjmp)
  43         lhi    %r3,0                /* second argument of zero */
  44         j      .Linternal_sigsetjmp /* branch relativ to __sigsetjmp */
  45 END (__setjmp)
  46
  47 ENTRY(__sigsetjmp)
  48 .Linternal_sigsetjmp:
  49 #ifdef PTR_MANGLE
  50         stm    %r6,%r13,0(%r2)      /* store registers in jmp_buf */
  51         lr     %r4,%r14
  52         lr     %r5,%r15
  53         PTR_MANGLE (%r4, %r1)
  54         PTR_MANGLE2 (%r5, %r1)
  55         stm    %r4,%r5,32(%r2)
  56 #else
  57         stm    %r6,%r15,0(%r2)      /* store registers in jmp_buf */
  58 #endif
  59         std    %f4,40(%r2)
  60         std    %f6,48(%r2)
  61 #if defined NOT_IN_libc && defined IS_IN_rtld
  62         /* In ld.so we never save the signal mask.  */
  63         lhi    %r2,0
  64         br     %r14
  65 #elif defined PIC
  66         /* We cannot use the PLT, because it requires that %r12 be set, but
  67            we can't save and restore our caller's value.  Instead, we do an
  68            indirect jump through the GOT. */
  69         basr   %r1,0
  70 .L0:    al     %r1,.L1 - .L0(0,%r1) /* get address of global offset table */
  71                                     /* get address of __sigjmp_save from got */
  72         l      %r1,__sigjmp_save@GOT12(0,%r1)
  73         br     %r1
  74 .L1:    .long  _GLOBAL_OFFSET_TABLE_ - .L0
  75 #else
  76         basr   %r1,0
  77 .L0:    l      %r1,.L1-.L0(0,%r1)   /* load address of __sigjmp_save */
  78         br     %r1                  /* tail-call __sigjmp_save */
  79 .L1:    .long  __sigjmp_save
  80 #endif
  81 END (__sigsetjmp)