sysdeps/powerpc/powerpc32/submul_1.S

   1 /* Multiply a limb vector by a single limb, for PowerPC.
   2    Copyright (C) 1993-1995, 1997, 1999, 2000 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <bp-sym.h>
  22 #include <bp-asm.h>
  23
  24 /* mp_limb_t mpn_submul_1 (mp_ptr res_ptr, mp_srcptr s1_ptr,
  25                            mp_size_t s1_size, mp_limb_t s2_limb)
  26    Calculate res-s1*s2 and put result back in res; return carry.  */
  27
  28 ENTRY (BP_SYM (__mpn_submul_1))
  29 #if __BOUNDED_POINTERS__
  30         slwi r10,r5,2           /* convert limbs to bytes */
  31         CHECK_BOUNDS_BOTH_WIDE (r3, r8, r9, r10)
  32         CHECK_BOUNDS_BOTH_WIDE (r4, r8, r9, r10)
  33 #endif
  34         mtctr   r5
  35
  36         lwz     r0,0(r4)
  37         mullw   r7,r0,r6
  38         mulhwu  r10,r0,r6
  39         lwz     r9,0(r3)
  40         subf    r8,r7,r9
  41         addc    r7,r7,r8                # invert cy (r7 is junk)
  42         addi    r3,r3,-4                # adjust res_ptr
  43         bdz     L(1)
  44
  45 L(0):   lwzu    r0,4(r4)
  46         stwu    r8,4(r3)
  47         mullw   r8,r0,r6
  48         adde    r7,r8,r10
  49         mulhwu  r10,r0,r6
  50         lwz     r9,4(r3)
  51         addze   r10,r10
  52         subf    r8,r7,r9
  53         addc    r7,r7,r8                # invert cy (r7 is junk)
  54         bdnz    L(0)
  55
  56 L(1):   stw     r8,4(r3)
  57         addze   r3,r10
  58         blr
  59 END (BP_SYM (__mpn_submul_1))