sysdeps/ia64/memccpy.S

   1 /* Optimized version of the memccpy() function.
   2    This file is part of the GNU C Library.
   3    Copyright (C) 2000,2001,2003,2006 Free Software Foundation, Inc.
   4    Contributed by Dan Pop <Dan.Pop@cern.ch>.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 /* Return: a pointer to the next byte after char in dest or NULL
  22
  23    Inputs:
  24         in0:    dest
  25         in1:    src
  26         in2:    char
  27         in3:    byte count
  28
  29    This implementation assumes little endian mode (UM.be = 0).
  30
  31    This implementation assumes that it is safe to do read ahead
  32    in the src block, without getting beyond its limit.  */
  33
  34 #include <sysdep.h>
  35 #undef ret
  36
  37 #define OP_T_THRES      16
  38 #define OPSIZ           8
  39
  40 #define saved_pr        r17
  41 #define saved_lc        r18
  42 #define dest            r19
  43 #define src             r20
  44 #define len             r21
  45 #define asrc            r22
  46 #define tmp             r23
  47 #define char            r24
  48 #define charx8          r25
  49 #define saved_ec        r26
  50 #define sh2             r28
  51 #define sh1             r29
  52 #define loopcnt         r30
  53 #define value           r31
  54
  55 #ifdef GAS_ALIGN_BREAKS_UNWIND_INFO
  56 /* Manually force proper loop-alignment.  Note: be sure to
  57    double-check the code-layout after making any changes to
  58    this routine! */
  59 # define ALIGN(n)       { nop 0 }
  60 #else
  61 # define ALIGN(n)       .align n
  62 #endif
  63
  64 ENTRY(memccpy)
  65         .prologue
  66         alloc   r2 = ar.pfs, 4, 40 - 4, 0, 40
  67
  68 #include "softpipe.h"
  69         .rotr   r[MEMLAT + 7], tmp1[4], tmp2[4], val[4], tmp3[2], pos0[2]
  70         .rotp   p[MEMLAT + 6 + 1]
  71
  72         mov     ret0 = r0               // return NULL if no match
  73         .save pr, saved_pr
  74         mov     saved_pr = pr           // save the predicate registers
  75         mov     dest = in0              // dest
  76         .save ar.lc, saved_lc
  77         mov     saved_lc = ar.lc        // save the loop counter
  78         mov     saved_ec = ar.ec        // save the loop counter
  79         .body
  80         mov     src = in1               // src
  81         extr.u  char = in2, 0, 8        // char
  82         mov     len = in3               // len
  83         sub     tmp = r0, in0           // tmp = -dest
  84         cmp.ne  p7, p0 = r0, r0         // clear p7
  85         ;;
  86         and     loopcnt = 7, tmp        // loopcnt = -dest % 8
  87         cmp.ge  p6, p0 = OP_T_THRES, len        // is len <= OP_T_THRES
  88         mov     ar.ec = 0               // ec not guaranteed zero on entry
  89 (p6)    br.cond.spnt    .cpyfew         // copy byte by byte
  90         ;;
  91         cmp.eq  p6, p0 = loopcnt, r0
  92         mux1    charx8 = char, @brcst
  93 (p6)    br.cond.sptk .dest_aligned
  94         sub     len = len, loopcnt      // len -= -dest % 8
  95         adds    loopcnt = -1, loopcnt   // --loopcnt
  96         ;;
  97         mov     ar.lc = loopcnt
  98 .l1:                                    // copy -dest % 8 bytes
  99         ld1     value = [src], 1        // value = *src++
 100         ;;
 101         st1     [dest] = value, 1       // *dest++ = value
 102         cmp.eq  p6, p0 = value, char
 103 (p6)    br.cond.spnt .foundit
 104         br.cloop.dptk .l1
 105 .dest_aligned:
 106         and     sh1 = 7, src            // sh1 = src % 8
 107         and     tmp = -8, len           // tmp = len & -OPSIZ
 108         and     asrc = -8, src          // asrc = src & -OPSIZ  -- align src
 109         shr.u   loopcnt = len, 3        // loopcnt = len / 8
 110         and     len = 7, len ;;         // len = len % 8
 111         shl     sh1 = sh1, 3            // sh1 = 8 * (src % 8)
 112         adds    loopcnt = -1, loopcnt   // --loopcnt
 113         mov     pr.rot = 1 << 16 ;;     // set rotating predicates
 114         sub     sh2 = 64, sh1           // sh2 = 64 - sh1
 115         mov     ar.lc = loopcnt         // set LC
 116         cmp.eq  p6, p0 = sh1, r0        // is the src aligned?
 117 (p6)    br.cond.sptk .src_aligned ;;
 118         add     src = src, tmp          // src += len & -OPSIZ
 119         mov     ar.ec = MEMLAT + 6 + 1  // six more passes needed
 120         ld8     r[1] = [asrc], 8        // r[1] = w0
 121         cmp.ne  p6, p0 = r0, r0 ;;      // clear p6
 122         ALIGN(32)
 123 .l2:
 124 (p[0])          ld8.s   r[0] = [asrc], 8                // r[0] = w1
 125 (p[MEMLAT])     shr.u   tmp1[0] = r[1 + MEMLAT], sh1    // tmp1 = w0 >> sh1
 126 (p[MEMLAT])     shl     tmp2[0] = r[0 + MEMLAT], sh2    // tmp2 = w1 << sh2
 127 (p[MEMLAT+4])   xor     tmp3[0] = val[1], charx8
 128 (p[MEMLAT+5])   czx1.r  pos0[0] = tmp3[1]
 129 (p[MEMLAT+6])   chk.s   r[6 + MEMLAT], .recovery1       // our data isn't
 130                                                         // valid - rollback!
 131 (p[MEMLAT+6])   cmp.ne  p6, p0 = 8, pos0[1]
 132 (p6)            br.cond.spnt    .gotit
 133 (p[MEMLAT+6])   st8     [dest] = val[3], 8              // store val to dest
 134 (p[MEMLAT+3])   or      val[0] = tmp1[3], tmp2[3]       // val = tmp1 | tmp2
 135                 br.ctop.sptk    .l2
 136                 br.cond.sptk .cpyfew
 137
 138 .src_aligned:
 139                 cmp.ne  p6, p0 = r0, r0                 // clear p6
 140                 mov     ar.ec = MEMLAT + 2 + 1 ;;       // set EC
 141 .l3:
 142 (p[0])          ld8.s   r[0] = [src], 8
 143 (p[MEMLAT])     xor     tmp3[0] = r[MEMLAT], charx8
 144 (p[MEMLAT+1])   czx1.r  pos0[0] = tmp3[1]
 145 (p[MEMLAT+2])   cmp.ne  p7, p0 = 8, pos0[1]
 146 (p[MEMLAT+2])   chk.s   r[MEMLAT+2], .recovery2
 147 (p7)            br.cond.spnt    .gotit
 148 .back2:
 149 (p[MEMLAT+2])   st8     [dest] = r[MEMLAT+2], 8
 150                 br.ctop.dptk .l3
 151 .cpyfew:
 152         cmp.eq  p6, p0 = len, r0        // is len == 0 ?
 153         adds    len = -1, len           // --len;
 154 (p6)    br.cond.spnt    .restore_and_exit ;;
 155         mov     ar.lc = len
 156 .l4:
 157         ld1     value = [src], 1
 158         ;;
 159         st1     [dest] = value, 1
 160         cmp.eq  p6, p0 = value, char
 161 (p6)    br.cond.spnt .foundit
 162         br.cloop.dptk   .l4 ;;
 163 .foundit:
 164 (p6)    mov     ret0 = dest
 165 .restore_and_exit:
 166         mov     pr = saved_pr, -1       // restore the predicate registers
 167         mov     ar.lc = saved_lc        // restore the loop counter
 168         mov     ar.ec = saved_ec ;;     // restore the epilog counter
 169         br.ret.sptk.many b0
 170 .gotit:
 171         .pred.rel "mutex" p6, p7
 172 (p6)    mov     value = val[3]          // if coming from l2
 173 (p7)    mov     value = r[MEMLAT+2]     // if coming from l3
 174         mov     ar.lc = pos0[1] ;;
 175 .l5:
 176         extr.u  tmp = value, 0, 8 ;;
 177         st1     [dest] = tmp, 1
 178         shr.u   value = value, 8
 179         br.cloop.sptk .l5 ;;
 180         mov     ret0 = dest
 181         mov     pr = saved_pr, -1
 182         mov     ar.lc = saved_lc
 183         br.ret.sptk.many b0
 184
 185 .recovery1:
 186 #if MEMLAT != 6
 187 # error "MEMLAT must be 6!"
 188 #endif
 189         adds    src = -8, asrc
 190         mov     loopcnt = ar.lc
 191         mov     tmp = ar.ec
 192         ;;
 193 (p[0])  adds    src = -8, src
 194         ;;
 195 (p[1])  adds    src = -8, src
 196         sub     sh1 = (MEMLAT + 6 + 1), tmp
 197         ;;
 198 (p[2])  adds    src = -8, src
 199         ;;
 200 (p[3])  adds    src = -8, src
 201         shl     loopcnt = loopcnt, 3
 202         ;;
 203 (p[4])  adds    src = -8, src
 204         ;;
 205 (p[5])  adds    src = -8, src
 206         shl     sh1 = sh1, 3
 207         ;;
 208 (p[6])  adds    src = -8, src
 209         ;;
 210 (p[7])  adds    src = -8, src
 211         shl     tmp = tmp, 3
 212         ;;
 213 (p[8])  adds    src = -8, src
 214         ;;
 215 (p[9])  adds    src = -8, src
 216         shr.u   sh2 = sh2, 3
 217         ;;
 218 (p[10]) adds    src = -8, src
 219         ;;
 220 (p[11]) adds    src = -8, src
 221         add     len = len, loopcnt
 222         ;;
 223         sub     src = src, sh2
 224         ;;
 225         add     len = tmp, len
 226         add     src = sh1, src
 227         br.cond.sptk .cpyfew
 228
 229 .recovery2:
 230 #if MEMLAT != 6
 231 # error "MEMLAT must be 6!"
 232 #endif
 233         add     tmp = -8, src
 234 (p7)    br.cond.spnt .gotit
 235         ;;
 236 (p[0])  add     tmp = -8, tmp ;;
 237 (p[1])  add     tmp = -8, tmp ;;
 238 (p[2])  add     tmp = -8, tmp ;;
 239 (p[3])  add     tmp = -8, tmp ;;
 240 (p[4])  add     tmp = -8, tmp ;;
 241 (p[5])  add     tmp = -8, tmp ;;
 242 (p[6])  add     tmp = -8, tmp ;;
 243 (p[7])  add     tmp = -8, tmp ;;
 244         ld8     r[MEMLAT+2] = [tmp] ;;
 245         xor     pos0[1] = r[MEMLAT+2], charx8 ;;
 246         czx1.r  pos0[1] = pos0[1] ;;
 247         cmp.ne  p7, p6 = 8, pos0[1]
 248 (p7)    br.cond.spnt .gotit
 249         br.cond.sptk .back2
 250 END(memccpy)