sysdeps/i386/fpu/s_frexpl.S

   1 /* ix87 specific frexp implementation for long double.
   2    Copyright (C) 1997, 2000, 2001, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <machine/asm.h>
  22 #include "bp-sym.h"
  23 #include "bp-asm.h"
  24
  25 #ifdef __ELF__
  26         .section .rodata
  27 #else
  28         .text
  29 #endif
  30
  31         .align ALIGNARG(4)
  32         ASM_TYPE_DIRECTIVE(two64,@object)
  33 two64:  .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x43
  34         ASM_SIZE_DIRECTIVE(two64)
  35
  36 #ifdef PIC
  37 #define MO(op) op##@GOTOFF(%edx)
  38 #else
  39 #define MO(op) op
  40 #endif
  41
  42 #define PARMS   LINKAGE         /* no space for saved regs */
  43 #define VAL0    PARMS
  44 #define VAL1    VAL0+4
  45 #define VAL2    VAL1+4
  46 #define EXPP    VAL2+4
  47
  48         .text
  49 ENTRY (BP_SYM (__frexpl))
  50         ENTER
  51
  52         movl    VAL0(%esp), %ecx
  53         movl    VAL2(%esp), %eax
  54         orl     VAL1(%esp), %ecx
  55         movl    %eax, %edx
  56         andl    $0x7fff, %eax
  57         orl     %eax, %ecx
  58         jz      1f
  59         xorl    %ecx, %ecx
  60         cmpl    $0x7fff, %eax
  61         je      1f
  62
  63         cmpl    $0, %eax
  64         jne     2f
  65
  66         fldt    VAL0(%esp)
  67 #ifdef  PIC
  68         LOAD_PIC_REG (dx)
  69 #endif
  70
  71         fmull   MO(two64)       /* It's not necessary to use a 80bit factor */
  72         movl    $-64, %ecx
  73         fstpt   VAL0(%esp)
  74         fwait
  75         movl    VAL2(%esp), %eax
  76         movl    %eax, %edx
  77         andl    $0x7fff, %eax
  78
  79 2:      andl    $0x8000, %edx
  80         subl    $16382, %eax
  81         orl     $0x3ffe, %edx
  82         addl    %eax, %ecx
  83         movl    %edx, VAL2(%esp)
  84
  85         /* Store %ecx in the variable pointed to by the second argument,
  86            get the factor from the stack and return.  */
  87 1:      movl    EXPP(%esp), %eax
  88         CHECK_BOUNDS_BOTH_WIDE (%eax, EXPP(%esp), $4)
  89         fldt    VAL0(%esp)
  90         movl    %ecx, (%eax)
  91
  92         LEAVE
  93         ret
  94 END (BP_SYM (__frexpl))
  95 weak_alias (BP_SYM (__frexpl), BP_SYM (frexpl))