| blob | fa54e9039faae19da5d420added462fd33116b65 |
1 .file "exp10f.s"
4 // Copyright (c) 2000 - 2005, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
39 //
40 // History
41 //==============================================================
42 // 08/25/00 Initial version
43 // 05/20/02 Cleaned up namespace and sf0 syntax
44 // 09/06/02 Improved performance and accuracy; no inexact flags on exact cases
45 // 01/29/03 Added missing } to bundle templates
46 // 12/16/04 Call error handling on underflow.
47 // 03/31/05 Reformatted delimiters between data tables
48 //
49 // API
50 //==============================================================
51 // float exp10f(float)
52 //
53 // Overview of operation
54 //==============================================================
55 // Background
56 //
57 // Implementation
58 //
59 // Let x= (K + fh + fl + r)/log2(10), where
60 // K is an integer, fh= 0.b1 b2 b3 b4 b5,
61 // fl= 2^{-5}* 0.b6 b7 b8 b8 b10 (fh, fl >= 0),
62 // and |r|<2^{-11}
63 // Th is a table that stores 2^fh (32 entries) rounded to
64 // double extended precision (only mantissa is stored)
65 // Tl is a table that stores 2^fl (32 entries) rounded to
66 // double extended precision (only mantissa is stored)
67 //
68 // 10^x is approximated as
69 // 2^K * Th [ f ] * Tl [ f ] * (1+c1*r+c2*r^2)
71 // Note there are only 10 non-zero values that produce an exact result:
72 // 1.0, 2.0, ... 10.0.
73 // We test for these cases and use s1 to avoid setting the inexact flag.
75 // Special values
76 //==============================================================
77 // exp10(0)= 1
78 // exp10(+inf)= inf
79 // exp10(-inf)= 0
80 //
82 // Registers used
83 //==============================================================
84 // r2-r3, r14-r40
85 // f6-f15, f32-f52
86 // p6-p12
87 //
90 GR_TBL_START = r2
91 GR_LOG_TBL = r3
93 GR_OF_LIMIT = r14
94 GR_UF_LIMIT = r15
95 GR_EXP_CORR = r16
96 GR_F_low = r17
97 GR_F_high = r18
98 GR_K = r19
99 GR_Flow_ADDR = r20
101 GR_BIAS = r21
102 GR_Fh = r22
103 GR_Fh_ADDR = r23
104 GR_EXPMAX = r24
106 GR_ROUNDVAL = r26
107 GR_SNORM_LIMIT = r26
108 GR_MASK = r27
109 GR_KF0 = r28
110 GR_MASK_low = r29
111 GR_COEFF_START = r30
112 GR_exact_limit = r31
114 GR_SAVE_B0 = r33
115 GR_SAVE_PFS = r34
116 GR_SAVE_GP = r35
117 GR_SAVE_SP = r36
119 GR_Parameter_X = r37
120 GR_Parameter_Y = r38
121 GR_Parameter_RESULT = r39
122 GR_Parameter_TAG = r40
125 FR_X = f10
126 FR_Y = f1
127 FR_RESULT = f8
130 FR_COEFF1 = f6
131 FR_COEFF2 = f7
132 FR_R = f9
133 FR_LOG2_10 = f10
135 FR_2P53 = f11
136 FR_KF0 = f12
137 FR_COEFF3 = f13
138 FR_COEFF4 = f14
139 FR_UF_LIMIT = f15
141 FR_OF_LIMIT = f32
142 FR_DX_L210 = f33
143 FR_ROUNDVAL = f34
144 FR_KF = f35
146 FR_2_TO_K = f36
147 FR_T_low = f37
148 FR_T_high = f38
150 FR_P12 = f41
151 FR_T_low_K = f42
152 FR_T = f44
153 FR_P = f45
155 FR_E = f49
156 FR_exact_limit = f50
158 FR_int_x = f51
159 FR_SNORM_LIMIT = f52
162 // Data tables
163 //==============================================================
165 RODATA
167 .align 16
169 LOCAL_OBJECT_START(poly_coeffs)
171 data8 0xd49a784bcd1b8afe, 0x00003fcb // log2(10)*2^(10-63)
172 data8 0xb17217f7d1cf79ab, 0x00004033 // C_1 * 2^53
173 data8 0xf5fdeffc162c7541, 0x00004066 // C_2 * 2^106
174 LOCAL_OBJECT_END(poly_coeffs)
177 LOCAL_OBJECT_START(T_table)
179 // 2^{0.00000 b6 b7 b8 b9 b10}
180 data8 0x8000000000000000, 0x8016302f17467628
181 data8 0x802c6436d0e04f50, 0x80429c17d77c18ed
182 data8 0x8058d7d2d5e5f6b0, 0x806f17687707a7af
183 data8 0x80855ad965e88b83, 0x809ba2264dada76a
184 data8 0x80b1ed4fd999ab6c, 0x80c83c56b50cf77f
185 data8 0x80de8f3b8b85a0af, 0x80f4e5ff089f763e
186 data8 0x810b40a1d81406d4, 0x81219f24a5baa59d
187 data8 0x813801881d886f7b, 0x814e67cceb90502c
188 data8 0x8164d1f3bc030773, 0x817b3ffd3b2f2e47
189 data8 0x8191b1ea15813bfd, 0x81a827baf7838b78
190 data8 0x81bea1708dde6055, 0x81d51f0b8557ec1c
191 data8 0x81eba08c8ad4536f, 0x820225f44b55b33b
192 data8 0x8218af4373fc25eb, 0x822f3c7ab205c89a
193 data8 0x8245cd9ab2cec048, 0x825c62a423d13f0c
194 data8 0x8272fb97b2a5894c, 0x828998760d01faf3
195 data8 0x82a0393fe0bb0ca8, 0x82b6ddf5dbc35906
196 //
197 // 2^{0.b1 b2 b3 b4 b5}
198 data8 0x8000000000000000, 0x82cd8698ac2ba1d7
199 data8 0x85aac367cc487b14, 0x88980e8092da8527
200 data8 0x8b95c1e3ea8bd6e6, 0x8ea4398b45cd53c0
201 data8 0x91c3d373ab11c336, 0x94f4efa8fef70961
202 data8 0x9837f0518db8a96f, 0x9b8d39b9d54e5538
203 data8 0x9ef5326091a111ad, 0xa27043030c496818
204 data8 0xa5fed6a9b15138ea, 0xa9a15ab4ea7c0ef8
205 data8 0xad583eea42a14ac6, 0xb123f581d2ac258f
206 data8 0xb504f333f9de6484, 0xb8fbaf4762fb9ee9
207 data8 0xbd08a39f580c36be, 0xc12c4cca66709456
208 data8 0xc5672a115506dadd, 0xc9b9bd866e2f27a2
209 data8 0xce248c151f8480e3, 0xd2a81d91f12ae45a
210 data8 0xd744fccad69d6af4, 0xdbfbb797daf23755
211 data8 0xe0ccdeec2a94e111, 0xe5b906e77c8348a8
212 data8 0xeac0c6e7dd24392e, 0xefe4b99bdcdaf5cb
213 data8 0xf5257d152486cc2c, 0xfa83b2db722a033a
214 LOCAL_OBJECT_END(T_table)
218 .section .text
219 GLOBAL_IEEE754_ENTRY(exp10f)
222 {.mfi
223 alloc r32= ar.pfs, 1, 4, 4, 0
224 // will continue only for non-zero normal/denormal numbers
225 fclass.nm.unc p12, p7= f8, 0x1b
226 nop.i 0
227 }
228 {.mlx
229 // GR_TBL_START= pointer to log2(10), C_1...C_4 followed by T_table
230 addl GR_TBL_START= @ltoff(poly_coeffs), gp
231 movl GR_ROUNDVAL= 0x3fc00000 // 1.5 (SP)
232 }
233 ;;
235 {.mfi
236 ld8 GR_COEFF_START= [ GR_TBL_START ] // Load pointer to coeff table
237 fcmp.lt.s1 p6, p8= f8, f0 // X<0 ?
238 nop.i 0
239 }
240 ;;
242 {.mlx
243 nop.m 0
244 movl GR_UF_LIMIT= 0xc2349e35 // (-2^7-22) / log2(10)
245 }
246 {.mlx
247 setf.s FR_ROUNDVAL= GR_ROUNDVAL
248 movl GR_OF_LIMIT= 0x421a209a // Overflow threshold
249 }
250 ;;
252 {.mlx
253 ldfe FR_LOG2_10= [ GR_COEFF_START ], 16 // load log2(10)*2^(10-63)
254 movl GR_SNORM_LIMIT= 0xc217b818 // Smallest normal threshold
255 }
256 {.mib
257 nop.m 0
258 nop.i 0
259 (p12) br.cond.spnt SPECIAL_exp10 // Branch if nan, inf, zero
260 }
261 ;;
263 {.mfi
264 setf.s FR_OF_LIMIT= GR_OF_LIMIT // Set overflow limit
265 fma.s0 f8= f8, f1, f0 // normalize x
266 nop.i 0
267 }
268 ;;
270 {.mfi
271 setf.s FR_SNORM_LIMIT= GR_SNORM_LIMIT // Set smallest normal limit
272 (p8) fcvt.fx.s1 FR_int_x = f8 // Convert x to integer
273 nop.i 0
274 }
275 {.mfi
276 setf.s FR_UF_LIMIT= GR_UF_LIMIT // Set underflow limit
277 fma.s1 FR_KF0= f8, FR_LOG2_10, FR_ROUNDVAL // y= (x*log2(10)*2^10 +
278 // 1.5*2^63) * 2^(-63)
279 mov GR_EXP_CORR= 0xffff-126
280 }
281 ;;
283 {.mfi
284 ldfe FR_COEFF1= [ GR_COEFF_START ], 16 // load C_1
285 fms.s1 FR_KF= FR_KF0, f1, FR_ROUNDVAL // (K+f)*2^(10-63)
286 mov GR_MASK= 1023
287 }
288 ;;
290 {.mfi
291 ldfe FR_COEFF2= [ GR_COEFF_START ], 16 // load C_2
292 nop.f 0
293 mov GR_MASK_low= 31
294 }
295 ;;
297 {.mlx
298 getf.sig GR_KF0= FR_KF0 // (K+f)*2^10= round_to_int(y)
299 (p8) movl GR_exact_limit= 0x41200000 // Largest x for exact result,
300 // +10.0
301 }
302 ;;
304 {.mfi
305 add GR_LOG_TBL= 256, GR_COEFF_START // Pointer to high T_table
306 fcmp.gt.s1 p12, p7= f8, FR_OF_LIMIT // x>overflow threshold ?
307 nop.i 0
308 }
309 ;;
311 {.mfi
312 (p8) setf.s FR_exact_limit = GR_exact_limit // Largest x for exact result
313 (p8) fcvt.xf FR_int_x = FR_int_x // Integral part of x
314 shr GR_K= GR_KF0, 10 // K
315 }
316 {.mfi
317 and GR_F_high= GR_MASK, GR_KF0 // f_high*32
318 fms.s1 FR_R= f8, FR_LOG2_10, FR_KF // r*2^(-53)= [ x*log2(10)-
319 // (K+f) ] *2^{10-63}
320 and GR_F_low= GR_KF0, GR_MASK_low // f_low
321 }
322 ;;
324 {.mmi
325 shladd GR_Flow_ADDR= GR_F_low, 3, GR_COEFF_START // address of 2^{f_low}
326 add GR_BIAS= GR_K, GR_EXP_CORR // K= bias-2*63
327 shr GR_Fh= GR_F_high, 5 // f_high
328 }
329 ;;
331 {.mfi
332 setf.exp FR_2_TO_K= GR_BIAS // 2^{K-126}
333 (p7) fcmp.lt.s1 p12, p7= f8, FR_UF_LIMIT // x<underflow threshold ?
334 shladd GR_Fh_ADDR= GR_Fh, 3, GR_LOG_TBL // address of 2^{f_high}
335 }
336 {.mfi
337 ldf8 FR_T_low= [ GR_Flow_ADDR ] // load T_low= 2^{f_low}
338 nop.f 0
339 nop.i 0
340 }
341 ;;
343 {.mfb
344 ldf8 FR_T_high= [ GR_Fh_ADDR ] // load T_high= 2^{f_high}
345 fcmp.ge.s1 p11, p0= f8, FR_SNORM_LIMIT // Test x for normal range
346 (p12) br.cond.spnt OUT_RANGE_exp10
347 }
348 ;;
350 {.mfi
351 nop.m 0
352 fma.s1 FR_P12= FR_COEFF2, FR_R, FR_COEFF1 // P12= C_1+C_2*r
353 cmp.eq p7,p9= r0,r0 // Assume inexact result
354 }
355 ;;
357 {.mfi
358 nop.m 0
359 (p8) fcmp.eq.s1 p9,p7= FR_int_x, f8 // Test x positive integer
360 nop.i 0
361 }
362 {.mfi
363 nop.m 0
364 fma.s1 FR_T_low_K= FR_T_low, FR_2_TO_K, f0 // T= 2^{K-126}*T_low
365 nop.i 0
366 }
367 ;;
369 {.mfi
370 nop.m 0
371 fma.s1 FR_P= FR_P12, FR_R, f0 // P= P12*r
372 nop.i 0
373 }
374 ;;
376 // If x a positive integer, will it produce an exact result?
377 // p7 result will be inexact
378 // p9 result will be exact
379 {.mfi
380 nop.m 0
381 (p9) fcmp.le.s1 p9,p7= f8, FR_exact_limit // Test x gives exact result
382 nop.i 0
383 }
384 {.mfi
385 nop.m 0
386 fma.s1 FR_T= FR_T_low_K, FR_T_high, f0 // T= T*T_high
387 nop.i 0
388 }
389 ;;
391 .pred.rel "mutex",p7,p9
392 {.mfi
393 nop.m 0
394 (p7) fma.s.s0 f8= FR_P, FR_T, FR_T // result= T+T*P, inexact set
395 nop.i 0
396 }
397 {.mfb
398 nop.m 0
399 (p9) fma.s.s1 f8= FR_P, FR_T, FR_T // result= T+T*P, exact use s1
400 (p11) br.ret.sptk b0 // return, if result normal
401 }
402 ;;
404 // Here if result in denormal range (and not zero)
405 {.mib
406 nop.m 0
407 mov GR_Parameter_TAG= 266
408 br.cond.sptk __libm_error_region // Branch to error handling
409 }
410 ;;
412 SPECIAL_exp10:
413 {.mfi
414 nop.m 0
415 fclass.m p6, p0= f8, 0x22 // x= -Infinity ?
416 nop.i 0
417 }
418 ;;
420 {.mfi
421 nop.m 0
422 fclass.m p7, p0= f8, 0x21 // x= +Infinity ?
423 nop.i 0
424 }
425 ;;
427 {.mfi
428 nop.m 0
429 fclass.m p8, p0= f8, 0x7 // x= +/-Zero ?
430 nop.i 0
431 }
432 {.mfb
433 nop.m 0
434 (p6) mov f8= f0 // exp10(-Infinity)= 0
435 (p6) br.ret.spnt b0
436 }
437 ;;
439 {.mfb
440 nop.m 0
441 nop.f 0
442 (p7) br.ret.spnt b0 // exp10(+Infinity)= +Infinity
443 }
444 ;;
446 {.mfb
447 nop.m 0
448 (p8) mov f8= f1 // exp10(+/-0)= 1
449 (p8) br.ret.spnt b0
450 }
451 ;;
453 {.mfb
454 nop.m 0
455 fma.s.s0 f8= f8, f1, f0 // Remaining cases: NaNs
456 br.ret.sptk b0
457 }
458 ;;
461 OUT_RANGE_exp10:
463 // underflow: p6= 1
464 // overflow: p8= 1
466 .pred.rel "mutex",p6,p8
467 {.mmi
468 (p8) mov GR_EXPMAX= 0x1fffe
469 (p6) mov GR_EXPMAX= 1
470 nop.i 0
471 }
472 ;;
474 {.mii
475 setf.exp FR_R= GR_EXPMAX
476 (p8) mov GR_Parameter_TAG= 167
477 (p6) mov GR_Parameter_TAG= 266
478 }
479 ;;
481 {.mfb
482 nop.m 0
483 fma.s.s0 f8= FR_R, FR_R, f0 // Create overflow/underflow
484 br.cond.sptk __libm_error_region // Branch to error handling
485 }
486 ;;
488 GLOBAL_IEEE754_END(exp10f)
489 weak_alias (exp10f, pow10f)
492 LOCAL_LIBM_ENTRY(__libm_error_region)
494 .prologue
495 {.mfi
496 add GR_Parameter_Y= -32, sp // Parameter 2 value
497 nop.f 0
498 .save ar.pfs, GR_SAVE_PFS
499 mov GR_SAVE_PFS= ar.pfs // Save ar.pfs
500 }
502 {.mfi
503 .fframe 64
504 add sp= -64, sp // Create new stack
505 nop.f 0
506 mov GR_SAVE_GP= gp // Save gp
507 }
508 ;;
510 {.mmi
511 stfs [ GR_Parameter_Y ]= FR_Y, 16 // STORE Parameter 2 on stack
512 add GR_Parameter_X= 16, sp // Parameter 1 address
513 .save b0, GR_SAVE_B0
514 mov GR_SAVE_B0= b0 // Save b0
515 }
516 ;;
518 .body
519 {.mib
520 stfs [ GR_Parameter_X ]= FR_X // STORE Parameter 1 on stack
521 add GR_Parameter_RESULT= 0, GR_Parameter_Y // Parameter 3 address
522 nop.b 0
523 }
524 {.mib
525 stfs [ GR_Parameter_Y ]= FR_RESULT // STORE Parameter 3 on stack
526 add GR_Parameter_Y= -16, GR_Parameter_Y
527 br.call.sptk b0= __libm_error_support# // Call error handling function
528 }
529 ;;
531 {.mmi
532 add GR_Parameter_RESULT= 48, sp
533 nop.m 0
534 nop.i 0
535 }
536 ;;
538 {.mmi
539 ldfs f8= [ GR_Parameter_RESULT ] // Get return result off stack
540 .restore sp
541 add sp= 64, sp // Restore stack pointer
542 mov b0= GR_SAVE_B0 // Restore return address
543 }
544 ;;
546 {.mib
547 mov gp= GR_SAVE_GP // Restore gp
548 mov ar.pfs= GR_SAVE_PFS // Restore ar.pfs
549 br.ret.sptk b0 // Return
550 }
551 ;;
554 LOCAL_LIBM_END(__libm_error_region)
556 .type __libm_error_support#, @function
557 .global __libm_error_support#