| blob | 97cb4e1771ea655cbbe999cb36b749da33a9533e |
1 .file "coshf.s"
4 // Copyright (c) 2000 - 2005, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
40 // History
41 //*********************************************************************
42 // 02/02/00 Initial version
43 // 02/16/00 The error tag for coshf overflow changed to 65 (from 64).
44 // 04/04/00 Unwind support added
45 // 08/15/00 Bundle added after call to __libm_error_support to properly
46 // set [the previously overwritten] GR_Parameter_RESULT.
47 // 05/07/01 Reworked to improve speed of all paths
48 // 05/20/02 Cleaned up namespace and sf0 syntax
49 // 11/15/02 Improved algorithm based on expf
50 // 03/31/05 Reformatted delimiters between data tables
51 //
52 // API
53 //*********************************************************************
54 // float coshf(float)
55 //
56 // Overview of operation
57 //*********************************************************************
58 // Case 1: 0 < |x| < 0.25
59 // Evaluate cosh(x) by a 8th order polynomial
60 // Care is take for the order of multiplication; and A2 is not exactly 1/4!,
61 // A3 is not exactly 1/6!, etc.
62 // cosh(x) = 1 + (A1*x^2 + A2*x^4 + A3*x^6 + A4*x^8)
63 //
64 // Case 2: 0.25 < |x| < 89.41598
65 // Algorithm is based on the identity cosh(x) = ( exp(x) + exp(-x) ) / 2.
66 // The algorithm for exp is described as below. There are a number of
67 // economies from evaluating both exp(x) and exp(-x). Although we
68 // are evaluating both quantities, only where the quantities diverge do we
69 // duplicate the computations. The basic algorithm for exp(x) is described
70 // below.
71 //
72 // Take the input x. w is "how many log2/128 in x?"
73 // w = x * 64/log2
74 // NJ = int(w)
75 // x = NJ*log2/64 + R
77 // NJ = 64*n + j
78 // x = n*log2 + (log2/64)*j + R
79 //
80 // So, exp(x) = 2^n * 2^(j/64)* exp(R)
81 //
82 // T = 2^n * 2^(j/64)
83 // Construct 2^n
84 // Get 2^(j/64) table
85 // actually all the entries of 2^(j/64) table are stored in DP and
86 // with exponent bits set to 0 -> multiplication on 2^n can be
87 // performed by doing logical "or" operation with bits presenting 2^n
89 // exp(R) = 1 + (exp(R) - 1)
90 // P = exp(R) - 1 approximated by Taylor series of 3rd degree
91 // P = A3*R^3 + A2*R^2 + R, A3 = 1/6, A2 = 1/2
92 //
94 // The final result is reconstructed as follows
95 // exp(x) = T + T*P
97 // Special values
98 //*********************************************************************
99 // coshf(+0) = 1.0
100 // coshf(-0) = 1.0
102 // coshf(+qnan) = +qnan
103 // coshf(-qnan) = -qnan
104 // coshf(+snan) = +qnan
105 // coshf(-snan) = -qnan
107 // coshf(-inf) = +inf
108 // coshf(+inf) = +inf
110 // Overflow and Underflow
111 //*********************************************************************
112 // coshf(x) = largest single normal when
113 // x = 89.41598 = 0x42b2d4fc
114 //
115 // There is no underflow.
117 // Registers used
118 //*********************************************************************
119 // Floating Point registers used:
120 // f8 input, output
121 // f6,f7, f9 -> f15, f32 -> f45
123 // General registers used:
124 // r2, r3, r16 -> r38
126 // Predicate registers used:
127 // p6 -> p15
129 // Assembly macros
130 //*********************************************************************
131 // integer registers used
132 // scratch
133 rNJ = r2
134 rNJ_neg = r3
136 rJ_neg = r16
137 rN_neg = r17
138 rSignexp_x = r18
139 rExp_x = r18
140 rExp_mask = r19
141 rExp_bias = r20
142 rAd1 = r21
143 rAd2 = r22
144 rJ = r23
145 rN = r24
146 rTblAddr = r25
147 rA3 = r26
148 rExpHalf = r27
149 rLn2Div64 = r28
150 rGt_ln = r29
151 r17ones_m1 = r29
152 rRightShifter = r30
153 rJ_mask = r30
154 r64DivLn2 = r31
155 rN_mask = r31
156 // stacked
157 GR_SAVE_PFS = r32
158 GR_SAVE_B0 = r33
159 GR_SAVE_GP = r34
160 GR_Parameter_X = r35
161 GR_Parameter_Y = r36
162 GR_Parameter_RESULT = r37
163 GR_Parameter_TAG = r38
165 // floating point registers used
166 FR_X = f10
167 FR_Y = f1
168 FR_RESULT = f8
169 // scratch
170 fRightShifter = f6
171 f64DivLn2 = f7
172 fNormX = f9
173 fNint = f10
174 fN = f11
175 fR = f12
176 fLn2Div64 = f13
177 fA2 = f14
178 fA3 = f15
179 // stacked
180 fP = f32
181 fT = f33
182 fMIN_SGL_OFLOW_ARG = f34
183 fMAX_SGL_NORM_ARG = f35
184 fRSqr = f36
185 fA1 = f37
186 fA21 = f37
187 fA4 = f38
188 fA43 = f38
189 fA4321 = f38
190 fX4 = f39
191 fTmp = f39
192 fGt_pln = f39
193 fWre_urm_f8 = f40
194 fXsq = f40
195 fP_neg = f41
196 fT_neg = f42
197 fExp = f43
198 fExp_neg = f44
199 fAbsX = f45
202 RODATA
203 .align 16
205 LOCAL_OBJECT_START(_coshf_table)
206 data4 0x42b2d4fd // Smallest single arg to overflow single result
207 data4 0x42b2d4fc // Largest single arg to give normal single result
208 data4 0x00000000 // pad
209 data4 0x00000000 // pad
210 //
211 // 2^(j/64) table, j goes from 0 to 63
212 data8 0x0000000000000000 // 2^(0/64)
213 data8 0x00002C9A3E778061 // 2^(1/64)
214 data8 0x000059B0D3158574 // 2^(2/64)
215 data8 0x0000874518759BC8 // 2^(3/64)
216 data8 0x0000B5586CF9890F // 2^(4/64)
217 data8 0x0000E3EC32D3D1A2 // 2^(5/64)
218 data8 0x00011301D0125B51 // 2^(6/64)
219 data8 0x0001429AAEA92DE0 // 2^(7/64)
220 data8 0x000172B83C7D517B // 2^(8/64)
221 data8 0x0001A35BEB6FCB75 // 2^(9/64)
222 data8 0x0001D4873168B9AA // 2^(10/64)
223 data8 0x0002063B88628CD6 // 2^(11/64)
224 data8 0x0002387A6E756238 // 2^(12/64)
225 data8 0x00026B4565E27CDD // 2^(13/64)
226 data8 0x00029E9DF51FDEE1 // 2^(14/64)
227 data8 0x0002D285A6E4030B // 2^(15/64)
228 data8 0x000306FE0A31B715 // 2^(16/64)
229 data8 0x00033C08B26416FF // 2^(17/64)
230 data8 0x000371A7373AA9CB // 2^(18/64)
231 data8 0x0003A7DB34E59FF7 // 2^(19/64)
232 data8 0x0003DEA64C123422 // 2^(20/64)
233 data8 0x0004160A21F72E2A // 2^(21/64)
234 data8 0x00044E086061892D // 2^(22/64)
235 data8 0x000486A2B5C13CD0 // 2^(23/64)
236 data8 0x0004BFDAD5362A27 // 2^(24/64)
237 data8 0x0004F9B2769D2CA7 // 2^(25/64)
238 data8 0x0005342B569D4F82 // 2^(26/64)
239 data8 0x00056F4736B527DA // 2^(27/64)
240 data8 0x0005AB07DD485429 // 2^(28/64)
241 data8 0x0005E76F15AD2148 // 2^(29/64)
242 data8 0x0006247EB03A5585 // 2^(30/64)
243 data8 0x0006623882552225 // 2^(31/64)
244 data8 0x0006A09E667F3BCD // 2^(32/64)
245 data8 0x0006DFB23C651A2F // 2^(33/64)
246 data8 0x00071F75E8EC5F74 // 2^(34/64)
247 data8 0x00075FEB564267C9 // 2^(35/64)
248 data8 0x0007A11473EB0187 // 2^(36/64)
249 data8 0x0007E2F336CF4E62 // 2^(37/64)
250 data8 0x00082589994CCE13 // 2^(38/64)
251 data8 0x000868D99B4492ED // 2^(39/64)
252 data8 0x0008ACE5422AA0DB // 2^(40/64)
253 data8 0x0008F1AE99157736 // 2^(41/64)
254 data8 0x00093737B0CDC5E5 // 2^(42/64)
255 data8 0x00097D829FDE4E50 // 2^(43/64)
256 data8 0x0009C49182A3F090 // 2^(44/64)
257 data8 0x000A0C667B5DE565 // 2^(45/64)
258 data8 0x000A5503B23E255D // 2^(46/64)
259 data8 0x000A9E6B5579FDBF // 2^(47/64)
260 data8 0x000AE89F995AD3AD // 2^(48/64)
261 data8 0x000B33A2B84F15FB // 2^(49/64)
262 data8 0x000B7F76F2FB5E47 // 2^(50/64)
263 data8 0x000BCC1E904BC1D2 // 2^(51/64)
264 data8 0x000C199BDD85529C // 2^(52/64)
265 data8 0x000C67F12E57D14B // 2^(53/64)
266 data8 0x000CB720DCEF9069 // 2^(54/64)
267 data8 0x000D072D4A07897C // 2^(55/64)
268 data8 0x000D5818DCFBA487 // 2^(56/64)
269 data8 0x000DA9E603DB3285 // 2^(57/64)
270 data8 0x000DFC97337B9B5F // 2^(58/64)
271 data8 0x000E502EE78B3FF6 // 2^(59/64)
272 data8 0x000EA4AFA2A490DA // 2^(60/64)
273 data8 0x000EFA1BEE615A27 // 2^(61/64)
274 data8 0x000F50765B6E4540 // 2^(62/64)
275 data8 0x000FA7C1819E90D8 // 2^(63/64)
276 LOCAL_OBJECT_END(_coshf_table)
278 LOCAL_OBJECT_START(cosh_p_table)
279 data8 0x3efa3001dcf5905b // A4
280 data8 0x3f56c1437543543e // A3
281 data8 0x3fa5555572601504 // A2
282 data8 0x3fdfffffffe2f097 // A1
283 LOCAL_OBJECT_END(cosh_p_table)
286 .section .text
287 GLOBAL_IEEE754_ENTRY(coshf)
289 { .mlx
290 getf.exp rSignexp_x = f8 // Must recompute if x unorm
291 movl r64DivLn2 = 0x40571547652B82FE // 64/ln(2)
292 }
293 { .mlx
294 addl rTblAddr = @ltoff(_coshf_table),gp
295 movl rRightShifter = 0x43E8000000000000 // DP Right Shifter
296 }
297 ;;
299 { .mfi
300 // point to the beginning of the table
301 ld8 rTblAddr = [rTblAddr]
302 fclass.m p6, p0 = f8, 0x0b // Test for x=unorm
303 addl rA3 = 0x3E2AA, r0 // high bits of 1.0/6.0 rounded to SP
304 }
305 { .mfi
306 nop.m 0
307 fnorm.s1 fNormX = f8 // normalized x
308 addl rExpHalf = 0xFFFE, r0 // exponent of 1/2
309 }
310 ;;
312 { .mfi
313 setf.d f64DivLn2 = r64DivLn2 // load 64/ln(2) to FP reg
314 fclass.m p15, p0 = f8, 0x1e3 // test for NaT,NaN,Inf
315 nop.i 0
316 }
317 { .mlx
318 // load Right Shifter to FP reg
319 setf.d fRightShifter = rRightShifter
320 movl rLn2Div64 = 0x3F862E42FEFA39EF // DP ln(2)/64 in GR
321 }
322 ;;
324 { .mfi
325 mov rExp_mask = 0x1ffff
326 fcmp.eq.s1 p13, p0 = f0, f8 // test for x = 0.0
327 shl rA3 = rA3, 12 // 0x3E2AA000, approx to 1.0/6.0 in SP
328 }
329 { .mfb
330 nop.m 0
331 nop.f 0
332 (p6) br.cond.spnt COSH_UNORM // Branch if x=unorm
333 }
334 ;;
336 COSH_COMMON:
337 { .mfi
338 setf.exp fA2 = rExpHalf // load A2 to FP reg
339 nop.f 0
340 mov rExp_bias = 0xffff
341 }
342 { .mfb
343 setf.d fLn2Div64 = rLn2Div64 // load ln(2)/64 to FP reg
344 (p15) fma.s.s0 f8 = f8, f8, f0 // result if x = NaT,NaN,Inf
345 (p15) br.ret.spnt b0 // exit here if x = NaT,NaN,Inf
346 }
347 ;;
349 { .mfi
350 // min overflow and max normal threshold
351 ldfps fMIN_SGL_OFLOW_ARG, fMAX_SGL_NORM_ARG = [rTblAddr], 8
352 nop.f 0
353 and rExp_x = rExp_mask, rSignexp_x // Biased exponent of x
354 }
355 { .mfb
356 setf.s fA3 = rA3 // load A3 to FP reg
357 (p13) fma.s.s0 f8 = f1, f1, f0 // result if x = 0.0
358 (p13) br.ret.spnt b0 // exit here if x =0.0
359 }
360 ;;
362 { .mfi
363 sub rExp_x = rExp_x, rExp_bias // True exponent of x
364 fmerge.s fAbsX = f0, fNormX // Form |x|
365 nop.i 0
366 }
367 ;;
369 { .mfi
370 nop.m 0
371 // x*(64/ln(2)) + Right Shifter
372 fma.s1 fNint = fNormX, f64DivLn2, fRightShifter
373 add rTblAddr = 8, rTblAddr
374 }
375 { .mfb
376 cmp.gt p7, p0 = -2, rExp_x // Test |x| < 2^(-2)
377 fma.s1 fXsq = fNormX, fNormX, f0 // x*x for small path
378 (p7) br.cond.spnt COSH_SMALL // Branch if 0 < |x| < 2^-2
379 }
380 ;;
382 { .mfi
383 nop.m 0
384 // check for overflow
385 fcmp.ge.s1 p12, p13 = fAbsX, fMIN_SGL_OFLOW_ARG
386 mov rJ_mask = 0x3f // 6-bit mask for J
387 }
388 ;;
390 { .mfb
391 nop.m 0
392 fms.s1 fN = fNint, f1, fRightShifter // n in FP register
393 // branch out if overflow
394 (p12) br.cond.spnt COSH_CERTAIN_OVERFLOW
395 }
396 ;;
398 { .mfi
399 getf.sig rNJ = fNint // bits of n, j
400 // check for possible overflow
401 fcmp.gt.s1 p13, p0 = fAbsX, fMAX_SGL_NORM_ARG
402 nop.i 0
403 }
404 ;;
406 { .mfi
407 addl rN = 0xFFBF - 63, rNJ // biased and shifted n-1,j
408 fnma.s1 fR = fLn2Div64, fN, fNormX // R = x - N*ln(2)/64
409 and rJ = rJ_mask, rNJ // bits of j
410 }
411 { .mfi
412 sub rNJ_neg = r0, rNJ // bits of n, j for -x
413 nop.f 0
414 andcm rN_mask = -1, rJ_mask // 0xff...fc0 to mask N
415 }
416 ;;
418 { .mfi
419 shladd rJ = rJ, 3, rTblAddr // address in the 2^(j/64) table
420 nop.f 0
421 and rN = rN_mask, rN // biased, shifted n-1
422 }
423 { .mfi
424 addl rN_neg = 0xFFBF - 63, rNJ_neg // -x biased, shifted n-1,j
425 nop.f 0
426 and rJ_neg = rJ_mask, rNJ_neg // bits of j for -x
427 }
428 ;;
430 { .mfi
431 ld8 rJ = [rJ] // Table value
432 nop.f 0
433 shl rN = rN, 46 // 2^(n-1) bits in DP format
434 }
435 { .mfi
436 shladd rJ_neg = rJ_neg, 3, rTblAddr // addr in 2^(j/64) table -x
437 nop.f 0
438 and rN_neg = rN_mask, rN_neg // biased, shifted n-1 for -x
439 }
440 ;;
442 { .mfi
443 ld8 rJ_neg = [rJ_neg] // Table value for -x
444 nop.f 0
445 shl rN_neg = rN_neg, 46 // 2^(n-1) bits in DP format for -x
446 }
447 ;;
449 { .mfi
450 or rN = rN, rJ // bits of 2^n * 2^(j/64) in DP format
451 nop.f 0
452 nop.i 0
453 }
454 ;;
456 { .mmf
457 setf.d fT = rN // 2^(n-1) * 2^(j/64)
458 or rN_neg = rN_neg, rJ_neg // -x bits of 2^n * 2^(j/64) in DP
459 fma.s1 fRSqr = fR, fR, f0 // R^2
460 }
461 ;;
463 { .mfi
464 setf.d fT_neg = rN_neg // 2^(n-1) * 2^(j/64) for -x
465 fma.s1 fP = fA3, fR, fA2 // A3*R + A2
466 nop.i 0
467 }
468 { .mfi
469 nop.m 0
470 fnma.s1 fP_neg = fA3, fR, fA2 // A3*R + A2 for -x
471 nop.i 0
472 }
473 ;;
475 { .mfi
476 nop.m 0
477 fma.s1 fP = fP, fRSqr, fR // P = (A3*R + A2)*R^2 + R
478 nop.i 0
479 }
480 { .mfi
481 nop.m 0
482 fms.s1 fP_neg = fP_neg, fRSqr, fR // P = (A3*R + A2)*R^2 + R, -x
483 nop.i 0
484 }
485 ;;
487 { .mfi
488 nop.m 0
489 fmpy.s0 fTmp = fLn2Div64, fLn2Div64 // Force inexact
490 nop.i 0
491 }
492 ;;
494 { .mfi
495 nop.m 0
496 fma.s1 fExp = fP, fT, fT // exp(x)/2
497 nop.i 0
498 }
499 { .mfb
500 nop.m 0
501 fma.s1 fExp_neg = fP_neg, fT_neg, fT_neg // exp(-x)/2
502 // branch out if possible overflow result
503 (p13) br.cond.spnt COSH_POSSIBLE_OVERFLOW
504 }
505 ;;
507 { .mfb
508 nop.m 0
509 // final result in the absence of overflow
510 fma.s.s0 f8 = fExp, f1, fExp_neg // result = (exp(x)+exp(-x))/2
511 // exit here in the absence of overflow
512 br.ret.sptk b0 // Exit main path, 0.25 <= |x| < 89.41598
513 }
514 ;;
516 // Here if 0 < |x| < 0.25. Evaluate 8th order polynomial.
517 COSH_SMALL:
518 { .mmi
519 add rAd1 = 0x200, rTblAddr
520 add rAd2 = 0x210, rTblAddr
521 nop.i 0
522 }
523 ;;
525 { .mmi
526 ldfpd fA4, fA3 = [rAd1]
527 ldfpd fA2, fA1 = [rAd2]
528 nop.i 0
529 }
530 ;;
532 { .mfi
533 nop.m 0
534 fma.s1 fX4 = fXsq, fXsq, f0
535 nop.i 0
536 }
537 ;;
539 { .mfi
540 nop.m 0
541 fma.s1 fA43 = fXsq, fA4, fA3
542 nop.i 0
543 }
544 { .mfi
545 nop.m 0
546 fma.s1 fA21 = fXsq, fA2, fA1
547 nop.i 0
548 }
549 ;;
551 { .mfi
552 nop.m 0
553 fma.s1 fA4321 = fX4, fA43, fA21
554 nop.i 0
555 }
556 ;;
558 // Dummy multiply to generate inexact
559 { .mfi
560 nop.m 0
561 fmpy.s0 fTmp = fA4, fA4
562 nop.i 0
563 }
564 { .mfb
565 nop.m 0
566 fma.s.s0 f8 = fA4321, fXsq, f1
567 br.ret.sptk b0 // Exit if 0 < |x| < 0.25
568 }
569 ;;
571 COSH_POSSIBLE_OVERFLOW:
573 // Here if fMAX_SGL_NORM_ARG < x < fMIN_SGL_OFLOW_ARG
574 // This cannot happen if input is a single, only if input higher precision.
575 // Overflow is a possibility, not a certainty.
577 // Recompute result using status field 2 with user's rounding mode,
578 // and wre set. If result is larger than largest single, then we have
579 // overflow
581 { .mfi
582 mov rGt_ln = 0x1007f // Exponent for largest single + 1 ulp
583 fsetc.s2 0x7F,0x42 // Get user's round mode, set wre
584 nop.i 0
585 }
586 ;;
588 { .mfi
589 setf.exp fGt_pln = rGt_ln // Create largest single + 1 ulp
590 fma.s.s2 fWre_urm_f8 = fP, fT, fT // Result with wre set
591 nop.i 0
592 }
593 ;;
595 { .mfi
596 nop.m 0
597 fsetc.s2 0x7F,0x40 // Turn off wre in sf2
598 nop.i 0
599 }
600 ;;
602 { .mfi
603 nop.m 0
604 fcmp.ge.s1 p6, p0 = fWre_urm_f8, fGt_pln // Test for overflow
605 nop.i 0
606 }
607 ;;
609 { .mfb
610 nop.m 0
611 nop.f 0
612 (p6) br.cond.spnt COSH_CERTAIN_OVERFLOW // Branch if overflow
613 }
614 ;;
616 { .mfb
617 nop.m 0
618 fma.s.s0 f8 = fP, fT, fT
619 br.ret.sptk b0 // Exit if really no overflow
620 }
621 ;;
623 // here if overflow
624 COSH_CERTAIN_OVERFLOW:
625 { .mmi
626 addl r17ones_m1 = 0x1FFFE, r0
627 ;;
628 setf.exp fTmp = r17ones_m1
629 nop.i 0
630 }
631 ;;
633 { .mfi
634 alloc r32 = ar.pfs, 0, 3, 4, 0 // get some registers
635 fmerge.s FR_X = f8,f8
636 nop.i 0
637 }
638 { .mfb
639 mov GR_Parameter_TAG = 65
640 fma.s.s0 FR_RESULT = fTmp, fTmp, f0 // Set I,O and +INF result
641 br.cond.sptk __libm_error_region
642 }
643 ;;
645 // Here if x unorm
646 COSH_UNORM:
647 { .mfb
648 getf.exp rSignexp_x = fNormX // Must recompute if x unorm
649 fcmp.eq.s0 p6, p0 = f8, f0 // Set D flag
650 br.cond.sptk COSH_COMMON // Return to main path
651 }
652 ;;
654 GLOBAL_IEEE754_END(coshf)
657 LOCAL_LIBM_ENTRY(__libm_error_region)
658 .prologue
659 { .mfi
660 add GR_Parameter_Y=-32,sp // Parameter 2 value
661 nop.f 0
662 .save ar.pfs,GR_SAVE_PFS
663 mov GR_SAVE_PFS=ar.pfs // Save ar.pfs
664 }
665 { .mfi
666 .fframe 64
667 add sp=-64,sp // Create new stack
668 nop.f 0
669 mov GR_SAVE_GP=gp // Save gp
670 };;
671 { .mmi
672 stfs [GR_Parameter_Y] = FR_Y,16 // Store Parameter 2 on stack
673 add GR_Parameter_X = 16,sp // Parameter 1 address
674 .save b0, GR_SAVE_B0
675 mov GR_SAVE_B0=b0 // Save b0
676 };;
677 .body
678 { .mfi
679 stfs [GR_Parameter_X] = FR_X // Store Parameter 1 on stack
680 nop.f 0
681 add GR_Parameter_RESULT = 0,GR_Parameter_Y // Parameter 3 address
682 }
683 { .mib
684 stfs [GR_Parameter_Y] = FR_RESULT // Store Parameter 3 on stack
685 add GR_Parameter_Y = -16,GR_Parameter_Y
686 br.call.sptk b0=__libm_error_support# // Call error handling function
687 };;
689 { .mmi
690 add GR_Parameter_RESULT = 48,sp
691 nop.m 0
692 nop.i 0
693 };;
695 { .mmi
696 ldfs f8 = [GR_Parameter_RESULT] // Get return result off stack
697 .restore sp
698 add sp = 64,sp // Restore stack pointer
699 mov b0 = GR_SAVE_B0 // Restore return address
700 };;
701 { .mib
702 mov gp = GR_SAVE_GP // Restore gp
703 mov ar.pfs = GR_SAVE_PFS // Restore ar.pfs
704 br.ret.sptk b0 // Return
705 };;
707 LOCAL_LIBM_END(__libm_error_region)
710 .type __libm_error_support#,@function
711 .global __libm_error_support#