sysdeps/ia64/fpu/e_exp2f.S

   1 .file "exp2f.s"
   2
   3
   4 // Copyright (c) 2000 - 2005, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  39 //
  40 // History
  41 //==============================================================
  42 // 08/25/00  Initial version
  43 // 05/20/02  Cleaned up namespace and sf0 syntax
  44 // 09/05/02  Improved performance and accuracy
  45 // 01/17/03  Fixed to call error support when x=128.0
  46 // 03/31/05  Reformatted delimiters between data tables
  47 //
  48 // API
  49 //==============================================================
  50 // float exp2f(float)
  51 //
  52 // Overview of operation
  53 //==============================================================
  54 // Background
  55 //
  56 // Implementation
  57 //
  58 // Let x= (K + fh + fl + r), where
  59 // K is an integer, fh= 0.b1 b2 b3 b4 b5,
  60 // fl= 2^{-5}* 0.b6 b7 b8 b8 b10 (fh, fl >= 0),
  61 // and |r|<2^{-11}
  62 // Th is a table that stores 2^fh (32 entries) rounded to
  63 // double extended precision (only mantissa is stored)
  64 // Tl is a table that stores 2^fl (32 entries) rounded to
  65 // double extended precision (only mantissa is stored)
  66 //
  67 // 2^x is approximated as
  68 // 2^K * Th [ f ] * Tl [ f ] * (1+c1*r+c2*r^2)
  69
  70 // Note: We use the following trick to speed up conversion from FP to integer:
  71 //
  72 // Let  x = K + r, where K is an integer, and  |r| <= 0.5
  73 // Let N be the number of significand bits for the FP format used
  74 //   ( N=64 for double-extended, N=53 for double)
  75 //
  76 // Then let y = 1.5 * 2^(N-1)  +  x    for RN mode
  77 //          K = y -  1.5 * 2^(N-1)
  78 //          r  = x - K
  79 //
  80 // If we want to obtain the integer part and the first m fractional bits of x,
  81 // we can use the same trick, but with a constant of  1.5 * 2^(N-1-m):
  82 //
  83 // Let x = K + f + r
  84 // f = 0.b_1 b_2 ... b_m
  85 // |r| <= 2^(-m-1)
  86 //
  87 // Then let y = 1.5 * 2^(N-1-m)  +  x    for RN mode
  88 //          (K+f) = y -  1.5 * 2^(N-1-m)
  89 //          r  = x - K
  90
  91
  92 // Special values
  93 //==============================================================
  94 // exp2(0)= 1
  95 // exp2(+inf)= inf
  96 // exp2(-inf)= 0
  97 //
  98
  99 // Registers used
 100 //==============================================================
 101 // r2-r3, r14-r40
 102 // f6-f15, f32-f45
 103 // p6-p8, p12
 104 //
 105
 106
 107 GR_TBL_START        = r2
 108 GR_LOG_TBL          = r3
 109
 110 GR_OF_LIMIT         = r14
 111 GR_UF_LIMIT         = r15
 112 GR_EXP_CORR         = r16
 113 GR_F_low            = r17
 114 GR_F_high           = r18
 115 GR_K                = r19
 116 GR_Flow_ADDR        = r20
 117
 118 GR_BIAS             = r21
 119 GR_Fh               = r22
 120 GR_Fh_ADDR          = r23
 121 GR_EXPMAX           = r24
 122 GR_EMIN             = r25
 123
 124 GR_ROUNDVAL         = r26
 125 GR_MASK             = r27
 126 GR_KF0              = r28
 127 GR_MASK_low         = r29
 128 GR_COEFF_START      = r30
 129
 130 GR_SAVE_B0          = r33
 131 GR_SAVE_PFS         = r34
 132 GR_SAVE_GP          = r35
 133 GR_SAVE_SP          = r36
 134
 135 GR_Parameter_X      = r37
 136 GR_Parameter_Y      = r38
 137 GR_Parameter_RESULT = r39
 138 GR_Parameter_TAG    = r40
 139
 140
 141 FR_X                = f10
 142 FR_Y                = f1
 143 FR_RESULT           = f8
 144
 145
 146 FR_COEFF1           = f6
 147 FR_COEFF2           = f7
 148 FR_R                = f9
 149
 150 FR_KF0              = f12
 151 FR_UF_LIMIT         = f15
 152
 153 FR_OF_LIMIT         = f32
 154 FR_EXPMIN           = f33
 155 FR_ROUNDVAL         = f34
 156 FR_KF               = f35
 157
 158 FR_2_TO_K           = f36
 159 FR_T_low            = f37
 160 FR_T_high           = f38
 161
 162 FR_P12              = f41
 163 FR_T_low_K          = f42
 164 FR_T                = f44
 165 FR_P                = f45
 166
 167
 168 // Data tables
 169 //==============================================================
 170
 171 RODATA
 172
 173 .align 16
 174
 175 LOCAL_OBJECT_START(poly_coeffs)
 176
 177 data8 0xb17217f7d1cf79ab, 0x00003ffe // C_1
 178 data8 0xf5fdeffc162c7541, 0x00003ffc // C_2
 179 LOCAL_OBJECT_END(poly_coeffs)
 180
 181
 182 LOCAL_OBJECT_START(T_table)
 183
 184 // 2^{0.00000 b6 b7 b8 b9 b10}
 185 data8 0x8000000000000000, 0x8016302f17467628
 186 data8 0x802c6436d0e04f50, 0x80429c17d77c18ed
 187 data8 0x8058d7d2d5e5f6b0, 0x806f17687707a7af
 188 data8 0x80855ad965e88b83, 0x809ba2264dada76a
 189 data8 0x80b1ed4fd999ab6c, 0x80c83c56b50cf77f
 190 data8 0x80de8f3b8b85a0af, 0x80f4e5ff089f763e
 191 data8 0x810b40a1d81406d4, 0x81219f24a5baa59d
 192 data8 0x813801881d886f7b, 0x814e67cceb90502c
 193 data8 0x8164d1f3bc030773, 0x817b3ffd3b2f2e47
 194 data8 0x8191b1ea15813bfd, 0x81a827baf7838b78
 195 data8 0x81bea1708dde6055, 0x81d51f0b8557ec1c
 196 data8 0x81eba08c8ad4536f, 0x820225f44b55b33b
 197 data8 0x8218af4373fc25eb, 0x822f3c7ab205c89a
 198 data8 0x8245cd9ab2cec048, 0x825c62a423d13f0c
 199 data8 0x8272fb97b2a5894c, 0x828998760d01faf3
 200 data8 0x82a0393fe0bb0ca8, 0x82b6ddf5dbc35906
 201 //
 202 // 2^{0.b1 b2 b3 b4 b5}
 203 data8 0x8000000000000000, 0x82cd8698ac2ba1d7
 204 data8 0x85aac367cc487b14, 0x88980e8092da8527
 205 data8 0x8b95c1e3ea8bd6e6, 0x8ea4398b45cd53c0
 206 data8 0x91c3d373ab11c336, 0x94f4efa8fef70961
 207 data8 0x9837f0518db8a96f, 0x9b8d39b9d54e5538
 208 data8 0x9ef5326091a111ad, 0xa27043030c496818
 209 data8 0xa5fed6a9b15138ea, 0xa9a15ab4ea7c0ef8
 210 data8 0xad583eea42a14ac6, 0xb123f581d2ac258f
 211 data8 0xb504f333f9de6484, 0xb8fbaf4762fb9ee9
 212 data8 0xbd08a39f580c36be, 0xc12c4cca66709456
 213 data8 0xc5672a115506dadd, 0xc9b9bd866e2f27a2
 214 data8 0xce248c151f8480e3, 0xd2a81d91f12ae45a
 215 data8 0xd744fccad69d6af4, 0xdbfbb797daf23755
 216 data8 0xe0ccdeec2a94e111, 0xe5b906e77c8348a8
 217 data8 0xeac0c6e7dd24392e, 0xefe4b99bdcdaf5cb
 218 data8 0xf5257d152486cc2c, 0xfa83b2db722a033a
 219 LOCAL_OBJECT_END(T_table)
 220
 221
 222
 223 .section .text
 224 GLOBAL_LIBM_ENTRY(exp2f)
 225
 226
 227 {.mfi
 228        alloc r32= ar.pfs, 1, 4, 4, 0
 229        // will continue only for non-zero normal/denormal numbers
 230        fclass.nm p12, p0= f8, 0x1b
 231        // GR_TBL_START= pointer to C_1...C_2 followed by T_table
 232        addl GR_TBL_START= @ltoff(poly_coeffs), gp
 233 }
 234 {.mlx
 235        mov GR_OF_LIMIT= 0xffff + 7               // Exponent of overflow limit
 236        movl GR_ROUNDVAL= 0x5a400000              // 1.5*2^(63-10) (SP)
 237 }
 238 ;;
 239
 240 // Form special constant 1.5*2^(63-10) to give integer part and first 10
 241 // fractional bits of x
 242 {.mfi
 243        setf.s FR_ROUNDVAL= GR_ROUNDVAL           // Form special constant
 244        fcmp.lt.s1 p6, p8= f8, f0                 // X<0 ?
 245        nop.i 0
 246 }
 247 {.mfb
 248        ld8 GR_COEFF_START= [ GR_TBL_START ]      // Load pointer to coeff table
 249        nop.f 0
 250  (p12) br.cond.spnt SPECIAL_exp2                 // Branch if nan, inf, zero
 251 }
 252 ;;
 253
 254 {.mlx
 255        setf.exp FR_OF_LIMIT= GR_OF_LIMIT         // Set overflow limit
 256        movl GR_UF_LIMIT= 0xc3160000              // (-2^7-22) = -150
 257 }
 258 ;;
 259
 260 {.mfi
 261        ldfe FR_COEFF1= [ GR_COEFF_START ], 16    // load C_1
 262        fma.s0 f8= f8, f1, f0                     // normalize x
 263        nop.i 0
 264 }
 265 ;;
 266
 267 {.mmi
 268        ldfe FR_COEFF2= [ GR_COEFF_START ], 16    // load C_2
 269        setf.s FR_UF_LIMIT= GR_UF_LIMIT           // Set underflow limit
 270        mov GR_EXP_CORR= 0xffff-126
 271 }
 272 ;;
 273
 274 {.mfi
 275        nop.m 0
 276        fma.s1 FR_KF0= f8, f1, FR_ROUNDVAL        // y= x + 1.5*2^(63-10)
 277        nop.i 0
 278 }
 279 ;;
 280
 281 {.mfi
 282        mov GR_MASK= 1023
 283        fms.s1 FR_KF= FR_KF0, f1, FR_ROUNDVAL     // (K+f)
 284        mov GR_MASK_low= 31
 285 }
 286 ;;
 287
 288 {.mfi
 289        getf.sig GR_KF0= FR_KF0                   // (K+f)*2^10= round_to_int(y)
 290        fcmp.ge.s1 p12, p7= f8, FR_OF_LIMIT       // x >= overflow threshold ?
 291        add GR_LOG_TBL= 256, GR_COEFF_START       // Pointer to high T_table
 292 }
 293 ;;
 294
 295 {.mmi
 296        and GR_F_low= GR_KF0, GR_MASK_low         // f_low
 297        and GR_F_high= GR_MASK, GR_KF0            // f_high*32
 298        shr GR_K= GR_KF0, 10                      // K
 299 }
 300 ;;
 301
 302 {.mmi
 303        shladd GR_Flow_ADDR= GR_F_low, 3, GR_COEFF_START // address of 2^{f_low}
 304        add GR_BIAS= GR_K, GR_EXP_CORR            // K= bias-2*63
 305        shr GR_Fh= GR_F_high, 5                   // f_high
 306 }
 307 ;;
 308
 309 {.mfi
 310        setf.exp FR_2_TO_K= GR_BIAS               // 2^{K-126}
 311        fnma.s1 FR_R= FR_KF, f1, f8               // r= x - (K+f)
 312        shladd GR_Fh_ADDR= GR_Fh, 3, GR_LOG_TBL   // address of 2^{f_high}
 313 }
 314 {.mlx
 315        ldf8 FR_T_low= [ GR_Flow_ADDR ]           // load T_low= 2^{f_low}
 316        movl GR_EMIN= 0xc2fc0000                  // EMIN= -126
 317 }
 318 ;;
 319
 320 {.mfi
 321        ldf8 FR_T_high= [ GR_Fh_ADDR ]            // load T_high= 2^{f_high}
 322  (p7)  fcmp.lt.s1 p12, p7= f8, FR_UF_LIMIT       // x<underflow threshold ?
 323        nop.i 0
 324 }
 325 ;;
 326
 327 {.mfb
 328        setf.s FR_EXPMIN= GR_EMIN                 // FR_EXPMIN= EMIN
 329        fma.s1 FR_P12= FR_COEFF2, FR_R, FR_COEFF1 // P12= C_1+C_2*r
 330  (p12) br.cond.spnt OUT_RANGE_exp2
 331 }
 332 ;;
 333
 334 {.mfi
 335        nop.m 0
 336        fma.s1 FR_T_low_K= FR_T_low, FR_2_TO_K, f0 // T= 2^{K-126}*T_low
 337        nop.i 0
 338 }
 339 ;;
 340
 341 {.mfi
 342        nop.m 0
 343        fma.s1 FR_P= FR_R, FR_P12, f0              // P= P12+r
 344        nop.i 0
 345 }
 346 ;;
 347
 348 {.mfi
 349        nop.m 0
 350        fma.s1 FR_T= FR_T_low_K, FR_T_high, f0     // T= T*T_high
 351        nop.i 0
 352 }
 353 ;;
 354
 355 {.mfi
 356        nop.m 0
 357        fcmp.lt.s0 p6, p8= f8, FR_EXPMIN           // underflow (x<EMIN) ?
 358        nop.i 0
 359 }
 360 ;;
 361
 362 {.mfb
 363        nop.m 0
 364        fma.s.s0 f8= FR_P, FR_T, FR_T              // result= T+T*P
 365  (p8)  br.ret.sptk b0                             // return
 366 }
 367 ;;
 368
 369 {.mfb
 370  (p6)  mov GR_Parameter_TAG= 164
 371        nop.f 0
 372  (p6)  br.cond.sptk __libm_error_region
 373 }
 374 ;;
 375
 376
 377 SPECIAL_exp2:
 378 {.mfi
 379        nop.m 0
 380        fclass.m p6, p0= f8, 0x22                  // x= -Infinity ?
 381        nop.i 0
 382 }
 383 ;;
 384
 385 {.mfi
 386        nop.m 0
 387        fclass.m p7, p0= f8, 0x21                  // x= +Infinity ?
 388        nop.i 0
 389 }
 390 ;;
 391
 392 {.mfi
 393        nop.m 0
 394        fclass.m p8, p0= f8, 0x7                   // x= +/-Zero ?
 395        nop.i 0
 396 }
 397 {.mfb
 398        nop.m 0
 399  (p6)  mov f8= f0                                 // exp2(-Infinity)= 0
 400  (p6)  br.ret.spnt b0
 401 }
 402 ;;
 403
 404 {.mfb
 405        nop.m 0
 406        nop.f 0
 407  (p7)  br.ret.spnt b0                             // exp2(+Infinity)= +Infinity
 408 }
 409 ;;
 410
 411 {.mfb
 412        nop.m 0
 413  (p8)  mov f8= f1                                 // exp2(+/-0)= 1
 414  (p8)  br.ret.spnt b0
 415 }
 416 ;;
 417
 418 {.mfb
 419        nop.m 0
 420        fma.s.s0 f8= f8, f1, f0                    // Remaining cases: NaNs
 421        br.ret.sptk b0
 422 }
 423 ;;
 424
 425
 426 OUT_RANGE_exp2:
 427
 428 // overflow: p8= 1
 429
 430 {.mii
 431  (p8)  mov GR_EXPMAX= 0x1fffe
 432        nop.i 0
 433        nop.i 0
 434 }
 435 ;;
 436
 437 {.mmb
 438  (p8)  mov GR_Parameter_TAG= 163
 439  (p8)  setf.exp FR_R= GR_EXPMAX
 440        nop.b 999
 441 }
 442 ;;
 443
 444 {.mfi
 445        nop.m 999
 446  (p8)  fma.s.s0 f8= FR_R, FR_R, f0                // Create overflow
 447        nop.i 999
 448 }
 449 // underflow: p6= 1
 450 {.mii
 451  (p6)  mov GR_Parameter_TAG= 164
 452  (p6)  mov GR_EXPMAX= 1
 453        nop.i 0
 454 }
 455 ;;
 456
 457 {.mmb
 458        nop.m 0
 459  (p6)  setf.exp FR_R= GR_EXPMAX
 460        nop.b 999
 461 }
 462 ;;
 463
 464 {.mfb
 465        nop.m 999
 466  (p6)  fma.s.s0 f8= FR_R, FR_R, f0                // Create underflow
 467        nop.b 0
 468 }
 469 ;;
 470
 471 GLOBAL_LIBM_END(exp2f)
 472
 473
 474 LOCAL_LIBM_ENTRY(__libm_error_region)
 475
 476 .prologue
 477 {.mfi
 478        add GR_Parameter_Y= -32, sp                // Parameter 2 value
 479        nop.f 0
 480 .save ar.pfs, GR_SAVE_PFS
 481        mov GR_SAVE_PFS= ar.pfs                    // Save ar.pfs
 482 }
 483
 484 {.mfi
 485 .fframe 64
 486        add sp= -64, sp                            // Create new stack
 487        nop.f 0
 488        mov GR_SAVE_GP= gp                         // Save gp
 489 }
 490 ;;
 491
 492 {.mmi
 493        stfs [ GR_Parameter_Y ]= FR_Y, 16          // STORE Parameter 2 on stack
 494        add GR_Parameter_X= 16, sp                 // Parameter 1 address
 495 .save b0, GR_SAVE_B0
 496        mov GR_SAVE_B0= b0                         // Save b0
 497 }
 498 ;;
 499
 500 .body
 501 {.mib
 502        stfs [ GR_Parameter_X ]= FR_X              // STORE Parameter 1 on stack
 503        add GR_Parameter_RESULT= 0, GR_Parameter_Y // Parameter 3 address
 504        nop.b 0
 505 }
 506 {.mib
 507        stfs [ GR_Parameter_Y ]= FR_RESULT         // STORE Parameter 3 on stack
 508        add GR_Parameter_Y= -16, GR_Parameter_Y
 509        br.call.sptk b0= __libm_error_support#    // Call error handling function
 510 }
 511 ;;
 512
 513 {.mmi
 514        add GR_Parameter_RESULT= 48, sp
 515        nop.m 0
 516        nop.i 0
 517 }
 518 ;;
 519
 520 {.mmi
 521        ldfs f8= [ GR_Parameter_RESULT ]          // Get return result off stack
 522 .restore sp
 523        add sp= 64, sp                            // Restore stack pointer
 524        mov b0= GR_SAVE_B0                        // Restore return address
 525 }
 526 ;;
 527
 528 {.mib
 529        mov gp= GR_SAVE_GP                        // Restore gp
 530        mov ar.pfs= GR_SAVE_PFS                   // Restore ar.pfs
 531        br.ret.sptk b0                            // Return
 532 }
 533 ;;
 534
 535
 536 LOCAL_LIBM_END(__libm_error_region)
 537
 538 .type __libm_error_support#, @function
 539 .global __libm_error_support#