sysdeps/powerpc/powerpc32/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24 #include <math_ldbl_opt.h>
  25
  26         .section        .rodata.cst4,"aM",@progbits,4
  27         .align  2
  28 .LC0:   /* 2**52 */
  29         .long 0x59800000
  30
  31         .section        ".text"
  32 ENTRY (__rint)
  33 #ifdef SHARED
  34         mflr    r11
  35         cfi_register(lr,r11)
  36 # ifdef HAVE_ASM_PPC_REL16
  37         bcl     20,31,1f
  38 1:      mflr    r9
  39         addis   r9,r9,.LC0-1b@ha
  40         lfs     fp13,.LC0-1b@l(r9)
  41 # else
  42         bl      _GLOBAL_OFFSET_TABLE_@local-4
  43         mflr    r10
  44         lwz     r9,.LC0@got(10)
  45         lfs     fp13,0(r9)
  46 # endif
  47         mtlr    r11
  48         cfi_same_value (lr)
  49 #else
  50         lis     r9,.LC0@ha
  51         lfs     fp13,.LC0@l(r9)
  52 #endif
  53         fabs    fp0,fp1
  54         fsub    fp12,fp13,fp13  /* generate 0.0  */
  55         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  56         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  57         bnllr-  cr7
  58         bng-    cr6,.L4
  59         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  60         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  61         fabs    fp1,fp1         /* if (x == 0.0)  */
  62         blr                     /* x = 0.0; */
  63 .L4:
  64         bnllr-  cr6             /* if (x < 0.0)  */
  65         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  66         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  67         fnabs   fp1,fp1         /* if (x == 0.0)  */
  68         blr                     /* x = -0.0; */
  69         END (__rint)
  70
  71 weak_alias (__rint, rint)
  72
  73 #ifdef NO_LONG_DOUBLE
  74 weak_alias (__rint, rintl)
  75 strong_alias (__rint, __rintl)
  76 #endif
  77 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  78 compat_symbol (libm, __rint, rintl, GLIBC_2_0)
  79 #endif