sysdeps/powerpc/powerpc64/fpu/s_roundf.S

   1 /* roundf  function.  PowerPC64 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2**23 */
  24         .tc FD_4b000000_0[TC],0x4b00000000000000
  25 .LC1:   /* 0.5 */
  26         .tc FD_3f000000_0[TC],0x3f00000000000000
  27         .section        ".text"
  28
  29 /* float [fp1] roundf  (float x [fp1])
  30    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  31    integer value, rounding halfway cases away from zero, regardless of
  32    the current rounding mode."  However PowerPC Architecture defines
  33    "Round to Nearest" as "Choose the best approximation. In case of a
  34    tie, choose the one that is even (least significant bit o).".
  35    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  36    "Round toward Zero" mode and round by adding +-0.5 before rounding
  37    to the integer value.  */
  38
  39 EALIGN (__roundf, 4, 0)
  40         CALL_MCOUNT 0
  41         mffs    fp11            /* Save current FPU rounding mode.  */
  42         lfs     fp13,.LC0@toc(2)
  43         fabs    fp0,fp1
  44         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  45         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  46         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  47         bnllr-  cr7
  48         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  49         lfs     fp10,.LC1@toc(2)
  50         ble-    cr6,.L4
  51         fadds   fp1,fp1,fp10    /* x+= 0.5;  */
  52         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  53         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  54         fabs    fp1,fp1         /* if (x == 0.0)  */
  55                                 /* x = 0.0; */
  56         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  57         blr
  58 .L4:
  59         fsubs   fp9,fp1,fp10    /* x+= 0.5;  */
  60         bge-    cr6,.L9         /* if (x < 0.0)  */
  61         fsubs   fp1,fp9,fp13    /* x-= TWO23;  */
  62         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  63         fnabs   fp1,fp1         /* if (x == 0.0)  */
  64                                 /* x = -0.0; */
  65 .L9:
  66         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  67         blr
  68         END (__roundf)
  69
  70 weak_alias (__roundf, roundf)
  71