| blob | eafa59dd7c769956195db31a66c25e9d0d06d5db |
1 .file "exp10.s"
4 // Copyright (c) 2000 - 2005, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
39 //
40 // History
41 //==============================================================
42 // 08/25/00 Initial version
43 // 05/20/02 Cleaned up namespace and sf0 syntax
44 // 09/06/02 Improved performance; no inexact flags on exact cases
45 // 01/29/03 Added missing } to bundle templates
46 // 12/16/04 Call error handling on underflow.
47 // 03/31/05 Reformatted delimiters between data tables
48 //
49 // API
50 //==============================================================
51 // double exp10(double)
52 //
53 // Overview of operation
54 //==============================================================
55 // Background
56 //
57 // Implementation
58 //
59 // Let x= (K + fh + fl + r)/log2(10), where
60 // K is an integer, fh= 0.b1 b2 b3 b4 b5,
61 // fl= 2^{-5}* 0.b6 b7 b8 b8 b10 (fh, fl >= 0),
62 // and |r|<2^{-11}
63 // Th is a table that stores 2^fh (32 entries) rounded to
64 // double extended precision (only mantissa is stored)
65 // Tl is a table that stores 2^fl (32 entries) rounded to
66 // double extended precision (only mantissa is stored)
67 //
68 // 10^x is approximated as
69 // 2^K * Th [ f ] * Tl [ f ] * (1+c1*e+c1*r+c2*r^2+c3*r^3+c4*r^4),
70 // where e= (x*log2(10)_hi-RN(x*log2(10)_hi))+log2(10)_lo*x
72 // Note there are only 22 non-zero values that produce an exact result:
73 // 1.0, 2.0, ... 22.0.
74 // We test for these cases and use s1 to avoid setting the inexact flag.
76 // Special values
77 //==============================================================
78 // exp10(0)= 1
79 // exp10(+inf)= inf
80 // exp10(-inf)= 0
81 //
83 // Registers used
84 //==============================================================
85 // r2-r3, r14-r40
86 // f6-f15, f32-f52
87 // p6-p12
88 //
91 GR_TBL_START = r2
92 GR_LOG_TBL = r3
94 GR_OF_LIMIT = r14
95 GR_UF_LIMIT = r15
96 GR_EXP_CORR = r16
97 GR_F_low = r17
98 GR_F_high = r18
99 GR_K = r19
100 GR_Flow_ADDR = r20
102 GR_BIAS = r21
103 GR_Fh = r22
104 GR_Fh_ADDR = r23
105 GR_EXPMAX = r24
106 GR_BIAS53 = r25
108 GR_ROUNDVAL = r26
109 GR_SNORM_LIMIT = r26
110 GR_MASK = r27
111 GR_KF0 = r28
112 GR_MASK_low = r29
113 GR_COEFF_START = r30
114 GR_exact_limit = r31
116 GR_SAVE_B0 = r33
117 GR_SAVE_PFS = r34
118 GR_SAVE_GP = r35
119 GR_SAVE_SP = r36
121 GR_Parameter_X = r37
122 GR_Parameter_Y = r38
123 GR_Parameter_RESULT = r39
124 GR_Parameter_TAG = r40
127 FR_X = f10
128 FR_Y = f1
129 FR_RESULT = f8
132 FR_COEFF1 = f6
133 FR_COEFF2 = f7
134 FR_R = f9
135 FR_LOG2_10 = f10
137 FR_2P53 = f11
138 FR_KF0 = f12
139 FR_COEFF3 = f13
140 FR_COEFF4 = f14
141 FR_UF_LIMIT = f15
143 FR_OF_LIMIT = f32
144 FR_DX_L210 = f33
145 FR_ROUNDVAL = f34
146 FR_KF = f35
148 FR_2_TO_K = f36
149 FR_T_low = f37
150 FR_T_high = f38
151 FR_P34 = f39
152 FR_R2 = f40
154 FR_P12 = f41
155 FR_T_low_K = f42
156 FR_P14 = f43
157 FR_T = f44
158 FR_P = f45
160 FR_L2_10_low = f46
161 FR_L2_10_high = f47
162 FR_E0 = f48
163 FR_E = f49
164 FR_exact_limit = f50
166 FR_int_x = f51
167 FR_SNORM_LIMIT = f52
170 // Data tables
171 //==============================================================
173 RODATA
175 .align 16
177 LOCAL_OBJECT_START(poly_coeffs)
179 data8 0xd49a784bcd1b8afe, 0x00003fcb // log2(10)*2^(10-63)
180 data8 0x9257edfe9b5fb698, 0x3fbf // log2(10)_low (bits 64...127)
181 data8 0x3fac6b08d704a0c0, 0x3f83b2ab6fba4e77 // C_3 and C_4
182 data8 0xb17217f7d1cf79ab, 0x00003ffe // C_1
183 data8 0xf5fdeffc162c7541, 0x00003ffc // C_2
184 LOCAL_OBJECT_END(poly_coeffs)
187 LOCAL_OBJECT_START(T_table)
189 // 2^{0.00000 b6 b7 b8 b9 b10}
190 data8 0x8000000000000000, 0x8016302f17467628
191 data8 0x802c6436d0e04f50, 0x80429c17d77c18ed
192 data8 0x8058d7d2d5e5f6b0, 0x806f17687707a7af
193 data8 0x80855ad965e88b83, 0x809ba2264dada76a
194 data8 0x80b1ed4fd999ab6c, 0x80c83c56b50cf77f
195 data8 0x80de8f3b8b85a0af, 0x80f4e5ff089f763e
196 data8 0x810b40a1d81406d4, 0x81219f24a5baa59d
197 data8 0x813801881d886f7b, 0x814e67cceb90502c
198 data8 0x8164d1f3bc030773, 0x817b3ffd3b2f2e47
199 data8 0x8191b1ea15813bfd, 0x81a827baf7838b78
200 data8 0x81bea1708dde6055, 0x81d51f0b8557ec1c
201 data8 0x81eba08c8ad4536f, 0x820225f44b55b33b
202 data8 0x8218af4373fc25eb, 0x822f3c7ab205c89a
203 data8 0x8245cd9ab2cec048, 0x825c62a423d13f0c
204 data8 0x8272fb97b2a5894c, 0x828998760d01faf3
205 data8 0x82a0393fe0bb0ca8, 0x82b6ddf5dbc35906
206 //
207 // 2^{0.b1 b2 b3 b4 b5}
208 data8 0x8000000000000000, 0x82cd8698ac2ba1d7
209 data8 0x85aac367cc487b14, 0x88980e8092da8527
210 data8 0x8b95c1e3ea8bd6e6, 0x8ea4398b45cd53c0
211 data8 0x91c3d373ab11c336, 0x94f4efa8fef70961
212 data8 0x9837f0518db8a96f, 0x9b8d39b9d54e5538
213 data8 0x9ef5326091a111ad, 0xa27043030c496818
214 data8 0xa5fed6a9b15138ea, 0xa9a15ab4ea7c0ef8
215 data8 0xad583eea42a14ac6, 0xb123f581d2ac258f
216 data8 0xb504f333f9de6484, 0xb8fbaf4762fb9ee9
217 data8 0xbd08a39f580c36be, 0xc12c4cca66709456
218 data8 0xc5672a115506dadd, 0xc9b9bd866e2f27a2
219 data8 0xce248c151f8480e3, 0xd2a81d91f12ae45a
220 data8 0xd744fccad69d6af4, 0xdbfbb797daf23755
221 data8 0xe0ccdeec2a94e111, 0xe5b906e77c8348a8
222 data8 0xeac0c6e7dd24392e, 0xefe4b99bdcdaf5cb
223 data8 0xf5257d152486cc2c, 0xfa83b2db722a033a
224 LOCAL_OBJECT_END(T_table)
228 .section .text
229 GLOBAL_IEEE754_ENTRY(exp10)
232 {.mfi
233 alloc r32= ar.pfs, 1, 4, 4, 0
234 // will continue only for non-zero normal/denormal numbers
235 fclass.nm.unc p12, p7= f8, 0x1b
236 mov GR_BIAS53= 0xffff+63-10
237 }
238 {.mlx
239 // GR_TBL_START= pointer to log2(10), C_1...C_4 followed by T_table
240 addl GR_TBL_START= @ltoff(poly_coeffs), gp
241 movl GR_ROUNDVAL= 0x3fc00000 // 1.5 (SP)
242 }
243 ;;
245 {.mfi
246 ld8 GR_COEFF_START= [ GR_TBL_START ] // Load pointer to coeff table
247 fcmp.lt.s1 p6, p8= f8, f0 // X<0 ?
248 nop.i 0
249 }
250 ;;
252 {.mlx
253 setf.exp FR_2P53= GR_BIAS53 // 2^{63-10}
254 movl GR_UF_LIMIT= 0xc07439b746e36b52 // (-2^10-51) / log2(10)
255 }
256 {.mlx
257 setf.s FR_ROUNDVAL= GR_ROUNDVAL
258 movl GR_OF_LIMIT= 0x40734413509f79fe // Overflow threshold
259 }
260 ;;
262 {.mlx
263 ldfe FR_LOG2_10= [ GR_COEFF_START ], 16 // load log2(10)*2^(10-63)
264 movl GR_SNORM_LIMIT= 0xc0733a7146f72a41 // Smallest normal threshold
265 }
266 {.mib
267 nop.m 0
268 nop.i 0
269 (p12) br.cond.spnt SPECIAL_exp10 // Branch if nan, inf, zero
270 }
271 ;;
273 {.mmf
274 ldfe FR_L2_10_low= [ GR_COEFF_START ], 16 // load log2(10)_low
275 setf.d FR_OF_LIMIT= GR_OF_LIMIT // Set overflow limit
276 fma.s0 f8= f8, f1, f0 // normalize x
277 }
278 ;;
280 {.mfi
281 ldfpd FR_COEFF3, FR_COEFF4= [ GR_COEFF_START ], 16 // load C_3, C_4
282 (p8) fcvt.fx.s1 FR_int_x = f8 // Convert x to integer
283 nop.i 0
284 }
285 {.mfi
286 setf.d FR_UF_LIMIT= GR_UF_LIMIT // Set underflow limit
287 fma.s1 FR_KF0= f8, FR_LOG2_10, FR_ROUNDVAL // y= (x*log2(10)*2^10 +
288 // 1.5*2^63) * 2^(-63)
289 mov GR_EXP_CORR= 0xffff-126
290 }
291 ;;
293 {.mfi
294 setf.d FR_SNORM_LIMIT= GR_SNORM_LIMIT // Set smallest normal limit
295 fma.s1 FR_L2_10_high= FR_LOG2_10, FR_2P53, f0 // FR_LOG2_10= log2(10)_hi
296 nop.i 0
297 }
298 ;;
300 {.mfi
301 ldfe FR_COEFF1= [ GR_COEFF_START ], 16 // load C_1
302 fms.s1 FR_KF= FR_KF0, f1, FR_ROUNDVAL // (K+f)*2^(10-63)
303 mov GR_MASK= 1023
304 }
305 ;;
307 {.mfi
308 ldfe FR_COEFF2= [ GR_COEFF_START ], 16 // load C_2
309 fma.s1 FR_LOG2_10= f8, FR_L2_10_high, f0 // y0= x*log2(10)_hi
310 mov GR_MASK_low= 31
311 }
312 ;;
314 {.mlx
315 getf.sig GR_KF0= FR_KF0 // (K+f)*2^10= round_to_int(y)
316 (p8) movl GR_exact_limit= 0x41b00000 // Largest x for exact result,
317 // +22.0
318 }
319 ;;
321 {.mfi
322 add GR_LOG_TBL= 256, GR_COEFF_START // Pointer to high T_table
323 fcmp.gt.s1 p12, p7= f8, FR_OF_LIMIT // x>overflow threshold ?
324 nop.i 0
325 }
326 ;;
328 {.mfi
329 (p8) setf.s FR_exact_limit = GR_exact_limit // Largest x for exact result
330 (p8) fcvt.xf FR_int_x = FR_int_x // Integral part of x
331 shr GR_K= GR_KF0, 10 // K
332 }
333 {.mfi
334 and GR_F_high= GR_MASK, GR_KF0 // f_high*32
335 fnma.s1 FR_R= FR_KF, FR_2P53, FR_LOG2_10 // r= x*log2(10)-2^{63-10}*
336 // [ (K+f)*2^{10-63} ]
337 and GR_F_low= GR_KF0, GR_MASK_low // f_low
338 }
339 ;;
341 {.mmi
342 shladd GR_Flow_ADDR= GR_F_low, 3, GR_COEFF_START // address of 2^{f_low}
343 add GR_BIAS= GR_K, GR_EXP_CORR // K= bias-2*63
344 shr GR_Fh= GR_F_high, 5 // f_high
345 }
346 ;;
348 {.mfi
349 setf.exp FR_2_TO_K= GR_BIAS // 2^{K-126}
350 (p7) fcmp.lt.s1 p12, p7= f8, FR_UF_LIMIT // x<underflow threshold ?
351 shladd GR_Fh_ADDR= GR_Fh, 3, GR_LOG_TBL // address of 2^{f_high}
352 }
353 {.mfi
354 ldf8 FR_T_low= [ GR_Flow_ADDR ] // load T_low= 2^{f_low}
355 fms.s1 FR_DX_L210= f8, FR_L2_10_high, FR_LOG2_10 // x*log2(10)_hi-
356 // RN(x*log2(10)_hi)
357 nop.i 0
358 }
359 ;;
361 {.mfi
362 ldf8 FR_T_high= [ GR_Fh_ADDR ] // load T_high= 2^{f_high}
363 fma.s1 FR_P34= FR_COEFF4, FR_R, FR_COEFF3 // P34= C_3+C_4*r
364 nop.i 0
365 }
366 {.mfb
367 nop.m 0
368 fma.s1 FR_R2= FR_R, FR_R, f0 // r*r
369 (p12) br.cond.spnt OUT_RANGE_exp10
370 }
371 ;;
373 {.mfi
374 nop.m 0
375 // e= (x*log2(10)_hi-RN(x*log2(10)_hi))+log2(10)_lo*x
376 fma.s1 FR_E0= f8, FR_L2_10_low, FR_DX_L210
377 cmp.eq p7,p9= r0,r0 // Assume inexact result
378 }
379 {.mfi
380 nop.m 0
381 fma.s1 FR_P12= FR_COEFF2, FR_R, FR_COEFF1 // P12= C_1+C_2*r
382 nop.i 0
383 }
384 ;;
386 {.mfi
387 nop.m 0
388 (p8) fcmp.eq.s1 p9,p7= FR_int_x, f8 // Test x positive integer
389 nop.i 0
390 }
391 {.mfi
392 nop.m 0
393 fma.s1 FR_T_low_K= FR_T_low, FR_2_TO_K, f0 // T= 2^{K-126}*T_low
394 nop.i 0
395 }
396 ;;
398 {.mfi
399 nop.m 0
400 fcmp.ge.s1 p11,p0= f8, FR_SNORM_LIMIT // Test x for normal range
401 nop.i 0
402 }
403 ;;
405 {.mfi
406 nop.m 0
407 fma.s1 FR_E= FR_E0, FR_COEFF1, f0 // E= C_1*e
408 nop.i 0
409 }
410 {.mfi
411 nop.m 0
412 fma.s1 FR_P14= FR_R2, FR_P34, FR_P12 // P14= P12+r2*P34
413 nop.i 0
414 }
415 ;;
417 // If x a positive integer, will it produce an exact result?
418 // p7 result will be inexact
419 // p9 result will be exact
420 {.mfi
421 nop.m 0
422 (p9) fcmp.le.s1 p9,p7= f8, FR_exact_limit // Test x gives exact result
423 nop.i 0
424 }
425 {.mfi
426 nop.m 0
427 fma.s1 FR_T= FR_T_low_K, FR_T_high, f0 // T= T*T_high
428 nop.i 0
429 }
430 ;;
432 {.mfi
433 nop.m 0
434 fma.s1 FR_P= FR_P14, FR_R, FR_E // P= P14*r+E
435 nop.i 0
436 }
437 ;;
439 .pred.rel "mutex",p7,p9
440 {.mfi
441 nop.m 0
442 (p7) fma.d.s0 f8= FR_P, FR_T, FR_T // result= T+T*P, inexact set
443 nop.i 0
444 }
445 {.mfb
446 nop.m 0
447 (p9) fma.d.s1 f8= FR_P, FR_T, FR_T // result= T+T*P, exact use s1
448 (p11) br.ret.sptk b0 // return, if result normal
449 }
450 ;;
452 // Here if result in denormal range (and not zero)
453 {.mib
454 nop.m 0
455 mov GR_Parameter_TAG= 265
456 br.cond.sptk __libm_error_region // Branch to error handling
457 }
458 ;;
460 SPECIAL_exp10:
461 {.mfi
462 nop.m 0
463 fclass.m p6, p0= f8, 0x22 // x= -Infinity ?
464 nop.i 0
465 }
466 ;;
468 {.mfi
469 nop.m 0
470 fclass.m p7, p0= f8, 0x21 // x= +Infinity ?
471 nop.i 0
472 }
473 ;;
475 {.mfi
476 nop.m 0
477 fclass.m p8, p0= f8, 0x7 // x= +/-Zero ?
478 nop.i 0
479 }
480 {.mfb
481 nop.m 0
482 (p6) mov f8= f0 // exp10(-Infinity)= 0
483 (p6) br.ret.spnt b0
484 }
485 ;;
487 {.mfb
488 nop.m 0
489 nop.f 0
490 (p7) br.ret.spnt b0 // exp10(+Infinity)= +Infinity
491 }
492 ;;
494 {.mfb
495 nop.m 0
496 (p8) mov f8= f1 // exp10(+/-0)= 1
497 (p8) br.ret.spnt b0
498 }
499 ;;
501 {.mfb
502 nop.m 0
503 fma.d.s0 f8= f8, f1, f0 // Remaining cases: NaNs
504 br.ret.sptk b0
505 }
506 ;;
509 OUT_RANGE_exp10:
511 // underflow: p6= 1
512 // overflow: p8= 1
514 .pred.rel "mutex",p6,p8
515 {.mmi
516 (p8) mov GR_EXPMAX= 0x1fffe
517 (p6) mov GR_EXPMAX= 1
518 nop.i 0
519 }
520 ;;
522 {.mii
523 setf.exp FR_R= GR_EXPMAX
524 (p8) mov GR_Parameter_TAG= 166
525 (p6) mov GR_Parameter_TAG= 265
526 }
527 ;;
529 {.mfb
530 nop.m 0
531 fma.d.s0 f8= FR_R, FR_R, f0 // Create overflow/underflow
532 br.cond.sptk __libm_error_region // Branch to error handling
533 }
534 ;;
536 GLOBAL_IEEE754_END(exp10)
537 weak_alias (exp10, pow10)
540 LOCAL_LIBM_ENTRY(__libm_error_region)
542 .prologue
543 {.mfi
544 add GR_Parameter_Y= -32, sp // Parameter 2 value
545 nop.f 0
546 .save ar.pfs, GR_SAVE_PFS
547 mov GR_SAVE_PFS= ar.pfs // Save ar.pfs
548 }
550 {.mfi
551 .fframe 64
552 add sp= -64, sp // Create new stack
553 nop.f 0
554 mov GR_SAVE_GP= gp // Save gp
555 }
556 ;;
558 {.mmi
559 stfd [ GR_Parameter_Y ]= FR_Y, 16 // STORE Parameter 2 on stack
560 add GR_Parameter_X= 16, sp // Parameter 1 address
561 .save b0, GR_SAVE_B0
562 mov GR_SAVE_B0= b0 // Save b0
563 }
564 ;;
566 .body
567 {.mib
568 stfd [ GR_Parameter_X ]= FR_X // STORE Parameter 1 on stack
569 add GR_Parameter_RESULT= 0, GR_Parameter_Y // Parameter 3 address
570 nop.b 0
571 }
572 {.mib
573 stfd [ GR_Parameter_Y ]= FR_RESULT // STORE Parameter 3 on stack
574 add GR_Parameter_Y= -16, GR_Parameter_Y
575 br.call.sptk b0= __libm_error_support# // Call error handling function
576 }
577 ;;
579 {.mmi
580 add GR_Parameter_RESULT= 48, sp
581 nop.m 0
582 nop.i 0
583 }
584 ;;
586 {.mmi
587 ldfd f8= [ GR_Parameter_RESULT ] // Get return result off stack
588 .restore sp
589 add sp= 64, sp // Restore stack pointer
590 mov b0= GR_SAVE_B0 // Restore return address
591 }
592 ;;
594 {.mib
595 mov gp= GR_SAVE_GP // Restore gp
596 mov ar.pfs= GR_SAVE_PFS // Restore ar.pfs
597 br.ret.sptk b0 // Return
598 }
599 ;;
602 LOCAL_LIBM_END(__libm_error_region)
604 .type __libm_error_support#, @function
605 .global __libm_error_support#