sysdeps/alpha/alphaev67/strrchr.S

   1 /* Copyright (C) 2000, 2003 Free Software Foundation, Inc.
   2    EV67 optimized by Rick Gorton <rick.gorton@alpha-processor.com>.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* Return the address of the last occurrence of a given character
  21    within a null-terminated string, or null if it is not found.  */
  22
  23 #include <sysdep.h>
  24
  25         .arch ev6
  26         .set noreorder
  27         .set noat
  28
  29 ENTRY(strrchr)
  30 #ifdef PROF
  31         ldgp    gp, 0(pv)
  32         lda     AT, _mcount
  33         jsr     AT, (AT), _mcount
  34         .prologue 1
  35 #else
  36         .prologue 0
  37 #endif
  38
  39         and     a1, 0xff, t2    # E : 00000000000000ch
  40         insbl   a1, 1, t4       # U : 000000000000ch00
  41         insbl   a1, 2, t5       # U : 0000000000ch0000
  42         ldq_u   t0, 0(a0)       # L : load first quadword Latency=3
  43
  44         mov     zero, t6        # E : t6 is last match aligned addr
  45         or      t2, t4, a1      # E : 000000000000chch
  46         sll     t5, 8, t3       # U : 00000000ch000000
  47         mov     zero, t8        # E : t8 is last match byte compare mask
  48
  49         andnot  a0, 7, v0       # E : align source addr
  50         or      t5, t3, t3      # E : 00000000chch0000
  51         sll     a1, 32, t2      # U : 0000chch00000000
  52         sll     a1, 48, t4      # U : chch000000000000
  53
  54         or      t4, a1, a1      # E : chch00000000chch
  55         or      t2, t3, t2      # E : 0000chchchch0000
  56         or      a1, t2, a1      # E : chchchchchchchch
  57         lda     t5, -1          # E : build garbage mask
  58
  59         cmpbge  zero, t0, t1    # E : bits set iff byte == zero
  60         mskqh   t5, a0, t4      # E : Complete garbage mask
  61         xor     t0, a1, t2      # E : make bytes == c zero
  62         cmpbge  zero, t4, t4    # E : bits set iff byte is garbage
  63
  64         cmpbge  zero, t2, t3    # E : bits set iff byte == c
  65         andnot  t1, t4, t1      # E : clear garbage from null test
  66         andnot  t3, t4, t3      # E : clear garbage from char test
  67         bne     t1, $eos        # U : did we already hit the terminator?
  68
  69         /* Character search main loop */
  70 $loop:
  71         ldq     t0, 8(v0)       # L : load next quadword
  72         cmovne  t3, v0, t6      # E : save previous comparisons match
  73         nop                     #   : Latency=2, extra map slot (keep nop with cmov)
  74         nop
  75
  76         cmovne  t3, t3, t8      # E : Latency=2, extra map slot
  77         nop                     #   : keep with cmovne
  78         addq    v0, 8, v0       # E :
  79         xor     t0, a1, t2      # E :
  80
  81         cmpbge  zero, t0, t1    # E : bits set iff byte == zero
  82         cmpbge  zero, t2, t3    # E : bits set iff byte == c
  83         beq     t1, $loop       # U : if we havnt seen a null, loop
  84         nop
  85
  86         /* Mask out character matches after terminator */
  87 $eos:
  88         negq    t1, t4          # E : isolate first null byte match
  89         and     t1, t4, t4      # E :
  90         subq    t4, 1, t5       # E : build a mask of the bytes upto...
  91         or      t4, t5, t4      # E : ... and including the null
  92
  93         and     t3, t4, t3      # E : mask out char matches after null
  94         cmovne  t3, t3, t8      # E : save it, if match found Latency=2, extra map slot
  95         nop                     #   : Keep with cmovne
  96         nop
  97
  98         cmovne  t3, v0, t6      # E :
  99         nop                     #   : Keep with cmovne
 100         /* Locate the address of the last matched character */
 101         ctlz    t8, t2          # U0 : Latency=3 (0x40 for t8=0)
 102         nop
 103
 104         cmoveq  t8, 0x3f, t2    # E : Compensate for case when no match is seen
 105         nop                     # E : hide the cmov latency (2) behind ctlz latency
 106         lda     t5, 0x3f($31)   # E :
 107         subq    t5, t2, t5      # E : Normalize leading zero count
 108
 109         addq    t6, t5, v0      # E : and add to quadword address
 110         ret                     # L0 : Latency=3
 111         nop
 112         nop
 113
 114 END(strrchr)
 115
 116 weak_alias (strrchr, rindex)
 117 libc_hidden_builtin_def (strrchr)