sysdeps/i386/bsd-setjmp.S

   1 /* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  i386 version.
   2    Copyright (C) 1994-1997,2000,2001,2005, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* This just does a tail-call to `__sigsetjmp (ARG, 1)'.
  21    We cannot do it in C because it must be a tail-call, so frame-unwinding
  22    in setjmp doesn't clobber the state restored by longjmp.  */
  23
  24 #include <sysdep.h>
  25 #include <jmpbuf-offsets.h>
  26 #include "bp-sym.h"
  27 #include "bp-asm.h"
  28
  29 #define PARMS  LINKAGE          /* no space for saved regs */
  30 #define JMPBUF PARMS
  31 #define SIGMSK JMPBUF+PTR_SIZE
  32
  33 ENTRY (BP_SYM (setjmp))
  34         /* Note that we have to use a non-exported symbol in the next
  35            jump since otherwise gas will emit it as a jump through the
  36            PLT which is what we cannot use here.  */
  37         ENTER
  38
  39         movl JMPBUF(%esp), %eax
  40         CHECK_BOUNDS_BOTH_WIDE (%eax, JMPBUF(%esp), $JB_SIZE)
  41
  42         /* Save registers.  */
  43         movl %ebx, (JB_BX*4)(%eax)
  44         movl %esi, (JB_SI*4)(%eax)
  45         movl %edi, (JB_DI*4)(%eax)
  46         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  47 #ifdef PTR_MANGLE
  48         PTR_MANGLE (%ecx)
  49 #endif
  50         movl %ecx, (JB_SP*4)(%eax)
  51         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  52 #ifdef PTR_MANGLE
  53         PTR_MANGLE (%ecx)
  54 #endif
  55         movl %ecx, (JB_PC*4)(%eax)
  56         LEAVE /* pop frame pointer to prepare for tail-call.  */
  57         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  58
  59         /* Call __sigjmp_save.  */
  60         pushl $1
  61         cfi_adjust_cfa_offset (4)
  62         pushl 8(%esp)
  63         cfi_adjust_cfa_offset (4)
  64         call BP_SYM (__sigjmp_save)
  65         popl %ecx
  66         cfi_adjust_cfa_offset (-4)
  67         popl %edx
  68         cfi_adjust_cfa_offset (-4)
  69         ret
  70 END (BP_SYM (setjmp))