sysdeps/powerpc/powerpc32/fpu/s_trunc.S

   1 /* trunc function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        .rodata.cst4,"aM",@progbits,4
  24         .align  2
  25 .LC0:   /* 2**52 */
  26         .long 0x59800000
  27
  28 /* double [fp1] trunc (double x [fp1])
  29    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  30    value, in floating format, nearest to but no larger in magnitude
  31    then the argument."
  32    We set "round toward Zero" mode and trunc by adding +-2**52 then
  33    subtracting +-2**52.  */
  34
  35         .section        ".text"
  36 ENTRY (__trunc)
  37         mffs    fp11            /* Save current FPU rounding mode.  */
  38 #ifdef SHARED
  39         mflr    r11
  40         cfi_register(lr,r11)
  41 # ifdef HAVE_ASM_PPC_REL16
  42         bcl     20,31,1f
  43 1:      mflr    r9
  44         addis   r9,r9,.LC0-1b@ha
  45         lfs     fp13,.LC0-1b@l(r9)
  46 # else
  47         bl      _GLOBAL_OFFSET_TABLE_@local-4
  48         mflr    r10
  49         lwz     r9,.LC0@got(10)
  50         lfs     fp13,0(r9)
  51 # endif
  52         mtlr    r11
  53         cfi_same_value (lr)
  54 #else
  55         lis     r9,.LC0@ha
  56         lfs     fp13,.LC0@l(r9)
  57 #endif
  58         fabs    fp0,fp1
  59         fsub    fp12,fp13,fp13  /* generate 0.0  */
  60         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  61         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  62         bnllr-  cr7
  63         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  64         ble-    cr6,.L4
  65         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  66         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  67         fabs    fp1,fp1         /* if (x == 0.0)  */
  68                                 /* x = 0.0; */
  69         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  70         blr
  71 .L4:
  72         bge-    cr6,.L9         /* if (x < 0.0)  */
  73         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  74         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  75         fnabs   fp1,fp1         /* if (x == 0.0)  */
  76                                 /* x = -0.0; */
  77 .L9:
  78         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  79         blr
  80         END (__trunc)
  81
  82 weak_alias (__trunc, trunc)
  83
  84 #ifdef NO_LONG_DOUBLE
  85 weak_alias (__trunc, truncl)
  86 strong_alias (__trunc, __truncl)
  87 #endif
  88 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  89 compat_symbol (libm, __trunc, truncl, GLIBC_2_1)
  90 #endif