sysdeps/i386/fpu/e_pow.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004, 2005, 2007
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <machine/asm.h>
  23
  24 #ifdef __ELF__
  25         .section .rodata
  26 #else
  27         .text
  28 #endif
  29
  30         .align ALIGNARG(4)
  31         ASM_TYPE_DIRECTIVE(infinity,@object)
  32 inf_zero:
  33 infinity:
  34         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  35         ASM_SIZE_DIRECTIVE(infinity)
  36         ASM_TYPE_DIRECTIVE(zero,@object)
  37 zero:   .double 0.0
  38         ASM_SIZE_DIRECTIVE(zero)
  39         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  40 minf_mzero:
  41 minfinity:
  42         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  43 mzero:
  44         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  45         ASM_SIZE_DIRECTIVE(minf_mzero)
  46         ASM_TYPE_DIRECTIVE(one,@object)
  47 one:    .double 1.0
  48         ASM_SIZE_DIRECTIVE(one)
  49         ASM_TYPE_DIRECTIVE(limit,@object)
  50 limit:  .double 0.29
  51         ASM_SIZE_DIRECTIVE(limit)
  52         ASM_TYPE_DIRECTIVE(p63,@object)
  53 p63:    .byte 0, 0, 0, 0, 0, 0, 0xe0, 0x43
  54         ASM_SIZE_DIRECTIVE(p63)
  55
  56 #ifdef PIC
  57 #define MO(op) op##@GOTOFF(%ecx)
  58 #define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  59 #else
  60 #define MO(op) op
  61 #define MOX(op,x,f) op(,x,f)
  62 #endif
  63
  64         .text
  65 ENTRY(__ieee754_pow)
  66         fldl    12(%esp)        // y
  67         fxam
  68
  69 #ifdef  PIC
  70         LOAD_PIC_REG (cx)
  71 #endif
  72
  73         fnstsw
  74         movb    %ah, %dl
  75         andb    $0x45, %ah
  76         cmpb    $0x40, %ah      // is y == 0 ?
  77         je      11f
  78
  79         cmpb    $0x05, %ah      // is y == ±inf ?
  80         je      12f
  81
  82         cmpb    $0x01, %ah      // is y == NaN ?
  83         je      30f
  84
  85         fldl    4(%esp)         // x : y
  86
  87         subl    $8,%esp
  88         cfi_adjust_cfa_offset (8)
  89
  90         fxam
  91         fnstsw
  92         movb    %ah, %dh
  93         andb    $0x45, %ah
  94         cmpb    $0x40, %ah
  95         je      20f             // x is ±0
  96
  97         cmpb    $0x05, %ah
  98         je      15f             // x is ±inf
  99
 100         fxch                    // y : x
 101
 102         /* fistpll raises invalid exception for |y| >= 1L<<63.  */
 103         fld     %st             // y : y : x
 104         fabs                    // |y| : y : x
 105         fcompl  MO(p63)         // y : x
 106         fnstsw
 107         sahf
 108         jnc     2f
 109
 110         /* First see whether `y' is a natural number.  In this case we
 111            can use a more precise algorithm.  */
 112         fld     %st             // y : y : x
 113         fistpll (%esp)          // y : x
 114         fildll  (%esp)          // int(y) : y : x
 115         fucomp  %st(1)          // y : x
 116         fnstsw
 117         sahf
 118         jne     2f
 119
 120         /* OK, we have an integer value for y.  */
 121         popl    %eax
 122         cfi_adjust_cfa_offset (-4)
 123         popl    %edx
 124         cfi_adjust_cfa_offset (-4)
 125         orl     $0, %edx
 126         fstp    %st(0)          // x
 127         jns     4f              // y >= 0, jump
 128         fdivrl  MO(one)         // 1/x          (now referred to as x)
 129         negl    %eax
 130         adcl    $0, %edx
 131         negl    %edx
 132 4:      fldl    MO(one)         // 1 : x
 133         fxch
 134
 135 6:      shrdl   $1, %edx, %eax
 136         jnc     5f
 137         fxch
 138         fmul    %st(1)          // x : ST*x
 139         fxch
 140 5:      fmul    %st(0), %st     // x*x : ST*x
 141         shrl    $1, %edx
 142         movl    %eax, %ecx
 143         orl     %edx, %ecx
 144         jnz     6b
 145         fstp    %st(0)          // ST*x
 146         ret
 147
 148         /* y is ±NAN */
 149 30:     fldl    4(%esp)         // x : y
 150         fldl    MO(one)         // 1.0 : x : y
 151         fucomp  %st(1)          // x : y
 152         fnstsw
 153         sahf
 154         je      31f
 155         fxch                    // y : x
 156 31:     fstp    %st(1)
 157         ret
 158
 159         cfi_adjust_cfa_offset (8)
 160         .align ALIGNARG(4)
 161 2:      /* y is a real number.  */
 162         fxch                    // x : y
 163         fldl    MO(one)         // 1.0 : x : y
 164         fldl    MO(limit)       // 0.29 : 1.0 : x : y
 165         fld     %st(2)          // x : 0.29 : 1.0 : x : y
 166         fsub    %st(2)          // x-1 : 0.29 : 1.0 : x : y
 167         fabs                    // |x-1| : 0.29 : 1.0 : x : y
 168         fucompp                 // 1.0 : x : y
 169         fnstsw
 170         fxch                    // x : 1.0 : y
 171         sahf
 172         ja      7f
 173         fsub    %st(1)          // x-1 : 1.0 : y
 174         fyl2xp1                 // log2(x) : y
 175         jmp     8f
 176
 177 7:      fyl2x                   // log2(x) : y
 178 8:      fmul    %st(1)          // y*log2(x) : y
 179         fst     %st(1)          // y*log2(x) : y*log2(x)
 180         frndint                 // int(y*log2(x)) : y*log2(x)
 181         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 182         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 183         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 184         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 185         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 186         addl    $8, %esp
 187         cfi_adjust_cfa_offset (-8)
 188         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 189         ret
 190
 191
 192         // pow(x,±0) = 1
 193         .align ALIGNARG(4)
 194 11:     fstp    %st(0)          // pop y
 195         fldl    MO(one)
 196         ret
 197
 198         // y == ±inf
 199         .align ALIGNARG(4)
 200 12:     fstp    %st(0)          // pop y
 201         fldl    MO(one)         // 1
 202         fldl    4(%esp)         // x : 1
 203         fabs                    // abs(x) : 1
 204         fucompp                 // < 1, == 1, or > 1
 205         fnstsw
 206         andb    $0x45, %ah
 207         cmpb    $0x45, %ah
 208         je      13f             // jump if x is NaN
 209
 210         cmpb    $0x40, %ah
 211         je      14f             // jump if |x| == 1
 212
 213         shlb    $1, %ah
 214         xorb    %ah, %dl
 215         andl    $2, %edx
 216         fldl    MOX(inf_zero, %edx, 4)
 217         ret
 218
 219         .align ALIGNARG(4)
 220 14:     fldl    MO(one)
 221         ret
 222
 223         .align ALIGNARG(4)
 224 13:     fldl    4(%esp)         // load x == NaN
 225         ret
 226
 227         cfi_adjust_cfa_offset (8)
 228         .align ALIGNARG(4)
 229         // x is ±inf
 230 15:     fstp    %st(0)          // y
 231         testb   $2, %dh
 232         jz      16f             // jump if x == +inf
 233
 234         // We must find out whether y is an odd integer.
 235         fld     %st             // y : y
 236         fistpll (%esp)          // y
 237         fildll  (%esp)          // int(y) : y
 238         fucompp                 // <empty>
 239         fnstsw
 240         sahf
 241         jne     17f
 242
 243         // OK, the value is an integer, but is the number of bits small
 244         // enough so that all are coming from the mantissa?
 245         popl    %eax
 246         cfi_adjust_cfa_offset (-4)
 247         popl    %edx
 248         cfi_adjust_cfa_offset (-4)
 249         andb    $1, %al
 250         jz      18f             // jump if not odd
 251         movl    %edx, %eax
 252         orl     %edx, %edx
 253         jns     155f
 254         negl    %eax
 255 155:    cmpl    $0x00200000, %eax
 256         ja      18f             // does not fit in mantissa bits
 257         // It's an odd integer.
 258         shrl    $31, %edx
 259         fldl    MOX(minf_mzero, %edx, 8)
 260         ret
 261
 262         cfi_adjust_cfa_offset (8)
 263         .align ALIGNARG(4)
 264 16:     fcompl  MO(zero)
 265         addl    $8, %esp
 266         cfi_adjust_cfa_offset (-8)
 267         fnstsw
 268         shrl    $5, %eax
 269         andl    $8, %eax
 270         fldl    MOX(inf_zero, %eax, 1)
 271         ret
 272
 273         cfi_adjust_cfa_offset (8)
 274         .align ALIGNARG(4)
 275 17:     shll    $30, %edx       // sign bit for y in right position
 276         addl    $8, %esp
 277         cfi_adjust_cfa_offset (-8)
 278 18:     shrl    $31, %edx
 279         fldl    MOX(inf_zero, %edx, 8)
 280         ret
 281
 282         cfi_adjust_cfa_offset (8)
 283         .align ALIGNARG(4)
 284         // x is ±0
 285 20:     fstp    %st(0)          // y
 286         testb   $2, %dl
 287         jz      21f             // y > 0
 288
 289         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 290         testb   $2, %dh
 291         jz      25f
 292
 293         fld     %st             // y : y
 294         fistpll (%esp)          // y
 295         fildll  (%esp)          // int(y) : y
 296         fucompp                 // <empty>
 297         fnstsw
 298         sahf
 299         jne     26f
 300
 301         // OK, the value is an integer, but is the number of bits small
 302         // enough so that all are coming from the mantissa?
 303         popl    %eax
 304         cfi_adjust_cfa_offset (-4)
 305         popl    %edx
 306         cfi_adjust_cfa_offset (-4)
 307         andb    $1, %al
 308         jz      27f             // jump if not odd
 309         cmpl    $0xffe00000, %edx
 310         jbe     27f             // does not fit in mantissa bits
 311         // It's an odd integer.
 312         // Raise divide-by-zero exception and get minus infinity value.
 313         fldl    MO(one)
 314         fdivl   MO(zero)
 315         fchs
 316         ret
 317
 318         cfi_adjust_cfa_offset (8)
 319 25:     fstp    %st(0)
 320 26:     addl    $8, %esp
 321         cfi_adjust_cfa_offset (-8)
 322 27:     // Raise divide-by-zero exception and get infinity value.
 323         fldl    MO(one)
 324         fdivl   MO(zero)
 325         ret
 326
 327         cfi_adjust_cfa_offset (8)
 328         .align ALIGNARG(4)
 329         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 330 21:     testb   $2, %dh
 331         jz      22f
 332
 333         fld     %st             // y : y
 334         fistpll (%esp)          // y
 335         fildll  (%esp)          // int(y) : y
 336         fucompp                 // <empty>
 337         fnstsw
 338         sahf
 339         jne     23f
 340
 341         // OK, the value is an integer, but is the number of bits small
 342         // enough so that all are coming from the mantissa?
 343         popl    %eax
 344         cfi_adjust_cfa_offset (-4)
 345         popl    %edx
 346         cfi_adjust_cfa_offset (-4)
 347         andb    $1, %al
 348         jz      24f             // jump if not odd
 349         cmpl    $0xffe00000, %edx
 350         jae     24f             // does not fit in mantissa bits
 351         // It's an odd integer.
 352         fldl    MO(mzero)
 353         ret
 354
 355         cfi_adjust_cfa_offset (8)
 356 22:     fstp    %st(0)
 357 23:     addl    $8, %esp        // Don't use 2 x pop
 358         cfi_adjust_cfa_offset (-8)
 359 24:     fldl    MO(zero)
 360         ret
 361
 362 END(__ieee754_pow)