sysdeps/powerpc/powerpc32/add_n.S

   1 /* Add two limb vectors of equal, non-zero length for PowerPC.
   2    Copyright (C) 1997, 1999, 2000 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <bp-sym.h>
  22 #include <bp-asm.h>
  23
  24 /* mp_limb_t mpn_add_n (mp_ptr res_ptr, mp_srcptr s1_ptr, mp_srcptr s2_ptr,
  25                         mp_size_t size)
  26    Calculate s1+s2 and put result in res_ptr; return carry, 0 or 1.  */
  27
  28 /* Note on optimisation: This code is optimal for the 601.  Almost every other
  29    possible 2-unrolled inner loop will not be.  Also, watch out for the
  30    alignment...  */
  31
  32 EALIGN (BP_SYM (__mpn_add_n), 3, 0)
  33
  34 #if __BOUNDED_POINTERS__
  35         slwi r10,r6,2           /* convert limbs to bytes */
  36         CHECK_BOUNDS_BOTH_WIDE (r3, r8, r9, r10)
  37         CHECK_BOUNDS_BOTH_WIDE (r4, r8, r9, r10)
  38         CHECK_BOUNDS_BOTH_WIDE (r5, r8, r9, r10)
  39 #endif
  40 /* Set up for loop below.  */
  41         mtcrf 0x01,r6
  42         srwi. r7,r6,1
  43         li    r10,0
  44         mtctr r7
  45         bt    31,L(2)
  46
  47 /* Clear the carry.  */
  48         addic r0,r0,0
  49 /* Adjust pointers for loop.  */
  50         addi  r3,r3,-4
  51         addi  r4,r4,-4
  52         addi  r5,r5,-4
  53         b     L(0)
  54
  55 L(2):   lwz  r7,0(r5)
  56         lwz  r6,0(r4)
  57         addc r6,r6,r7
  58         stw  r6,0(r3)
  59         beq  L(1)
  60
  61 /* The loop.  */
  62
  63 /* Align start of loop to an odd word boundary to guarantee that the
  64    last two words can be fetched in one access (for 601).  */
  65 L(0):   lwz  r9,4(r4)
  66         lwz  r8,4(r5)
  67         lwzu r6,8(r4)
  68         lwzu r7,8(r5)
  69         adde r8,r9,r8
  70         stw  r8,4(r3)
  71         adde r6,r6,r7
  72         stwu r6,8(r3)
  73         bdnz L(0)
  74 /* Return the carry.  */
  75 L(1):   addze r3,r10
  76         blr
  77 END (BP_SYM (__mpn_add_n))