sysdeps/powerpc/powerpc32/power4/fpu/s_llround.S

   1 /* llround function.  PowerPC32 on PowerPC64 version.
   2    Copyright (C) 2004, 2006, 2007, 2008 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23  .section .rodata.cst12,"aM",@progbits,12
  24  .align 3
  25  .LC0:   /* 0x1.0000000000000p+52 == 2^52 */
  26         .long 0x43300000
  27         .long 0x00000000
  28         .long 0x3f000000 /* Use this for 0.5  */
  29
  30         .section        ".text"
  31
  32 /* long [r3] lround (float x [fp1])
  33    IEEE 1003.1 lround function.  IEEE specifies "round to the nearest
  34    integer value, rounding halfway cases away from zero, regardless of
  35    the current rounding mode."  However PowerPC Architecture defines
  36    "round to Nearest" as "Choose the best approximation. In case of a
  37    tie, choose the one that is even (least significant bit o).".
  38    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  39    "round toward Zero" mode and round by adding +-0.5 before rounding
  40    to the integer value.
  41
  42    It is necessary to detect when x is (+-)0x1.fffffffffffffp-2
  43    because adding +-0.5 in this case will cause an erroneous shift,
  44    carry and round.  We simply return 0 if 0.5 > x > -0.5.  Likewise
  45    if x is and odd number between +-(2^52 and 2^53-1) a shift and
  46    carry will erroneously round if biased with +-0.5.  Therefore if x
  47    is greater/less than +-2^52 we don't need to bias the number with
  48    +-0.5.  */
  49
  50 ENTRY (__llround)
  51         stwu    r1,-16(r1)
  52         cfi_adjust_cfa_offset (16)
  53 #ifdef SHARED
  54         mflr    r11
  55         cfi_register(lr,r11)
  56 # ifdef HAVE_ASM_PPC_REL16
  57         bcl     20,31,1f
  58 1:      mflr    r9
  59         addis   r9,r9,.LC0-1b@ha
  60         addi    r9,r9,.LC0-1b@l
  61 # else
  62         bl      _GLOBAL_OFFSET_TABLE_@local-4
  63         mflr    r10
  64         lwz     r9,.LC0@got(10)
  65 # endif
  66         mtlr    r11
  67         cfi_same_value (lr)
  68         lfd     fp9,0(r9)
  69         lfs     fp10,8(r9)
  70 #else
  71         lis r9,.LC0@ha
  72         lfd fp9,.LC0@l(r9)      /* Load 2^52 into fpr9.  */
  73         lfs fp10,.LC0@l+8(r9)   /* Load 0.5 into fpr10.  */
  74 #endif
  75         fabs    fp2,fp1         /* Get the absolute value of x.  */
  76         fsub    fp12,fp10,fp10  /* Compute 0.0 into fpr12.  */
  77         fcmpu   cr6,fp2,fp10    /* if |x| < 0.5  */
  78         fcmpu   cr7,fp2,fp9     /* if |x| >= 2^52  */
  79         fcmpu   cr1,fp1,fp12    /* x is negative? x < 0.0  */
  80         blt-    cr6,.Lretzero   /* 0.5 > x < -0.5 so just return 0.  */
  81         bge-    cr7,.Lnobias    /* 2^52 > x < -2^52 just convert with no bias.  */
  82         fadd    fp3,fp2,fp10    /* |x|+=0.5 bias to prepare to round.  */
  83         bge     cr1,.Lconvert   /* x is positive so don't negate x.  */
  84         fnabs   fp3,fp3         /* -(|x|+=0.5)  */
  85 .Lconvert:
  86         fctidz  fp4,fp3         /* Convert to Integer double word round toward 0.  */
  87         stfd    fp4,8(r1)
  88         nop
  89         nop
  90         nop
  91         lwz     r4,12(r1)       /* Load return as integer.  */
  92         lwz     r3,8(r1)
  93 .Lout:
  94         addi    r1,r1,16
  95         blr
  96 .Lretzero:                      /* 0.5 > x > -0.5  */
  97         li      r3,0            /* return 0.  */
  98         li      r4,0
  99         b       .Lout
 100 .Lnobias:
 101         fmr     fp3,fp1
 102         b       .Lconvert
 103         END (__llround)
 104
 105 weak_alias (__llround, llround)
 106
 107 strong_alias (__llround, __llroundf)
 108 weak_alias (__llround, llroundf)
 109
 110 #ifdef NO_LONG_DOUBLE
 111 weak_alias (__llround, llroundl)
 112 strong_alias (__llround, __llroundl)
 113 #endif
 114 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
 115 compat_symbol (libm, __llround, llroundl, GLIBC_2_1)
 116 #endif