sysdeps/powerpc/powerpc64/fpu/s_llround.S

   1 /* llround function.  PowerPC64 version.
   2    Copyright (C) 2004, 2006, 2007, 2008 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        ".toc","aw"
  24 .LC0:   /* 2^52 */
  25         .tc FD_43300000_0[TC],0x4330000000000000
  26 .LC1:   /* 0.5 */
  27         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  28         .section        ".text"
  29
  30 /* long long [r3] llround (double x [fp1])
  31    IEEE 1003.1 llround function.  IEEE specifies "round to the nearest
  32    integer value, rounding halfway cases away from zero, regardless of
  33    the current rounding mode."  However PowerPC Architecture defines
  34    "round to Nearest" as "Choose the best approximation. In case of a
  35    tie, choose the one that is even (least significant bit o).".
  36    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  37    "round toward Zero" mode and round by adding +-0.5 before rounding
  38    to the integer value.
  39
  40    It is necessary to detect when x is (+-)0x1.fffffffffffffp-2
  41    because adding +-0.5 in this case will cause an erroneous shift,
  42    carry and round.  We simply return 0 if 0.5 > x > -0.5.  Likewise
  43    if x is and odd number between +-(2^52 and 2^53-1) a shift and
  44    carry will erroneously round if biased with +-0.5.  Therefore if x
  45    is greater/less than +-2^52 we don't need to bias the number with
  46    +-0.5.  */
  47
  48 ENTRY (__llround)
  49         CALL_MCOUNT 0
  50         lfd     fp9,.LC0@toc(2) /* Load 2^52 into fpr9.  */
  51         lfd     fp10,.LC1@toc(2)/* Load 0.5 into fpr10.  */
  52         fabs    fp2,fp1         /* Get the absolute value of x.  */
  53         fsub    fp12,fp10,fp10  /* Compute 0.0 into fp12.  */
  54         fcmpu   cr6,fp2,fp10    /* if |x| < 0.5  */
  55         fcmpu   cr7,fp2,fp9     /* if |x| >= 2^52  */
  56         fcmpu   cr1,fp1,fp12    /* x is negative? x < 0.0  */
  57         blt-    cr6,.Lretzero   /* 0.5 > x < -0.5 so just return 0.  */
  58         bge-    cr7,.Lnobias    /* 2^52 > x < -2^52 just convert with no bias.  */
  59         fadd    fp3,fp2,fp10    /* |x|+=0.5 bias to prepare to round.  */
  60         bge     cr1,.Lconvert   /* x is positive so don't negate x.  */
  61         fnabs   fp3,fp3         /* -(|x|+=0.5)  */
  62 .Lconvert:
  63         fctidz  fp4,fp3         /* Convert to Integer double word round toward 0.  */
  64         stfd    fp4,-16(r1)
  65         nop
  66         nop
  67         nop
  68         ld      r3,-16(r1)      /* Load return as integer.  */
  69 .Lout:
  70         blr
  71 .Lretzero:                      /* 0.5 > x > -0.5  */
  72         li      r3,0            /* return 0.  */
  73         b       .Lout
  74 .Lnobias:
  75         fmr     fp3,fp1
  76         b       .Lconvert
  77         END (__llround)
  78
  79 strong_alias (__llround, __lround)
  80 weak_alias (__llround, llround)
  81 weak_alias (__lround, lround)
  82
  83 #ifdef NO_LONG_DOUBLE
  84 weak_alias (__llround, llroundl)
  85 strong_alias (__llround, __llroundl)
  86 weak_alias (__lround, lroundl)
  87 strong_alias (__lround, __lroundl)
  88 #endif
  89 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  90 compat_symbol (libm, __llround, llroundl, GLIBC_2_1)
  91 compat_symbol (libm, __lround, lroundl, GLIBC_2_1)
  92 #endif