nptl/sysdeps/unix/sysv/linux/ia64/vfork.S

   1 /* Copyright (C) 2000, 2002, 2004 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19
  20 #include <sysdep.h>
  21 #define _SIGNAL_H
  22 #include <bits/signum.h>
  23 #include <tcb-offsets.h>
  24
  25 /* The following are defined in linux/sched.h, which unfortunately      */
  26 /* is not safe for inclusion in an assembly file.                       */
  27 #define CLONE_VM        0x00000100      /* set if VM shared between processes */
  28 #define CLONE_VFORK     0x00004000      /* set if the parent wants the child to wake it up on mm_release */
  29
  30 /* pid_t vfork(void); */
  31 /* Implemented as __clone_syscall(CLONE_VFORK | CLONE_VM | SIGCHLD, 0)  */
  32
  33 ENTRY(__vfork)
  34         .prologue       // work around a GAS bug which triggers if
  35         .body           // first .prologue is not at the beginning of proc.
  36         alloc r2=ar.pfs,0,0,2,0
  37         adds r14=PID,r13
  38         ;;
  39         ld4 r16=[r14]
  40         ;;
  41         sub r15=0,r16
  42         cmp.eq p6,p0=0,r16
  43         ;;
  44 (p6)    movl r15=0x80000000
  45         mov out0=CLONE_VM+CLONE_VFORK+SIGCHLD
  46         mov out1=0              /* Standard sp value.                   */
  47         ;;
  48         st4 [r14]=r15
  49         DO_CALL (SYS_ify (clone))
  50         cmp.eq p6,p0=0,r8
  51         adds r14=PID,r13
  52 (p6)    br.cond.dptk 1f
  53         ;;
  54         ld4 r15=[r14]
  55         ;;
  56         extr.u r16=r15,0,31
  57         ;;
  58         cmp.eq p0,p6=0,r16
  59         ;;
  60 (p6)    sub r16=0,r15
  61         ;;
  62         st4 [r14]=r16
  63 1:
  64         cmp.eq p6,p0=-1,r10
  65 (p6)    br.cond.spnt.few __syscall_error
  66         ret
  67 PSEUDO_END(__vfork)
  68 libc_hidden_def (__vfork)
  69 weak_alias (__vfork, vfork)