nptl/sysdeps/unix/sysv/linux/ia64/__ia64_longjmp.S

   1 /* Copyright (C) 1999, 2000, 2001, 2004, 2005 Free Software Foundation, Inc.
   2    Contributed by David Mosberger-Tang <davidm@hpl.hp.com>.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #include <features.h>
  21
  22 LEAF(__ia64_flush_rbs)
  23         flushrs
  24         mov r9 = ar.rsc         // 12 cyc latency
  25         ;;
  26         mov r8 = ar.bsp         // 12 cyc latency
  27         ;;
  28         and r16 = ~0x3, r9      // clear ar.rsc.mode
  29         ;;
  30         mov ar.rsc = r16        // put RSE into enforced-lazy mode
  31         ;;
  32         mov r10 = ar.rnat       // 5 cyc latency
  33         ret
  34 END(__ia64_flush_rbs)
  35
  36
  37 #       define  pPos    p6      /* is rotate count positive? */
  38 #       define  pNeg    p7      /* is rotate count negative? */
  39
  40 /* __ia64_longjmp(__jmp_buf buf, int val, long rnat, long rsc)  */
  41
  42
  43 LEAF(__ia64_longjmp)
  44         alloc r8=ar.pfs,4,0,0,0
  45         add r2=0x98,in0         // r2 <- &jmpbuf.orig_jmp_buf_addr
  46         add r3=0x88,in0         // r3 <- &jmpbuf.ar_bsp
  47         ;;
  48         ld8 r8=[r2]             // r8 <- orig_jmp_buf_addr
  49         ld8 r23=[r3],8          // r23 <- jmpbuf.ar_bsp
  50         mov r2=in0
  51         ;;
  52         //
  53         // Note: we need to redo the "flushrs" here even though it's
  54         // already been done by __ia64_flush_rbs.  It is needed to
  55         // ensure that ar.bspstore == ar.bsp.
  56         //
  57         flushrs                 // flush dirty regs to backing store
  58         ld8 r25=[r3]            // r25 <- jmpbuf.ar_unat
  59         sub r8=r8,in0           // r8 <- &orig_jmpbuf - &jmpbuf
  60         ;;
  61         add r3=8,in0            // r3 <- &jmpbuf.r1
  62         extr.u r8=r8,3,6        // r8 <- (&orig_jmpbuf - &jmpbuf)/8 & 0x3f
  63         ;;
  64         cmp.lt pNeg,pPos=r8,r0
  65         ;;
  66 (pPos)  mov r16=r8
  67 (pNeg)  add r16=64,r8
  68 (pPos)  sub r17=64,r8
  69 (pNeg)  sub r17=r0,r8
  70         ;;
  71         shr.u r8=r25,r16
  72         shl r9=r25,r17
  73         ;;
  74         or r25=r8,r9
  75         ;;
  76         mov ar.unat=r25 // setup ar.unat (NaT bits for r1, r4-r7, and r12)
  77         ;;
  78         ld8.fill.nta sp=[r2],16 // r12 (sp)
  79         ld8.fill.nta gp=[r3],16 // r1 (gp)
  80         dep r11=-1,r23,3,6      // r11 <- ia64_rse_rnat_addr(jmpbuf.ar_bsp)
  81         ;;
  82         ld8.nta r16=[r2],16             // caller's unat
  83         ld8.nta r17=[r3],16             // fpsr
  84         ;;
  85         ld8.fill.nta r4=[r2],16         // r4
  86         ld8.fill.nta r5=[r3],16         // r5 (gp)
  87         ;;
  88         ld8.fill.nta r6=[r2],16         // r6
  89         ld8.fill.nta r7=[r3],16         // r7
  90         ;;
  91         mov ar.unat=r16                 // restore caller's unat
  92         mov ar.fpsr=r17                 // restore fpsr
  93         ;;
  94         ld8.nta r16=[r2],16             // b0
  95         ld8.nta r17=[r3],16             // b1
  96         ;;
  97         mov ar.bspstore=r23     // restore ar.bspstore
  98         ld8.nta r18=[r2],16             // b2
  99         ;;
 100         mov ar.rnat=in2         // restore ar.rnat
 101         ld8.nta r19=[r3],16             // b3
 102         ;;
 103         ld8.nta r20=[r2],16             // b4
 104         ld8.nta r21=[r3],16             // b5
 105 #ifdef PTR_DEMANGLE
 106         PTR_DEMANGLE (r16, r24)
 107 #endif
 108         ;;
 109         ld8.nta r11=[r2],16             // ar.pfs
 110         ld8.nta r22=[r3],56             // ar.lc
 111         ;;
 112         ld8.nta r24=[r2],32             // pr
 113         mov ar.rsc=in3          // restore ar.rsc
 114         mov b0=r16
 115         ;;
 116         ldf.fill.nta f2=[r2],32
 117         ldf.fill.nta f3=[r3],32
 118         mov b1=r17
 119         ;;
 120         ldf.fill.nta f4=[r2],32
 121         ldf.fill.nta f5=[r3],32
 122         mov b2=r18
 123         ;;
 124         ldf.fill.nta f16=[r2],32
 125         ldf.fill.nta f17=[r3],32
 126         mov b3=r19
 127         ;;
 128         ldf.fill.nta f18=[r2],32
 129         ldf.fill.nta f19=[r3],32
 130         mov b4=r20
 131         ;;
 132         ldf.fill.nta f20=[r2],32
 133         ldf.fill.nta f21=[r3],32
 134         mov b5=r21
 135         ;;
 136         ldf.fill.nta f22=[r2],32
 137         ldf.fill.nta f23=[r3],32
 138         mov ar.lc=r22
 139         ;;
 140         ldf.fill.nta f24=[r2],32
 141         ldf.fill.nta f25=[r3],32
 142         cmp.eq p8,p9=0,in1
 143         ;;
 144         ldf.fill.nta f26=[r2],32
 145         ldf.fill.nta f27=[r3],32
 146         mov ar.pfs=r11
 147         ;;
 148         ldf.fill.nta f28=[r2],32
 149         ldf.fill.nta f29=[r3],32
 150 (p8)    mov r8=1
 151         ;;
 152         ldf.fill.nta f30=[r2]
 153         ldf.fill.nta f31=[r3]
 154 (p9)    mov r8=in1
 155
 156         invala                  // virt. -> phys. regnum mapping may change
 157         mov pr=r24,-1
 158         ret
 159 END(__ia64_longjmp)