sysdeps/powerpc/powerpc64/fpu/s_ceil.S

   1 /* ceil function.  PowerPC64 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        ".toc","aw"
  24 .LC0:   /* 2**52 */
  25         .tc FD_43300000_0[TC],0x4330000000000000
  26         .section        ".text"
  27
  28 EALIGN (__ceil, 4, 0)
  29         CALL_MCOUNT 0
  30         mffs    fp11            /* Save current FPU rounding mode.  */
  31         lfd     fp13,.LC0@toc(2)
  32         fabs    fp0,fp1
  33         fsub    fp12,fp13,fp13  /* generate 0.0  */
  34         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  35         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  36         bnllr-  cr7
  37         mtfsfi  7,2             /* Set rounding mode toward +inf.  */
  38         ble-    cr6,.L4
  39         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  40         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  41         fabs    fp1,fp1         /* if (x == 0.0)  */
  42                                 /* x = 0.0; */
  43         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  44         blr
  45 .L4:
  46         bge-    cr6,.L9         /* if (x < 0.0)  */
  47         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  48         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  49         fnabs   fp1,fp1         /* if (x == 0.0)  */
  50                                 /* x = -0.0; */
  51 .L9:
  52         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  53         blr
  54         END (__ceil)
  55
  56 weak_alias (__ceil, ceil)
  57
  58 #ifdef NO_LONG_DOUBLE
  59 weak_alias (__ceil, ceill)
  60 strong_alias (__ceil, __ceill)
  61 #endif
  62 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  63 compat_symbol (libm, __ceil, ceill, GLIBC_2_0)
  64 #endif