sysdeps/powerpc/powerpc64/fpu/s_round.S

   1 /* round function.  PowerPC64 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        ".toc","aw"
  24 .LC0:   /* 2**52 */
  25         .tc FD_43300000_0[TC],0x4330000000000000
  26 .LC1:   /* 0.5 */
  27         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  28         .section        ".text"
  29
  30 /* double [fp1] round (double x [fp1])
  31    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  32    integer value, rounding halfway cases away from zero, regardless of
  33    the current rounding mode."  However PowerPC Architecture defines
  34    "Round to Nearest" as "Choose the best approximation. In case of a
  35    tie, choose the one that is even (least significant bit o).".
  36    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  37    "Round toward Zero" mode and round by adding +-0.5 before rounding
  38    to the integer value.  */
  39
  40 EALIGN (__round, 4, 0)
  41         CALL_MCOUNT 0
  42         mffs    fp11            /* Save current FPU rounding mode.  */
  43         lfd     fp13,.LC0@toc(2)
  44         fabs    fp0,fp1
  45         fsub    fp12,fp13,fp13  /* generate 0.0  */
  46         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  47         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  48         bnllr-  cr7
  49         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  50         lfd     fp10,.LC1@toc(2)
  51         ble-    cr6,.L4
  52         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  53         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  54         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  55         fabs    fp1,fp1         /* if (x == 0.0)  */
  56                                 /* x = 0.0; */
  57         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  58         blr
  59 .L4:
  60         fsub    fp9,fp1,fp10    /* x+= 0.5;  */
  61         bge-    cr6,.L9         /* if (x < 0.0)  */
  62         fsub    fp1,fp9,fp13    /* x-= TWO52;  */
  63         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  64         fnabs   fp1,fp1         /* if (x == 0.0)  */
  65                                 /* x = -0.0; */
  66 .L9:
  67         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  68         blr
  69         END (__round)
  70
  71 weak_alias (__round, round)
  72
  73 #ifdef NO_LONG_DOUBLE
  74 weak_alias (__round, roundl)
  75 strong_alias (__round, __roundl)
  76 #endif
  77 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  78 compat_symbol (libm, __round, roundl, GLIBC_2_1)
  79 #endif