sysdeps/powerpc/powerpc64/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24 #include <math_ldbl_opt.h>
  25
  26         .section        ".toc","aw"
  27 .LC0:   /* 2**52 */
  28         .tc FD_43300000_0[TC],0x4330000000000000
  29         .section        ".text"
  30
  31 EALIGN (__rint, 4, 0)
  32         CALL_MCOUNT 0
  33         lfd     fp13,.LC0@toc(2)
  34         fabs    fp0,fp1
  35         fsub    fp12,fp13,fp13  /* generate 0.0  */
  36         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  37         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  38         bnllr-  cr7
  39         bng-    cr6,.L4
  40         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  41         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  42         fabs    fp1,fp1         /* if (x == 0.0)  */
  43         blr                     /* x = 0.0; */
  44 .L4:
  45         bnllr-  cr6             /* if (x < 0.0)  */
  46         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  47         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  48         fnabs   fp1,fp1         /* if (x == 0.0)  */
  49         blr                     /* x = -0.0; */
  50         END (__rint)
  51
  52 weak_alias (__rint, rint)
  53
  54 #ifdef NO_LONG_DOUBLE
  55 weak_alias (__rint, rintl)
  56 strong_alias (__rint, __rintl)
  57 #endif
  58 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  59 compat_symbol (libm, __rint, rintl, GLIBC_2_0)
  60 #endif