sysdeps/powerpc/powerpc32/fpu/s_floor.S

   1 /* Floor function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        .rodata.cst4,"aM",@progbits,4
  24         .align  2
  25 .LC0:   /* 2**52 */
  26         .long 0x59800000
  27
  28         .section        ".text"
  29 ENTRY (__floor)
  30         mffs    fp11            /* Save current FPU rounding mode.  */
  31 #ifdef SHARED
  32         mflr    r11
  33         cfi_register(lr,r11)
  34 # ifdef HAVE_ASM_PPC_REL16
  35         bcl     20,31,1f
  36 1:      mflr    r9
  37         addis   r9,r9,.LC0-1b@ha
  38         lfs     fp13,.LC0-1b@l(r9)
  39 # else
  40         bl      _GLOBAL_OFFSET_TABLE_@local-4
  41         mflr    r10
  42         lwz     r9,.LC0@got(10)
  43         lfs     fp13,0(r9)
  44 # endif
  45         mtlr    r11
  46         cfi_same_value (lr)
  47 #else
  48         lis     r9,.LC0@ha
  49         lfs     fp13,.LC0@l(r9)
  50 #endif
  51         fabs    fp0,fp1
  52         fsub    fp12,fp13,fp13  /* generate 0.0  */
  53         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  54         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  55         bnllr-  cr7
  56         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  57         ble-    cr6,.L4
  58         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  59         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  60         fabs    fp1,fp1         /* if (x == 0.0)  */
  61                                 /* x = 0.0; */
  62         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  63         blr
  64 .L4:
  65         bge-    cr6,.L9         /* if (x < 0.0)  */
  66         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  67         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  68         fnabs   fp1,fp1         /* if (x == 0.0)  */
  69                                 /* x = -0.0; */
  70 .L9:
  71         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  72         blr
  73         END (__floor)
  74
  75 weak_alias (__floor, floor)
  76
  77 #ifdef NO_LONG_DOUBLE
  78 weak_alias (__floor, floorl)
  79 strong_alias (__floor, __floorl)
  80 #endif
  81 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  82 compat_symbol (libm, __floor, floorl, GLIBC_2_0)
  83 #endif