sysdeps/powerpc/powerpc64/configure.in

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2 # Local configure fragment for sysdeps/powerpc/powerpc64.
   3
   4 # The Aix ld uses global .symbol_names instead of symbol_names
   5 # and unfortunately early Linux PPC64 linkers use it as well.
   6 AC_CACHE_CHECK(for support for omitting dot symbols,
   7 libc_cv_omit_dot_syms, [dnl
   8 libc_cv_omit_dot_syms=no
   9 echo 'void foo (void) {}' > conftest.c
  10 if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
  11   if grep -w '\.foo' conftest.s > /dev/null; then
  12     :
  13   else
  14     libc_cv_omit_dot_syms=yes
  15   fi
  16 fi
  17 rm -f conftest.c conftest.s
  18 ])
  19 if test x$libc_cv_omit_dot_syms != xyes; then
  20   AC_DEFINE(HAVE_ASM_GLOBAL_DOT_NAME)
  21 fi
  22
  23 AC_CACHE_CHECK(for linker support for overlapping .opd entries,
  24 libc_cv_overlapping_opd, [dnl
  25 libc_cv_overlapping_opd=no
  26 echo 'void foo (void) {}' > conftest.c
  27 if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
  28 changequote(,)dnl
  29   if grep '\.TOC\.@tocbase' conftest.s > /dev/null; then
  30     if grep '\.TOC\.@tocbase[   ]*,[    ]*0' conftest.s > /dev/null; then
  31       :
  32     else
  33       libc_cv_overlapping_opd=yes
  34     fi
  35   fi
  36 changequote([,])dnl
  37 fi
  38 rm -f conftest.c conftest.s
  39 ])
  40 if test x$libc_cv_overlapping_opd = xyes; then
  41   AC_DEFINE(USE_PPC64_OVERLAPPING_OPD)
  42 fi