sysdeps/s390/s390-32/addmul_1.S

   1 /* S390 __mpn_addmul_1 -- Multiply a limb vector with a limb and add
   2    the result to a second limb vector.
   3    Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU MP Library.
   6
   7    The GNU MP Library is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU Lesser General Public License as published by
   9    the Free Software Foundation; either version 2.1 of the License, or (at your
  10    option) any later version.
  11
  12    The GNU MP Library is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15    License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public License
  18    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20    MA 02111-1307, USA. */
  21
  22 /*
  23    INPUT PARAMETERS
  24    res_ptr      %r2
  25    s1_ptr       %r3
  26    sizeP        %r4
  27    s2_limb      %r5
  28 */
  29
  30 #include "sysdep.h"
  31 #include "asm-syntax.h"
  32
  33         .text
  34 ENTRY(__mpn_addmul_1)
  35         st     %r6,24(%r15)
  36         cfi_offset (%r6, -72)
  37         slr    %r6,%r6            # cy_limb = 0
  38 .L0:    icm    %r1,15,0(%r3)      # get s1_ptr[i]
  39         mr     %r0,%r5            # umul_ppmm(prod_high,prod_low,s1_ptr[j],s2_limb)
  40         jnm    .L1
  41         alr    %r0,%r5
  42 .L1:    ltr    %r5,%r5
  43         jnm    .L2
  44         al     %r0,0(%r3)
  45 .L2:    alr    %r1,%r6            # prod_low += cy_limb
  46         lr     %r6,%r0            # cy_limb = prod_high
  47         brc    12,.L3
  48         ahi    %r6,1              #           + (prod_low < cy_limb)
  49 .L3:    al     %r1,0(%r2)         # prod_low += res_ptr[i]
  50         brc    12,.L4
  51         ahi    %r6,1              # cy_limb++
  52 .L4:    st     %r1,0(%r2)
  53         la     %r2,4(0,%r2)
  54         la     %r3,4(0,%r3)
  55         brct   %r4,.L0
  56         lr     %r2,%r6            # return cy_limb
  57         l      %r6,24(%r15)
  58 .Lexit: br     %r14
  59 END(__mpn_addmul_1)