sysdeps/powerpc/powerpc32/fpu/s_ceilf.S

   1 /* float ceil function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26
  27         .section        ".text"
  28 ENTRY (__ceilf)
  29         mffs    fp11            /* Save current FPU rounding mode.  */
  30 #ifdef SHARED
  31         mflr    r11
  32         cfi_register(lr,r11)
  33 # ifdef HAVE_ASM_PPC_REL16
  34         bcl     20,31,1f
  35 1:      mflr    r9
  36         addis   r9,r9,.LC0-1b@ha
  37         lfs     fp13,.LC0-1b@l(r9)
  38 # else
  39         bl      _GLOBAL_OFFSET_TABLE_@local-4
  40         mflr    r10
  41         lwz     r9,.LC0@got(10)
  42         lfs     fp13,0(r9)
  43 # endif
  44         mtlr    r11
  45         cfi_same_value (lr)
  46 #else
  47         lis     r9,.LC0@ha
  48         lfs     fp13,.LC0@l(r9)
  49 #endif
  50         fabs    fp0,fp1
  51         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  52         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  53         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  54         bnllr-  cr7
  55         mtfsfi  7,2             /* Set rounding mode toward +inf.  */
  56         ble-    cr6,.L4
  57         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  58         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  59         fabs    fp1,fp1         /* if (x == 0.0)  */
  60                                 /* x = 0.0; */
  61         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  62         blr
  63 .L4:
  64         bge-    cr6,.L9         /* if (x < 0.0)  */
  65         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  66         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  67         fnabs   fp1,fp1         /* if (x == 0.0)  */
  68                                 /* x = -0.0; */
  69 .L9:
  70         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  71         blr
  72         END (__ceilf)
  73
  74 weak_alias (__ceilf, ceilf)
  75