| blob | 68b0b2ee8df23759cfa76dcf3fa0bd07f63d5735 |
1 .file "acosf.s"
4 // Copyright (c) 2000 - 2003, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
40 // History
41 //==============================================================
42 // 02/02/00 Initial version
43 // 06/28/00 Improved speed
44 // 06/31/00 Changed register allocation because of some duplicate macros
45 // moved nan exit bundle up to gain a cycle.
46 // 08/15/00 Bundle added after call to __libm_error_support to properly
47 // set [the previously overwritten] GR_Parameter_RESULT.
48 // 08/17/00 Changed predicate register macro-usage to direct predicate
49 // names due to an assembler bug.
50 // 10/17/00 Improved speed of x=0 and x=1 paths, set D flag if x denormal.
51 // 03/13/01 Corrected sign of imm1 value in dep instruction.
52 // 05/20/02 Cleaned up namespace and sf0 syntax
53 // 02/06/03 Reordered header: .section, .global, .proc, .align
54 // 04/17/03 Moved mutex after label
57 // Description
58 //=========================================
59 // The acosf function computes the principle value of the arc sine of x.
60 // A doman error occurs for arguments not in the range [-1,+1].
62 // The acosf function returns the arc cosine in the range [0, +pi] radians.
63 // acos(1) returns +0
64 // acos(x) returns a Nan and raises the invalid exception for |x| >1
66 // |x| <= sqrt(2)/2. get Ax and Bx
68 // poly_p1 = x p1
69 // poly_p3 = x2 p4 + p3
70 // poly_p1 = x2 (poly_p1) + x = x2(x p1) + x
71 // poly_p2 = x2( poly_p3) + p2 = x2(x2 p4 + p3) + p2
73 // poly_Ax = x5(x2( poly_p3) + p2) + x2(x p1) + x
74 // = x5(x2(x2 p4 + p3) + p2) + x2(x p1) + x
76 // poly_p7 = x2 p8 + p7
77 // poly_p5 = x2 p6 + p5
79 // poly_p7 = x4 p9 + (x2 p8 + p7)
80 // poly_Bx = x4 (x4 p9 + (x2 p8 + p7)) + x2 p6 + p5
82 // sinf1 = x11(x4 (x4 p9 + (x2 p8 + p7)) + x2 p6 + p5) + x5(x2(x2 p4 + p3) + p2) + x2(x p1) + x
83 // = x19 p9 + x17 p8 + x15 p7 x13 p6 + x11 p5 + x9 p4 + x7 p3 + x5 p2 + x3 p1 + x
84 // answer1 = pi/2 - sinf1
88 // |x| > sqrt(2)/2
90 // Get z = sqrt(1-x2)
92 // Get polynomial in t = 1-x2
94 // t2 = t t
95 // t4 = t2 t2
97 // poly_p4 = t p5 + p4
98 // poly_p1 = t p1 + 1
100 // poly_p6 = t p7 + p6
101 // poly_p2 = t p3 + p2
103 // poly_p8 = t p9 + p8
105 // poly_p4 = t2 poly_p6 + poly_p4
106 // = t2 (t p7 + p6) + (t p5 + p4)
108 // poly_p2 = t2 poly_p2 + poly_p1
109 // = t2 (t p3 + p2) + (t p1 + 1)
111 // poly_p4 = t4 poly_p8 + poly_p4
112 // = t4 (t p9 + p8) + (t2 (t p7 + p6) + (t p5 + p4))
114 // P(t) = poly_p2 + t4 poly_p8
115 // = t2 (t p3 + p2) + (t p1 + 1) + t4 (t4 (t p9 + p8) + (t2 (t p7 + p6) + (t p5 + p4)))
116 // = t3 p3 + t2 p2 + t p1 + 1 + t9 p9 + t8 p8 + t7 p7 + t6 p6 + t5 p5 + t4 p4
119 // answer2 = sign(x) z P(t) if x>0
120 // = sign(x) z P(t) + pi if x<0
123 //
124 // Assembly macros
125 //=========================================
127 // predicate registers
128 //acosf_pred_LEsqrt2by2 = p7
129 //acosf_pred_GTsqrt2by2 = p8
131 // integer registers
132 ACOSF_Addr1 = r33
133 ACOSF_Addr2 = r34
134 ACOSF_GR_1by2 = r35
136 ACOSF_GR_3by2 = r36
137 ACOSF_GR_5by2 = r37
139 GR_SAVE_B0 = r38
140 GR_SAVE_PFS = r39
141 GR_SAVE_GP = r40
143 GR_Parameter_X = r41
144 GR_Parameter_Y = r42
145 GR_Parameter_RESULT = r43
146 GR_Parameter_TAG = r44
148 // floating point registers
150 acosf_y = f32
151 acosf_abs_x = f33
152 acosf_x2 = f34
153 acosf_sgn_x = f35
155 acosf_1by2 = f36
156 acosf_3by2 = f37
157 acosf_5by2 = f38
158 acosf_coeff_P3 = f39
159 acosf_coeff_P8 = f40
161 acosf_coeff_P1 = f41
162 acosf_coeff_P4 = f42
163 acosf_coeff_P5 = f43
164 acosf_coeff_P2 = f44
165 acosf_coeff_P7 = f45
167 acosf_coeff_P6 = f46
168 acosf_coeff_P9 = f47
169 acosf_x2 = f48
170 acosf_x3 = f49
171 acosf_x4 = f50
173 acosf_x8 = f51
174 acosf_x5 = f52
175 acosf_const_piby2 = f53
176 acosf_const_sqrt2by2 = f54
177 acosf_x11 = f55
179 acosf_poly_p1 = f56
180 acosf_poly_p3 = f57
181 acosf_sinf1 = f58
182 acosf_poly_p2 = f59
183 acosf_poly_Ax = f60
185 acosf_poly_p7 = f61
186 acosf_poly_p5 = f62
187 acosf_sgnx_t4 = f63
188 acosf_poly_Bx = f64
189 acosf_t = f65
191 acosf_yby2 = f66
192 acosf_B = f67
193 acosf_B2 = f68
194 acosf_Az = f69
195 acosf_dz = f70
197 acosf_Sz = f71
198 acosf_d2z = f72
199 acosf_Fz = f73
200 acosf_z = f74
201 acosf_sgnx_z = f75
203 acosf_t2 = f76
204 acosf_2poly_p4 = f77
205 acosf_2poly_p6 = f78
206 acosf_2poly_p1 = f79
207 acosf_2poly_p2 = f80
209 acosf_2poly_p8 = f81
210 acosf_t4 = f82
211 acosf_Pt = f83
212 acosf_sgnx_2poly_p2 = f84
213 acosf_sgn_x_piby2 = f85
215 acosf_poly_p7a = f86
216 acosf_2poly_p4a = f87
217 acosf_2poly_p4b = f88
218 acosf_2poly_p2a = f89
219 acosf_poly_p1a = f90
225 // Data tables
226 //==============================================================
228 RODATA
230 .align 16
232 LOCAL_OBJECT_START(acosf_coeff_1_table)
233 data8 0x3FC5555607DCF816 // P1
234 data8 0x3F9CF81AD9BAB2C6 // P4
235 data8 0x3FC59E0975074DF3 // P7
236 data8 0xBFA6F4CC2780AA1D // P6
237 data8 0x3FC2DD45292E93CB // P9
238 data8 0x3fe6a09e667f3bcd // sqrt(2)/2
239 LOCAL_OBJECT_END(acosf_coeff_1_table)
241 LOCAL_OBJECT_START(acosf_coeff_2_table)
242 data8 0x3FA6F108E31EFBA6 // P3
243 data8 0xBFCA31BF175D82A0 // P8
244 data8 0x3FA30C0337F6418B // P5
245 data8 0x3FB332C9266CB1F9 // P2
246 data8 0x3ff921fb54442d18 // pi_by_2
247 LOCAL_OBJECT_END(acosf_coeff_2_table)
250 .section .text
251 GLOBAL_LIBM_ENTRY(acosf)
253 // Load the addresses of the two tables.
254 // Then, load the coefficients and other constants.
256 { .mfi
257 alloc r32 = ar.pfs,1,8,4,0
258 fnma.s1 acosf_t = f8,f8,f1
259 dep.z ACOSF_GR_1by2 = 0x3f,24,8 // 0x3f000000
260 }
261 { .mfi
262 addl ACOSF_Addr1 = @ltoff(acosf_coeff_1_table),gp
263 fma.s1 acosf_x2 = f8,f8,f0
264 addl ACOSF_Addr2 = @ltoff(acosf_coeff_2_table),gp ;;
265 }
268 { .mfi
269 ld8 ACOSF_Addr1 = [ACOSF_Addr1]
270 fmerge.s acosf_abs_x = f1,f8
271 dep ACOSF_GR_3by2 = -1,r0,22,8 // 0x3fc00000
272 }
273 { .mlx
274 nop.m 999
275 movl ACOSF_GR_5by2 = 0x40200000;;
276 }
280 { .mfi
281 setf.s acosf_1by2 = ACOSF_GR_1by2
282 fmerge.s acosf_sgn_x = f8,f1
283 nop.i 999
284 }
285 { .mfi
286 ld8 ACOSF_Addr2 = [ACOSF_Addr2]
287 nop.f 0
288 nop.i 999;;
289 }
292 { .mfi
293 setf.s acosf_5by2 = ACOSF_GR_5by2
294 fcmp.lt.s1 p11,p12 = f8,f0
295 nop.i 999;;
296 }
298 { .mmf
299 ldfpd acosf_coeff_P1,acosf_coeff_P4 = [ACOSF_Addr1],16
300 setf.s acosf_3by2 = ACOSF_GR_3by2
301 fclass.m.unc p8,p0 = f8, 0xc3 ;; //@qnan | @snan
302 }
305 { .mfi
306 ldfpd acosf_coeff_P7,acosf_coeff_P6 = [ACOSF_Addr1],16
307 fma.s1 acosf_t2 = acosf_t,acosf_t,f0
308 nop.i 999
309 }
310 { .mfi
311 ldfpd acosf_coeff_P3,acosf_coeff_P8 = [ACOSF_Addr2],16
312 fma.s1 acosf_x4 = acosf_x2,acosf_x2,f0
313 nop.i 999;;
314 }
317 { .mfi
318 ldfpd acosf_coeff_P9,acosf_const_sqrt2by2 = [ACOSF_Addr1]
319 fclass.m.unc p10,p0 = f8, 0x07 //@zero
320 nop.i 999
321 }
322 { .mfi
323 ldfpd acosf_coeff_P5,acosf_coeff_P2 = [ACOSF_Addr2],16
324 fma.s1 acosf_x3 = f8,acosf_x2,f0
325 nop.i 999;;
326 }
329 { .mfi
330 ldfd acosf_const_piby2 = [ACOSF_Addr2]
331 frsqrta.s1 acosf_B,p0 = acosf_t
332 nop.i 999
333 }
334 { .mfb
335 nop.m 999
336 (p8) fma.s.s0 f8 = f8,f1,f0
337 (p8) br.ret.spnt b0 ;; // Exit if x=nan
338 }
341 { .mfb
342 nop.m 999
343 fcmp.eq.s1 p6,p0 = acosf_abs_x,f1
344 (p10) br.cond.spnt ACOSF_ZERO ;; // Branch if x=0
345 }
347 { .mfi
348 nop.m 999
349 fcmp.gt.s1 p9,p0 = acosf_abs_x,f1
350 nop.i 999;;
351 }
353 { .mfi
354 nop.m 999
355 fma.s1 acosf_x8 = acosf_x4,acosf_x4,f0
356 nop.i 999
357 }
358 { .mfb
359 nop.m 999
360 fma.s1 acosf_t4 = acosf_t2,acosf_t2,f0
361 (p6) br.cond.spnt ACOSF_ABS_ONE ;; // Branch if |x|=1
362 }
364 { .mfi
365 nop.m 999
366 fma.s1 acosf_x5 = acosf_x2,acosf_x3,f0
367 nop.i 999
368 }
369 { .mfb
370 (p9) mov GR_Parameter_TAG = 59
371 fma.s1 acosf_yby2 = acosf_t,acosf_1by2,f0
372 (p9) br.cond.spnt __libm_error_region ;; // Branch if |x|>1
373 }
376 { .mfi
377 nop.m 999
378 fma.s1 acosf_Az = acosf_t,acosf_B,f0
379 nop.i 999
380 }
381 { .mfi
382 nop.m 999
383 fma.s1 acosf_B2 = acosf_B,acosf_B,f0
384 nop.i 999;;
385 }
387 { .mfi
388 nop.m 999
389 fma.s1 acosf_poly_p1 = f8,acosf_coeff_P1,f0
390 nop.i 999
391 }
392 { .mfi
393 nop.m 999
394 fma.s1 acosf_2poly_p1 = acosf_coeff_P1,acosf_t,f1
395 nop.i 999;;
396 }
398 { .mfi
399 nop.m 999
400 fma.s1 acosf_poly_p3 = acosf_coeff_P4,acosf_x2,acosf_coeff_P3
401 nop.i 999
402 }
403 { .mfi
404 nop.m 999
405 fma.s1 acosf_2poly_p6 = acosf_coeff_P7,acosf_t,acosf_coeff_P6
406 nop.i 999;;
407 }
409 { .mfi
410 nop.m 999
411 fma.s1 acosf_poly_p7 = acosf_x2,acosf_coeff_P8,acosf_coeff_P7
412 nop.i 999
413 }
414 { .mfi
415 nop.m 999
416 fma.s1 acosf_2poly_p2 = acosf_coeff_P3,acosf_t,acosf_coeff_P2
417 nop.i 999;;
418 }
421 { .mfi
422 nop.m 999
423 fma.s1 acosf_poly_p5 = acosf_x2,acosf_coeff_P6,acosf_coeff_P5
424 nop.i 999
425 }
426 { .mfi
427 nop.m 999
428 fma.s1 acosf_2poly_p4 = acosf_coeff_P5,acosf_t,acosf_coeff_P4
429 nop.i 999;;
430 }
433 { .mfi
434 nop.m 999
435 fma.s1 acosf_x11 = acosf_x8,acosf_x3,f0
436 nop.i 999
437 }
438 { .mfi
439 nop.m 999
440 fnma.s1 acosf_dz = acosf_B2,acosf_yby2,acosf_1by2
441 nop.i 999;;
442 }
445 { .mfi
446 nop.m 999
447 fma.s1 acosf_poly_p1a = acosf_x2,acosf_poly_p1,f8
448 nop.i 999
449 }
450 { .mfi
451 nop.m 999
452 fma.s1 acosf_2poly_p8 = acosf_coeff_P9,acosf_t,acosf_coeff_P8
453 nop.i 999;;
454 }
457 // Get the absolute value of x and determine the region in which x lies
459 { .mfi
460 nop.m 999
461 fcmp.le.s1 p7,p8 = acosf_abs_x,acosf_const_sqrt2by2
462 nop.i 999
463 }
464 { .mfi
465 nop.m 999
466 fma.s1 acosf_poly_p2 = acosf_x2,acosf_poly_p3,acosf_coeff_P2
467 nop.i 999;;
468 }
471 { .mfi
472 nop.m 999
473 fma.s1 acosf_poly_p7a = acosf_x4,acosf_coeff_P9,acosf_poly_p7
474 nop.i 999
475 }
476 { .mfi
477 nop.m 999
478 fma.s1 acosf_2poly_p2a = acosf_2poly_p2,acosf_t2,acosf_2poly_p1
479 nop.i 999;;
480 }
483 { .mfi
484 nop.m 999
485 (p8) fma.s1 acosf_sgnx_t4 = acosf_sgn_x,acosf_t4,f0
486 nop.i 999
487 }
488 { .mfi
489 nop.m 999
490 (p8) fma.s1 acosf_2poly_p4a = acosf_2poly_p6,acosf_t2,acosf_2poly_p4
491 nop.i 999;;
492 }
495 { .mfi
496 nop.m 999
497 (p8) fma.s1 acosf_Sz = acosf_5by2,acosf_dz,acosf_3by2
498 nop.i 999
499 }
500 { .mfi
501 nop.m 999
502 (p8) fma.s1 acosf_d2z = acosf_dz,acosf_dz,f0
503 nop.i 999;;
504 }
507 { .mfi
508 nop.m 999
509 (p8) fnma.d.s1 acosf_sgn_x_piby2 = acosf_sgn_x,acosf_const_piby2,acosf_const_piby2
510 nop.i 999
511 }
512 { .mfi
513 nop.m 999
514 (p7) fma.s1 acosf_poly_Ax = acosf_x5,acosf_poly_p2,acosf_poly_p1a
515 nop.i 999;;
516 }
518 { .mfi
519 nop.m 999
520 (p7) fma.s1 acosf_poly_Bx = acosf_x4,acosf_poly_p7a,acosf_poly_p5
521 nop.i 999
522 }
523 { .mfi
524 nop.m 999
525 (p8) fma.s1 acosf_sgnx_2poly_p2 = acosf_sgn_x,acosf_2poly_p2a,f0
526 nop.i 999;;
527 }
529 { .mfi
530 nop.m 999
531 fcmp.eq.s0 p6,p0 = f8,f0 // Only purpose is to set D if x denormal
532 nop.i 999
533 }
534 { .mfi
535 nop.m 999
536 (p8) fma.s1 acosf_2poly_p4b = acosf_2poly_p8,acosf_t4,acosf_2poly_p4a
537 nop.i 999;;
538 }
541 { .mfi
542 nop.m 999
543 (p8) fma.s1 acosf_Fz = acosf_d2z,acosf_Sz,acosf_dz
544 nop.i 999;;
545 }
548 { .mfi
549 nop.m 999
550 (p8) fma.d.s1 acosf_Pt = acosf_2poly_p4b,acosf_sgnx_t4,acosf_sgnx_2poly_p2
551 nop.i 999;;
552 }
554 { .mfi
555 nop.m 999
556 (p8) fma.d.s1 acosf_z = acosf_Az,acosf_Fz,acosf_Az
557 nop.i 999 ;;
558 }
560 { .mfi
561 nop.m 999
562 (p7) fma.d.s1 acosf_sinf1 = acosf_x11,acosf_poly_Bx,acosf_poly_Ax
563 nop.i 999;;
564 }
566 .pred.rel "mutex",p8,p7 //acosf_pred_GTsqrt2by2,acosf_pred_LEsqrt2by2
567 { .mfi
568 nop.m 999
569 (p8) fma.s.s0 f8 = acosf_z,acosf_Pt,acosf_sgn_x_piby2
570 nop.i 999
571 }
573 { .mfb
574 nop.m 999
575 (p7) fms.s.s0 f8 = acosf_const_piby2,f1,acosf_sinf1
576 br.ret.sptk b0 ;;
577 }
579 ACOSF_ZERO:
580 // Here if x=0
581 { .mfb
582 nop.m 999
583 fma.s.s0 f8 = acosf_const_piby2,f1,f0 // acosf(0)=pi/2
584 br.ret.sptk b0 ;;
585 }
588 ACOSF_ABS_ONE:
589 .pred.rel "mutex",p11,p12
590 // Here if |x|=1
591 { .mfi
592 nop.m 999
593 (p11) fma.s.s0 f8 = acosf_const_piby2,f1,acosf_const_piby2 // acosf(-1)=pi
594 nop.i 999
595 }
596 { .mfb
597 nop.m 999
598 (p12) fma.s.s0 f8 = f1,f0,f0 // acosf(1)=0
599 br.ret.sptk b0 ;;
600 }
602 GLOBAL_LIBM_END(acosf)
605 // Stack operations when calling error support.
606 // (1) (2)
607 // sp -> + psp -> +
608 // | |
609 // | | <- GR_Y
610 // | |
611 // | <-GR_Y Y2->|
612 // | |
613 // | | <- GR_X
614 // | |
615 // sp-64 -> + sp -> +
616 // save ar.pfs save b0
617 // save gp
620 // Stack operations when calling error support.
621 // (3) (call) (4)
622 // psp -> + sp -> +
623 // | |
624 // R3 ->| <- GR_RESULT | -> f8
625 // | |
626 // Y2 ->| <- GR_Y |
627 // | |
628 // X1 ->| |
629 // | |
630 // sp -> + +
631 // restore gp
632 // restore ar.pfs
635 LOCAL_LIBM_ENTRY(__libm_error_region)
636 .prologue
637 { .mfi
638 add GR_Parameter_Y=-32,sp // Parameter 2 value
639 nop.f 999
640 .save ar.pfs,GR_SAVE_PFS
641 mov GR_SAVE_PFS=ar.pfs // Save ar.pfs
642 }
643 { .mfi
644 .fframe 64
645 add sp=-64,sp // Create new stack
646 nop.f 0
647 mov GR_SAVE_GP=gp // Save gp
648 };;
649 { .mmi
650 stfs [GR_Parameter_Y] = f1,16 // Store Parameter 2 on stack
651 add GR_Parameter_X = 16,sp // Parameter 1 address
652 .save b0, GR_SAVE_B0
653 mov GR_SAVE_B0=b0 // Save b0
654 };;
656 .body
657 { .mfi
658 nop.m 0
659 frcpa.s0 f9,p0 = f0,f0
660 nop.i 0
661 };;
663 { .mib
664 stfs [GR_Parameter_X] = f8 // Store Parameter 1 on stack
665 add GR_Parameter_RESULT = 0,GR_Parameter_Y
666 nop.b 0 // Parameter 3 address
667 }
668 { .mib
669 stfs [GR_Parameter_Y] = f9 // Store Parameter 3 on stack
670 add GR_Parameter_Y = -16,GR_Parameter_Y
671 br.call.sptk b0=__libm_error_support# // Call error handling function
672 };;
673 { .mmi
674 nop.m 0
675 nop.m 0
676 add GR_Parameter_RESULT = 48,sp
677 };;
679 { .mmi
680 ldfs f8 = [GR_Parameter_RESULT] // Get return result off stack
681 .restore sp
682 add sp = 64,sp // Restore stack pointer
683 mov b0 = GR_SAVE_B0 // Restore return address
684 };;
685 { .mib
686 mov gp = GR_SAVE_GP // Restore gp
687 mov ar.pfs = GR_SAVE_PFS // Restore ar.pfs
688 br.ret.sptk b0 // Return
689 };;
691 LOCAL_LIBM_END(__libm_error_region)
693 .type __libm_error_support#,@function
694 .global __libm_error_support#