sysdeps/ia64/fpu/e_expf.S

   1 .file "expf.s"
   2
   3
   4 // Copyright (c) 2000 - 2005, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  39
  40 // History
  41 //*********************************************************************
  42 // 02/02/00 Original version
  43 // 04/04/00 Unwind support added
  44 // 08/15/00 Bundle added after call to __libm_error_support to properly
  45 //          set [the previously overwritten] GR_Parameter_RESULT.
  46 // 08/21/00 Improvements to save 2 cycles on main path, and shorten x=0 case
  47 // 12/07/00 Widen main path, shorten x=inf, nan paths
  48 // 03/15/01 Fix monotonicity problem around x=0 for round to +inf
  49 // 02/05/02 Corrected uninitialize predicate in POSSIBLE_UNDERFLOW path
  50 // 05/20/02 Cleaned up namespace and sf0 syntax
  51 // 07/26/02 Algorithm changed, accuracy improved
  52 // 09/26/02 support of higher precision inputs added, underflow threshold
  53 //          corrected
  54 // 11/15/02 Improved performance on Itanium 2, added possible over/under paths
  55 // 05/30/03 Set inexact flag on unmasked overflow/underflow
  56 // 03/31/05 Reformatted delimiters between data tables
  57 //
  58 //
  59 // API
  60 //*********************************************************************
  61 // float expf(float)
  62 //
  63 // Overview of operation
  64 //*********************************************************************
  65 // Take the input x. w is "how many log2/128 in x?"
  66 //  w = x * 64/log2
  67 //  NJ = int(w)
  68 //  x = NJ*log2/64 + R
  69
  70 //  NJ = 64*n + j
  71 //  x = n*log2 + (log2/64)*j + R
  72 //
  73 //  So, exp(x) = 2^n * 2^(j/64)* exp(R)
  74 //
  75 //  T =  2^n * 2^(j/64)
  76 //       Construct 2^n
  77 //       Get 2^(j/64) table
  78 //           actually all the entries of 2^(j/64) table are stored in DP and
  79 //           with exponent bits set to 0 -> multiplication on 2^n can be
  80 //           performed by doing logical "or" operation with bits presenting 2^n
  81
  82 //  exp(R) = 1 + (exp(R) - 1)
  83 //  P = exp(R) - 1 approximated by Taylor series of 3rd degree
  84 //      P = A3*R^3 + A2*R^2 + R, A3 = 1/6, A2 = 1/2
  85 //
  86
  87 //  The final result is reconstructed as follows
  88 //  exp(x) = T + T*P
  89
  90 // Special values
  91 //*********************************************************************
  92 // expf(+0)    = 1.0
  93 // expf(-0)    = 1.0
  94
  95 // expf(+qnan) = +qnan
  96 // expf(-qnan) = -qnan
  97 // expf(+snan) = +qnan
  98 // expf(-snan) = -qnan
  99
 100 // expf(-inf)  = +0
 101 // expf(+inf)  = +inf
 102
 103 // Overflow and Underflow
 104 //*********************************************************************
 105 // expf(x) = largest single normal when
 106 //     x = 88.72283 = 0x42b17217
 107
 108 // expf(x) = smallest single normal when
 109 //     x = -87.33654 = 0xc2aeac4f
 110
 111 // expf(x) = largest round-to-nearest single zero when
 112 //     x = -103.97208 = 0xc2cff1b5
 113
 114
 115 // Registers used
 116 //*********************************************************************
 117 // Floating Point registers used:
 118 // f8, input
 119 // f6,f7, f9 -> f15,  f32 -> f40
 120
 121 // General registers used:
 122 // r3, r23 -> r38
 123
 124 // Predicate registers used:
 125 // p10 -> p15
 126
 127 // Assembly macros
 128 //*********************************************************************
 129 // integer registers used
 130 // scratch
 131 rNJ                   = r3
 132
 133 rTmp                  = r23
 134 rJ                    = r23
 135 rN                    = r24
 136 rTblAddr              = r25
 137 rA3                   = r26
 138 rExpHalf              = r27
 139 rLn2Div64             = r28
 140 r17ones_m1            = r29
 141 rGt_ln                = r29
 142 rRightShifter         = r30
 143 r64DivLn2             = r31
 144 // stacked
 145 GR_SAVE_PFS           = r32
 146 GR_SAVE_B0            = r33
 147 GR_SAVE_GP            = r34
 148 GR_Parameter_X        = r35
 149 GR_Parameter_Y        = r36
 150 GR_Parameter_RESULT   = r37
 151 GR_Parameter_TAG      = r38
 152
 153 // floating point registers used
 154 FR_X                  = f10
 155 FR_Y                  = f1
 156 FR_RESULT             = f8
 157 // scratch
 158 fRightShifter         = f6
 159 f64DivLn2             = f7
 160 fNormX                = f9
 161 fNint                 = f10
 162 fN                    = f11
 163 fR                    = f12
 164 fLn2Div64             = f13
 165 fA2                   = f14
 166 fA3                   = f15
 167 // stacked
 168 fP                    = f32
 169 fT                    = f33
 170 fMIN_SGL_OFLOW_ARG    = f34
 171 fMAX_SGL_ZERO_ARG     = f35
 172 fMAX_SGL_NORM_ARG     = f36
 173 fMIN_SGL_NORM_ARG     = f37
 174 fRSqr                 = f38
 175 fTmp                  = f39
 176 fGt_pln               = f39
 177 fWre_urm_f8           = f40
 178 fFtz_urm_f8           = f40
 179
 180
 181 RODATA
 182 .align 16
 183
 184 LOCAL_OBJECT_START(_expf_table)
 185 data4 0x42b17218         // Smallest sgl arg to overflow sgl result, +88.7228
 186 data4 0xc2cff1b5         // Largest sgl for rnd-to-nearest 0 result, -103.9720
 187 data4 0x42b17217         // Largest sgl arg to give normal sgl result, +88.7228
 188 data4 0xc2aeac4f         // Smallest sgl arg to give normal sgl result, -87.3365
 189 //
 190 // 2^(j/64) table, j goes from 0 to 63
 191 data8 0x0000000000000000 // 2^(0/64)
 192 data8 0x00002C9A3E778061 // 2^(1/64)
 193 data8 0x000059B0D3158574 // 2^(2/64)
 194 data8 0x0000874518759BC8 // 2^(3/64)
 195 data8 0x0000B5586CF9890F // 2^(4/64)
 196 data8 0x0000E3EC32D3D1A2 // 2^(5/64)
 197 data8 0x00011301D0125B51 // 2^(6/64)
 198 data8 0x0001429AAEA92DE0 // 2^(7/64)
 199 data8 0x000172B83C7D517B // 2^(8/64)
 200 data8 0x0001A35BEB6FCB75 // 2^(9/64)
 201 data8 0x0001D4873168B9AA // 2^(10/64)
 202 data8 0x0002063B88628CD6 // 2^(11/64)
 203 data8 0x0002387A6E756238 // 2^(12/64)
 204 data8 0x00026B4565E27CDD // 2^(13/64)
 205 data8 0x00029E9DF51FDEE1 // 2^(14/64)
 206 data8 0x0002D285A6E4030B // 2^(15/64)
 207 data8 0x000306FE0A31B715 // 2^(16/64)
 208 data8 0x00033C08B26416FF // 2^(17/64)
 209 data8 0x000371A7373AA9CB // 2^(18/64)
 210 data8 0x0003A7DB34E59FF7 // 2^(19/64)
 211 data8 0x0003DEA64C123422 // 2^(20/64)
 212 data8 0x0004160A21F72E2A // 2^(21/64)
 213 data8 0x00044E086061892D // 2^(22/64)
 214 data8 0x000486A2B5C13CD0 // 2^(23/64)
 215 data8 0x0004BFDAD5362A27 // 2^(24/64)
 216 data8 0x0004F9B2769D2CA7 // 2^(25/64)
 217 data8 0x0005342B569D4F82 // 2^(26/64)
 218 data8 0x00056F4736B527DA // 2^(27/64)
 219 data8 0x0005AB07DD485429 // 2^(28/64)
 220 data8 0x0005E76F15AD2148 // 2^(29/64)
 221 data8 0x0006247EB03A5585 // 2^(30/64)
 222 data8 0x0006623882552225 // 2^(31/64)
 223 data8 0x0006A09E667F3BCD // 2^(32/64)
 224 data8 0x0006DFB23C651A2F // 2^(33/64)
 225 data8 0x00071F75E8EC5F74 // 2^(34/64)
 226 data8 0x00075FEB564267C9 // 2^(35/64)
 227 data8 0x0007A11473EB0187 // 2^(36/64)
 228 data8 0x0007E2F336CF4E62 // 2^(37/64)
 229 data8 0x00082589994CCE13 // 2^(38/64)
 230 data8 0x000868D99B4492ED // 2^(39/64)
 231 data8 0x0008ACE5422AA0DB // 2^(40/64)
 232 data8 0x0008F1AE99157736 // 2^(41/64)
 233 data8 0x00093737B0CDC5E5 // 2^(42/64)
 234 data8 0x00097D829FDE4E50 // 2^(43/64)
 235 data8 0x0009C49182A3F090 // 2^(44/64)
 236 data8 0x000A0C667B5DE565 // 2^(45/64)
 237 data8 0x000A5503B23E255D // 2^(46/64)
 238 data8 0x000A9E6B5579FDBF // 2^(47/64)
 239 data8 0x000AE89F995AD3AD // 2^(48/64)
 240 data8 0x000B33A2B84F15FB // 2^(49/64)
 241 data8 0x000B7F76F2FB5E47 // 2^(50/64)
 242 data8 0x000BCC1E904BC1D2 // 2^(51/64)
 243 data8 0x000C199BDD85529C // 2^(52/64)
 244 data8 0x000C67F12E57D14B // 2^(53/64)
 245 data8 0x000CB720DCEF9069 // 2^(54/64)
 246 data8 0x000D072D4A07897C // 2^(55/64)
 247 data8 0x000D5818DCFBA487 // 2^(56/64)
 248 data8 0x000DA9E603DB3285 // 2^(57/64)
 249 data8 0x000DFC97337B9B5F // 2^(58/64)
 250 data8 0x000E502EE78B3FF6 // 2^(59/64)
 251 data8 0x000EA4AFA2A490DA // 2^(60/64)
 252 data8 0x000EFA1BEE615A27 // 2^(61/64)
 253 data8 0x000F50765B6E4540 // 2^(62/64)
 254 data8 0x000FA7C1819E90D8 // 2^(63/64)
 255 LOCAL_OBJECT_END(_expf_table)
 256
 257
 258 .section .text
 259 GLOBAL_IEEE754_ENTRY(expf)
 260
 261 { .mlx
 262       addl            rTblAddr = @ltoff(_expf_table),gp
 263       movl            r64DivLn2 = 0x40571547652B82FE // 64/ln(2)
 264 }
 265 { .mlx
 266       addl            rA3 = 0x3E2AA, r0 // high bits of 1.0/6.0 rounded to SP
 267       movl            rRightShifter = 0x43E8000000000000 // DP Right Shifter
 268 }
 269 ;;
 270
 271 { .mfi
 272       // point to the beginning of the table
 273       ld8             rTblAddr = [rTblAddr]
 274       fclass.m        p14, p0 = f8, 0x22    // test for -INF
 275       shl             rA3 = rA3, 12  // 0x3E2AA000, approx to 1.0/6.0 in SP
 276 }
 277 { .mfi
 278       nop.m           0
 279       fnorm.s1        fNormX = f8           // normalized x
 280       addl            rExpHalf = 0xFFFE, r0 // exponent of 1/2
 281 }
 282 ;;
 283
 284 { .mfi
 285       setf.d          f64DivLn2 = r64DivLn2 // load 64/ln(2) to FP reg
 286       fclass.m        p15, p0 = f8, 0x1e1   // test for NaT,NaN,+Inf
 287       nop.i           0
 288 }
 289 { .mlx
 290       // load Right Shifter to FP reg
 291       setf.d          fRightShifter = rRightShifter
 292       movl            rLn2Div64 = 0x3F862E42FEFA39EF // DP ln(2)/64 in GR
 293 }
 294 ;;
 295
 296 { .mfi
 297       nop.m           0
 298       fcmp.eq.s1      p13, p0 = f0, f8      // test for x = 0.0
 299       nop.i           0
 300 }
 301 { .mfb
 302       setf.s          fA3 = rA3             // load A3 to FP reg
 303 (p14) fma.s.s0        f8 = f0, f1, f0       // result if x = -inf
 304 (p14) br.ret.spnt     b0                    // exit here if x = -inf
 305 }
 306 ;;
 307
 308 { .mfi
 309       setf.exp        fA2 = rExpHalf        // load A2 to FP reg
 310       fcmp.eq.s0      p6, p0 = f8, f0       // Dummy to flag denorm
 311       nop.i           0
 312 }
 313 { .mfb
 314       setf.d          fLn2Div64 = rLn2Div64 // load ln(2)/64 to FP reg
 315 (p15) fma.s.s0        f8 = f8, f1, f0       // result if x = NaT,NaN,+Inf
 316 (p15) br.ret.spnt     b0                    // exit here if x = NaT,NaN,+Inf
 317 }
 318 ;;
 319
 320 { .mfb
 321       // overflow and underflow_zero threshold
 322       ldfps           fMIN_SGL_OFLOW_ARG, fMAX_SGL_ZERO_ARG = [rTblAddr], 8
 323 (p13) fma.s.s0        f8 = f1, f1, f0       // result if x = 0.0
 324 (p13) br.ret.spnt     b0                    // exit here if x =0.0
 325 }
 326 ;;
 327
 328       // max normal and underflow_denorm threshold
 329 { .mfi
 330       ldfps           fMAX_SGL_NORM_ARG, fMIN_SGL_NORM_ARG = [rTblAddr], 8
 331       nop.f           0
 332       nop.i           0
 333 }
 334 ;;
 335
 336 { .mfi
 337       nop.m           0
 338       // x*(64/ln(2)) + Right Shifter
 339       fma.s1          fNint = fNormX, f64DivLn2, fRightShifter
 340       nop.i           0
 341 }
 342 ;;
 343
 344 // Divide arguments into the following categories:
 345 //  Certain Underflow       p11 - -inf < x <= MAX_SGL_ZERO_ARG
 346 //  Possible Underflow      p13 - MAX_SGL_ZERO_ARG < x < MIN_SGL_NORM_ARG
 347 //  Certain Safe                - MIN_SGL_NORM_ARG <= x <= MAX_SGL_NORM_ARG
 348 //  Possible Overflow       p14 - MAX_SGL_NORM_ARG < x < MIN_SGL_OFLOW_ARG
 349 //  Certain Overflow        p15 - MIN_SGL_OFLOW_ARG <= x < +inf
 350 //
 351 // If the input is really a single arg, then there will never be
 352 // "Possible Overflow" arguments.
 353 //
 354
 355 { .mfi
 356       nop.m           0
 357       // check for overflow
 358       fcmp.ge.s1      p15, p0 = fNormX, fMIN_SGL_OFLOW_ARG
 359       nop.i           0
 360 }
 361 ;;
 362
 363 { .mfi
 364       nop.m           0
 365       // check for underflow and tiny (+0) result
 366       fcmp.le.s1      p11, p0 = fNormX, fMAX_SGL_ZERO_ARG
 367       nop.i           0
 368 }
 369 { .mfb
 370       nop.m           0
 371       fms.s1          fN = fNint, f1, fRightShifter // n in FP register
 372       // branch out if overflow
 373 (p15) br.cond.spnt    EXP_CERTAIN_OVERFLOW
 374 }
 375 ;;
 376
 377 { .mfb
 378       getf.sig        rNJ = fNint           // bits of n, j
 379       // check for underflow and deno result
 380       fcmp.lt.s1      p13, p0 = fNormX, fMIN_SGL_NORM_ARG
 381       // branch out if underflow and tiny (+0) result
 382 (p11) br.cond.spnt    EXP_CERTAIN_UNDERFLOW
 383 }
 384 ;;
 385
 386 { .mfi
 387       nop.m           0
 388       // check for possible overflow
 389       fcmp.gt.s1      p14, p0 = fNormX, fMAX_SGL_NORM_ARG
 390       extr.u          rJ = rNJ, 0, 6        // bits of j
 391 }
 392 { .mfi
 393       addl            rN = 0xFFFF - 63, rNJ // biased and shifted n
 394       fnma.s1         fR = fLn2Div64, fN, fNormX // R = x - N*ln(2)/64
 395       nop.i           0
 396 }
 397 ;;
 398
 399 { .mfi
 400       shladd          rJ = rJ, 3, rTblAddr  // address in the 2^(j/64) table
 401       nop.f           0
 402       shr             rN = rN, 6            // biased n
 403 }
 404 ;;
 405
 406 { .mfi
 407       ld8             rJ = [rJ]
 408       nop.f           0
 409       shl             rN = rN, 52           // 2^n bits in DP format
 410 }
 411 ;;
 412
 413 { .mfi
 414       or              rN = rN, rJ // bits of 2^n * 2^(j/64) in DP format
 415       nop.f           0
 416       nop.i           0
 417 }
 418 ;;
 419
 420 { .mfi
 421       setf.d          fT = rN               // 2^n * 2^(j/64)
 422       fma.s1          fP = fA3, fR, fA2     // A3*R + A2
 423       nop.i           0
 424 }
 425 { .mfi
 426       nop.m           0
 427       fma.s1          fRSqr = fR, fR, f0    // R^2
 428       nop.i           0
 429 }
 430 ;;
 431
 432 { .mfi
 433       nop.m           0
 434       fma.s1          fP = fP, fRSqr, fR    // P = (A3*R + A2)*R^2 + R
 435       nop.i           0
 436 }
 437 ;;
 438
 439 { .mbb
 440       nop.m           0
 441       // branch out if possible underflow
 442 (p13) br.cond.spnt    EXP_POSSIBLE_UNDERFLOW
 443       // branch out if possible overflow result
 444 (p14) br.cond.spnt    EXP_POSSIBLE_OVERFLOW
 445 }
 446 ;;
 447
 448 { .mfb
 449       nop.m           0
 450       // final result in the absence of over- and underflow
 451       fma.s.s0        f8 = fP, fT, fT
 452       // exit here in the absence of over- and underflow
 453       br.ret.sptk     b0
 454 }
 455 ;;
 456
 457 EXP_POSSIBLE_OVERFLOW:
 458
 459 // Here if fMAX_SGL_NORM_ARG < x < fMIN_SGL_OFLOW_ARG
 460 // This cannot happen if input is a single, only if input higher precision.
 461 // Overflow is a possibility, not a certainty.
 462
 463 // Recompute result using status field 2 with user's rounding mode,
 464 // and wre set.  If result is larger than largest single, then we have
 465 // overflow
 466
 467 { .mfi
 468       mov             rGt_ln  = 0x1007f // Exponent for largest single + 1 ulp
 469       fsetc.s2        0x7F,0x42         // Get user's round mode, set wre
 470       nop.i           0
 471 }
 472 ;;
 473
 474 { .mfi
 475       setf.exp        fGt_pln = rGt_ln  // Create largest single + 1 ulp
 476       fma.s.s2        fWre_urm_f8 = fP, fT, fT    // Result with wre set
 477       nop.i           0
 478 }
 479 ;;
 480
 481 { .mfi
 482       nop.m           0
 483       fsetc.s2        0x7F,0x40                   // Turn off wre in sf2
 484       nop.i           0
 485 }
 486 ;;
 487
 488 { .mfi
 489       nop.m           0
 490       fcmp.ge.s1      p6, p0 =  fWre_urm_f8, fGt_pln // Test for overflow
 491       nop.i           0
 492 }
 493 ;;
 494
 495 { .mfb
 496       nop.m           0
 497       nop.f           0
 498 (p6)  br.cond.spnt    EXP_CERTAIN_OVERFLOW // Branch if overflow
 499 }
 500 ;;
 501
 502 { .mfb
 503       nop.m           0
 504       fma.s.s0        f8 = fP, fT, fT
 505       br.ret.sptk     b0                     // Exit if really no overflow
 506 }
 507 ;;
 508
 509 // here if overflow
 510 EXP_CERTAIN_OVERFLOW:
 511 { .mmi
 512       addl            r17ones_m1 = 0x1FFFE, r0
 513 ;;
 514       setf.exp        fTmp = r17ones_m1
 515       nop.i           0
 516 }
 517 ;;
 518
 519 { .mfi
 520       alloc           r32=ar.pfs,0,3,4,0
 521       fmerge.s        FR_X = f8,f8
 522       nop.i           0
 523 }
 524 { .mfb
 525       mov             GR_Parameter_TAG = 16
 526       fma.s.s0        FR_RESULT = fTmp, fTmp, fTmp // Set I,O and +INF result
 527       br.cond.sptk    __libm_error_region
 528 }
 529 ;;
 530
 531 EXP_POSSIBLE_UNDERFLOW:
 532
 533 // Here if fMAX_SGL_ZERO_ARG < x < fMIN_SGL_NORM_ARG
 534 // Underflow is a possibility, not a certainty
 535
 536 // We define an underflow when the answer with
 537 //    ftz set
 538 // is zero (tiny numbers become zero)
 539
 540 // Notice (from below) that if we have an unlimited exponent range,
 541 // then there is an extra machine number E between the largest denormal and
 542 // the smallest normal.
 543
 544 // So if with unbounded exponent we round to E or below, then we are
 545 // tiny and underflow has occurred.
 546
 547 // But notice that you can be in a situation where we are tiny, namely
 548 // rounded to E, but when the exponent is bounded we round to smallest
 549 // normal. So the answer can be the smallest normal with underflow.
 550
 551 //                           E
 552 // -----+--------------------+--------------------+-----
 553 //      |                    |                    |
 554 //   1.1...10 2^-3fff    1.1...11 2^-3fff    1.0...00 2^-3ffe
 555 //   0.1...11 2^-3ffe                                   (biased, 1)
 556 //    largest dn                               smallest normal
 557
 558 { .mfi
 559       nop.m           0
 560       fsetc.s2        0x7F,0x41                // Get user's round mode, set ftz
 561       nop.i           0
 562 }
 563 ;;
 564
 565 { .mfi
 566       nop.m           0
 567       fma.s.s2        fFtz_urm_f8 = fP, fT, fT // Result with ftz set
 568       nop.i           0
 569 }
 570 ;;
 571
 572 { .mfi
 573       nop.m           0
 574       fsetc.s2        0x7F,0x40                // Turn off ftz in sf2
 575       nop.i           0
 576 }
 577 ;;
 578
 579 { .mfi
 580       nop.m           0
 581       fcmp.eq.s1      p6, p7 = fFtz_urm_f8, f0 // Test for underflow
 582       nop.i           0
 583 }
 584 { .mfi
 585       nop.m           0
 586       fma.s.s0        f8 = fP, fT, fT          // Compute result, set I, maybe U
 587       nop.i           0
 588 }
 589 ;;
 590
 591 { .mbb
 592       nop.m           0
 593 (p6)  br.cond.spnt    EXP_UNDERFLOW_COMMON     // Branch if really underflow
 594 (p7)  br.ret.sptk     b0                       // Exit if really no underflow
 595 }
 596 ;;
 597
 598 EXP_CERTAIN_UNDERFLOW:
 599 // Here if  x < fMAX_SGL_ZERO_ARG
 600 // Result will be zero (or smallest denorm if round to +inf) with I, U set
 601 { .mmi
 602       mov             rTmp = 1
 603 ;;
 604       setf.exp        fTmp = rTmp               // Form small normal
 605       nop.i           0
 606 }
 607 ;;
 608
 609 { .mfi
 610       nop.m           0
 611       fmerge.se       fTmp = fTmp, f64DivLn2    // Small with non-trial signif
 612       nop.i           0
 613 }
 614 ;;
 615
 616 { .mfb
 617       nop.m           0
 618       fma.s.s0        f8 = fTmp, fTmp, f0 // Set I,U, tiny (+0.0) result
 619       br.cond.sptk    EXP_UNDERFLOW_COMMON
 620 }
 621 ;;
 622
 623 EXP_UNDERFLOW_COMMON:
 624 // Determine if underflow result is zero or nonzero
 625 { .mfi
 626       alloc           r32=ar.pfs,0,3,4,0
 627       fcmp.eq.s1      p6, p0 =  f8, f0
 628       nop.i           0
 629 }
 630 ;;
 631
 632 { .mfb
 633       nop.m           0
 634       fmerge.s        FR_X = fNormX,fNormX
 635 (p6)  br.cond.spnt    EXP_UNDERFLOW_ZERO
 636 }
 637 ;;
 638
 639 EXP_UNDERFLOW_NONZERO:
 640 // Here if  x < fMIN_SGL_NORM_ARG and result nonzero;
 641 // I, U are set
 642 { .mfb
 643       mov             GR_Parameter_TAG = 17
 644       nop.f           0                         // FR_RESULT already set
 645       br.cond.sptk    __libm_error_region
 646 }
 647 ;;
 648
 649 EXP_UNDERFLOW_ZERO:
 650 // Here if x < fMIN_SGL_NORM_ARG and result zero;
 651 // I, U are set
 652 { .mfb
 653       mov             GR_Parameter_TAG = 17
 654       nop.f           0                         // FR_RESULT already set
 655       br.cond.sptk    __libm_error_region
 656 }
 657 ;;
 658
 659 GLOBAL_IEEE754_END(expf)
 660
 661
 662 LOCAL_LIBM_ENTRY(__libm_error_region)
 663 .prologue
 664 { .mfi
 665       add   GR_Parameter_Y=-32,sp             // Parameter 2 value
 666       nop.f 0
 667 .save   ar.pfs,GR_SAVE_PFS
 668       mov  GR_SAVE_PFS=ar.pfs                 // Save ar.pfs
 669 }
 670 { .mfi
 671 .fframe 64
 672       add sp=-64,sp                           // Create new stack
 673       nop.f 0
 674       mov GR_SAVE_GP=gp                       // Save gp
 675 };;
 676 { .mmi
 677       stfs [GR_Parameter_Y] = FR_Y,16         // Store Parameter 2 on stack
 678       add GR_Parameter_X = 16,sp              // Parameter 1 address
 679 .save   b0, GR_SAVE_B0
 680       mov GR_SAVE_B0=b0                       // Save b0
 681 };;
 682 .body
 683 { .mfi
 684       stfs [GR_Parameter_X] = FR_X            // Store Parameter 1 on stack
 685       nop.f 0
 686       add   GR_Parameter_RESULT = 0,GR_Parameter_Y // Parameter 3 address
 687 }
 688 { .mib
 689       stfs [GR_Parameter_Y] = FR_RESULT       // Store Parameter 3 on stack
 690       add   GR_Parameter_Y = -16,GR_Parameter_Y
 691       br.call.sptk b0=__libm_error_support#   // Call error handling function
 692 };;
 693
 694 { .mmi
 695       add   GR_Parameter_RESULT = 48,sp
 696       nop.m 0
 697       nop.i 0
 698 };;
 699
 700 { .mmi
 701       ldfs  f8 = [GR_Parameter_RESULT]       // Get return result off stack
 702 .restore sp
 703       add   sp = 64,sp                       // Restore stack pointer
 704       mov   b0 = GR_SAVE_B0                  // Restore return address
 705 };;
 706 { .mib
 707       mov   gp = GR_SAVE_GP                  // Restore gp
 708       mov   ar.pfs = GR_SAVE_PFS             // Restore ar.pfs
 709       br.ret.sptk     b0                     // Return
 710 };;
 711
 712 LOCAL_LIBM_END(__libm_error_region)
 713
 714
 715 .type   __libm_error_support#,@function
 716 .global __libm_error_support#