nptl/sysdeps/unix/sysv/linux/sh/pt-vfork.S

   1 /* Copyright (C) 2003, 2004 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <tcb-offsets.h>
  23
  24 /* Clone the calling process, but without copying the whole address space.
  25    The calling process is suspended until the new process exits or is
  26    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  27    and the process ID of the new process to the old process.  */
  28
  29 ENTRY (__vfork)
  30         /* Save the PID value.  */
  31         stc     gbr, r2
  32         mov.w   .L2, r0
  33         mov.l   @(r0,r2), r4
  34         neg     r4, r1
  35         mov.l   r1, @(r0,r2)
  36
  37         mov.w   .L1, r3
  38         trapa   #0x10
  39         mov     r0, r1
  40
  41         /* Restore the old PID value in the parent.  */
  42         tst     r0, r0
  43         bt/s    2f
  44          stc    gbr, r2
  45         mov.w   .L2, r0
  46         mov.l   r4, @(r0,r2)
  47         mov     r1, r0
  48 2:
  49         mov     #-12, r2
  50         shad    r2, r1
  51         not     r1, r1                  // r1=0 means r0 = -1 to -4095
  52         tst     r1, r1                  // i.e. error in linux
  53         bf      .Lpseudo_end
  54         SYSCALL_ERROR_HANDLER
  55 .Lpseudo_end:
  56         rts
  57          nop
  58 .L1:
  59         .word   __NR_vfork
  60 .L2:
  61         .word   PID - TLS_PRE_TCB_SIZE
  62
  63 PSEUDO_END (__vfork)
  64 libc_hidden_def (__vfork)
  65
  66 weak_alias (__vfork, vfork)