sysdeps/powerpc/powerpc64/fpu/s_truncf.S

   1 /* truncf function.  PowerPC64 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2**23 */
  24         .tc FD_4b000000_0[TC],0x4b00000000000000
  25         .section        ".text"
  26
  27 /* float [fp1] truncf (float x [fp1])
  28    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  29    value, in floating format, nearest to but no larger in magnitude
  30    then the argument."
  31    We set "round toward Zero" mode and trunc by adding +-2**23 then
  32    subtracting +-2**23.  */
  33
  34 EALIGN (__truncf, 4, 0)
  35         CALL_MCOUNT 0
  36         mffs    fp11            /* Save current FPU rounding mode.  */
  37         lfs     fp13,.LC0@toc(2)
  38         fabs    fp0,fp1
  39         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  40         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  41         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  42         bnllr-  cr7
  43         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  44         ble-    cr6,.L4
  45         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  46         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  47         fabs    fp1,fp1         /* if (x == 0.0)  */
  48                                 /* x = 0.0; */
  49         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  50         blr
  51 .L4:
  52         bge-    cr6,.L9         /* if (x < 0.0)  */
  53         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  54         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  55         fnabs   fp1,fp1         /* if (x == 0.0)  */
  56                                 /* x = -0.0; */
  57 .L9:
  58         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  59         blr
  60         END (__truncf)
  61
  62 weak_alias (__truncf, truncf)
  63