nptl/sysdeps/unix/sysv/linux/x86_64/sem_post.S

   1 /* Copyright (C) 2002, 2003, 2005, 2007, 2008 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <lowlevellock.h>
  22 #include <shlib-compat.h>
  23 #include <pthread-errnos.h>
  24 #include <structsem.h>
  25
  26
  27         .text
  28
  29         .globl  sem_post
  30         .type   sem_post,@function
  31         .align  16
  32 sem_post:
  33 #if VALUE == 0
  34         movl    (%rdi), %eax
  35 #else
  36         movl    VALUE(%rdi), %eax
  37 #endif
  38 0:      cmpl    $SEM_VALUE_MAX, %eax
  39         je      3f
  40         leal    1(%rax), %esi
  41         LOCK
  42 #if VALUE == 0
  43         cmpxchgl %esi, (%rdi)
  44 #else
  45         cmpxchgl %esi, VALUE(%rdi)
  46 #endif
  47         jnz     0b
  48
  49         cmpq    $0, NWAITERS(%rdi)
  50         je      2f
  51
  52         movl    $SYS_futex, %eax
  53         movl    $FUTEX_WAKE, %esi
  54         orl     PRIVATE(%rdi), %esi
  55         movl    $1, %edx
  56         syscall
  57
  58         testq   %rax, %rax
  59         js      1f
  60
  61 2:      xorl    %eax, %eax
  62         retq
  63
  64 1:
  65 #if USE___THREAD
  66         movl    $EINVAL, %eax
  67 #else
  68         callq   __errno_location@plt
  69         movl    $EINVAL, %edx
  70 #endif
  71         jmp     4f
  72
  73 3:
  74 #if USE___THREAD
  75         movl    $EOVERFLOW, %eax
  76 #else
  77         callq   __errno_location@plt
  78         movl    $EOVERFLOW, %edx
  79 #endif
  80
  81 4:
  82 #if USE___THREAD
  83         movq    errno@gottpoff(%rip), %rdx
  84         movl    %eax, %fs:(%rdx)
  85 #else
  86         movl    %edx, (%rax)
  87 #endif
  88         orl     $-1, %eax
  89         retq
  90         .size   sem_post,.-sem_post