sysdeps/s390/s390-32/bcopy.S

   1 /* bcopy -- copy a block from source to destination.  S/390 version.
   2    This file is part of the GNU C Library.
   3    Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 /* INPUT PARAMETERS
  22      %r2 = address of source
  23      %r3 = address of destination
  24      %r4 = number of bytes to copy.  */
  25
  26 #include "sysdep.h"
  27 #include "asm-syntax.h"
  28
  29         .text
  30 ENTRY(__bcopy)
  31         ltr     %r1,%r4             # zero bcopy ?
  32         jz      .L4
  33         clr     %r2,%r3             # check against destructive overlap
  34         jnl     .L0
  35         alr     %r1,%r2
  36         clr     %r1,%r3
  37         jh      .L7
  38 .L0:    ahi     %r4,-1              # length - 1
  39         lr      %r1,%r4
  40         srl     %r1,8
  41         ltr     %r1,%r1             # < 256 bytes to move ?
  42         jz      .L2
  43         chi     %r1,255             # > 1MB to move ?
  44         jh      .L5
  45 .L1:    mvc     0(256,%r3),0(%r2)   # move in 256 byte chunks
  46         la      %r2,256(%r2)
  47         la      %r3,256(%r3)
  48         brct    %r1,.L1
  49 .L2:    bras    %r1,.L3             # setup base pointer for execute
  50         mvc     0(1,%r3),0(%r2)     # instruction for execute
  51 .L3:    ex      %r4,0(%r1)          # execute mvc with length ((%r4)&255)+1
  52 .L4:    br      %r14
  53
  54         # data copies > 1MB are faster with mvcle.
  55 .L5:    ahi     %r4,1               # length + 1
  56         lr      %r5,%r4             # source length
  57         lr      %r4,%r2             # source address
  58         lr      %r2,%r3             # set destination
  59         lr      %r3,%r5             # destination length = source length
  60 .L6:    mvcle   %r2,%r4,0           # thats it, MVCLE is your friend
  61         jo      .L6
  62         br      %r14
  63 .L7:                                # destructive overlay, can not use mvcle
  64         lr     %r1,%r2              # bcopy is called with source,dest
  65         lr     %r2,%r3              # memmove with dest,source! Oh, well...
  66         lr     %r3,%r1
  67         basr   %r1,0
  68 .L8:
  69 #ifdef PIC
  70         al     %r1,.L9-.L8(%r1)     # get address of global offset table
  71                                     # load address of memmove
  72         l      %r1,memmove@GOT12(%r1)
  73         br     %r1
  74 .L9:    .long  _GLOBAL_OFFSET_TABLE_-.L8
  75 #else
  76         al     %r1,.L9-.L8(%r1)     # load address of memmove
  77         br     %r1                  # jump to memmove
  78 .L9:    .long  memmove-.L8
  79 #endif
  80
  81 END(__bcopy)
  82
  83 #ifndef NO_WEAK_ALIAS
  84 weak_alias (__bcopy, bcopy)
  85 #endif
  86